tests/vpp/device/ip4/eth2p-ethip4-ip4base-copblklistbase-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP4FWD | FEATURE | COPBLKLIST | DRV_VFIO_PCI
  19 |
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace
  23 |
  24 | Test Template | Local Template
  25 |
  26 | Documentation | *COP Security IPv4 whitelist test cases*
  27 |
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
  29 | ... | with single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on all links.
  31 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  32 | ... | static routes. COP security white-lists is applied on DUT1 ingress \
  33 | ... | interface from TG.
  34 | ... | *[Ver] TG verification:* Test IPv4 packets are sent in one direction \
  35 | ... | by TG on link to DUT1; on receive TG verifies packets for correctness \
  36 | ... | and drops as applicable.
  37 | ... | *[Ref] Applicable standard specifications:*
  38
  39 *** Variables ***
  40 | @{plugins_to_enable}= | dpdk_plugin.so
  41 | ${crypto_type}= | ${None}
  42 | ${nic_name}= | virtual
  43 | ${nic_driver}= | vfio-pci
  44 | ${overhead}= | ${0}
  45
  46 *** Keywords ***
  47 | Local Template
  48 | | [Documentation]
  49 | | ... | [Ver] Make TG send IPv4 on its interface to DUT1; \
  50 | | ... | verify received IPv4 pkts are correct.
  51 | |
  52 | | ... | *Arguments:*
  53 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  54 | | ... | - phy_cores - Number of physical cores. Type: integer
  55 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  56 | |
  57 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  58 | |
  59 | | Set Test Variable | \${frame_size}
  60 | |
  61 | | Given Set Max Rate And Jumbo
  62 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  63 | | And Pre-initialize layer driver | ${nic_driver}
  64 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  65 | | When Initialize layer driver | ${nic_driver}
  66 | | And Initialize layer interface
  67 | | And Initialize IPv4 forwarding in circular topology
  68 | | And Add Fib Table | ${dut1} | 1
  69 | | And Vpp Route Add | ${dut1} | 10.10.10.0 | 24 | vrf=1 | local=${TRUE}
  70 | | And COP Add whitelist Entry | ${dut1} | ${dut1_if1} | ip4 | 1
  71 | | And COP interface enable or disable | ${dut1} | ${dut1_if1} | enable
  72 | | Then Packet transmission from port to port should fail
  73 | | ... | ${tg} | 100.0.0.2 | 200.0.0.2
  74 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  75 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
  76
  77 *** Test Cases ***
  78 | tc01-64B-ethip4-ip4base-copblklistbase-dev
  79 | | [Tags] | 64B
  80 | | frame_size=${64} | phy_cores=${0}