tests/vpp/device/interfaces/eth2p-ethicmpv4-l2bdbasemaclrn-eth-2tap-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2BD | BASE | 2TAP
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test | namespace
  22 | Test Teardown | Tear down test | packet_trace | namespace | linux_bridge
  23 | ...
  24 | Test Template | Local Template
  25 | ...
  26 | Documentation | *Tap Interface Traffic Tests*
  27 | ...
  28 | ... | *[Top] Network Topologies:* TG=DUT1 2-node topology with two links
  29 | ... | between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of
  31 | ... | IPv4.
  32 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  33 | ... | bridge-domain (L2BD) MAC learning enabled; Split Horizon Groups (SHG)
  34 | ... | are set depending on test case; Namespaces (NM)
  35 | ... | are set on DUT1 with attached linux-TAP.
  36 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets
  37 | ... | are sent by TG on link to DUT1; On receipt TG verifies packets
  38 | ... | for correctness and their IPv4 src-addr, dst-addr, and MAC addresses.
  39 | ... | *[Ref] Applicable standard specifications:*
  40
  41 *** Variables ***
  42 | @{plugins_to_enable}= | dpdk_plugin.so
  43 | ${nic_name}= | virtual
  44 | ${overhead}= | ${0}
  45 | ${bid_TAP}= | tapBr
  46
  47 *** Keywords ***
  48 | Local Template
  49 | | [Documentation]
  50 | | ... | [Ver] Packet sent from TG is passed through all L2BD and received\
  51 | | ... | back on TG. Then src_ip, dst_ip and MAC are checked.
  52 | | ...
  53 | | ... | *Arguments:*
  54 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  55 | | ... | - phy_cores - Number of physical cores. Type: integer
  56 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  57 | | ...
  58 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  59 | | ...
  60 | | Set Test Variable | \${frame_size}
  61 | | ...
  62 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  63 | | And Add PCI devices to all DUTs
  64 | | And Set Max Rate And Jumbo And Handle Multi Seg
  65 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  66 | | When Set interfaces in path up
  67 | | ${int1}= | And Add Tap Interface | ${dut1} | tap0
  68 | | ${int2}= | And Add Tap Interface | ${dut1} | tap1
  69 | | And Set Interface State | ${dut1} | ${int1} | up
  70 | | And Set Interface State | ${dut1} | ${int2} | up
  71 | | And Create bridge domain | ${dut1} | 19 | learn=${TRUE}
  72 | | And Create bridge domain | ${dut1} | 20 | learn=${TRUE}
  73 | | And Linux Add Bridge | ${dut1} | ${bid_TAP} | tap0 | tap1
  74 | | And Add interface to bridge domain | ${dut1} | ${int1} | 20 | 0
  75 | | And Add interface to bridge domain | ${dut1} | ${dut1_if1} | 20 | 0
  76 | | And Add interface to bridge domain | ${dut1} | ${int2} | 19 | 0
  77 | | And Add interface to bridge domain | ${dut1} | ${dut1_if2} | 19 | 0
  78 | | Then Send ICMP packet and verify received packet
  79 | | ... | ${tg} | ${tg_if1} | ${tg_if2}
  80
  81 *** Test Cases ***
  82 | tc01-eth2p-ethicmpv4-l2bdbasemaclrn-eth-2tap-dev
  83 | | [Tags] | 64B
  84 | | frame_size=${64} | phy_cores=${0}