tests/vpp/device/ip4/eth2p-ethipv4-ip4base-dev.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Intel-X710 | ETH | IP4FWD | BASE | IP4BASE | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | ethipv4-ip4base
  21 |
  22 | Suite Setup | Setup suite topology interfaces | scapy
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | packet_trace
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | *IPv4 routing test cases*
  29 | ...
  30 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
  31 | ... | with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing on both \
  33 | ... | links.
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  35 | ... | two static IPv4 /24 route entries.
  36 | ... | *[Ver] TG verification:* Test IPv4 packet with IP protocol=61 is sent \
  37 | ... | in one direction by TG on links to DUT1; on receive TG verifies packet \
  38 | ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
  39 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  40
  41 *** Variables ***
  42 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  43 | ${crypto_type}= | ${None}
  44 | ${nic_name}= | Intel-X710
  45 | ${nic_driver}= | vfio-pci
  46 | ${nic_rxq_size}= | 0
  47 | ${nic_txq_size}= | 0
  48 | ${nic_pfs}= | 2
  49 | ${nic_vfs}= | 0
  50 | ${overhead}= | ${0}
  51
  52 *** Keywords ***
  53 | Local Template
  54 | | [Documentation]
  55 | | ... | [Ver] Make TG send IPv4 packet routed over DUT1 interfaces.\
  56 | | ... | Make TG verify IPv4 packet is correct.
  57 | |
  58 | | ... | *Arguments:*
  59 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  60 | | ... | - phy_cores - Number of physical cores. Type: integer
  61 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  62 | |
  63 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  64 | |
  65 | | Set Test Variable | \${frame_size}
  66 | |
  67 | | Given Set Max Rate And Jumbo
  68 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  69 | | And Pre-initialize layer driver | ${nic_driver}
  70 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  71 | | When Initialize layer driver | ${nic_driver}
  72 | | And Initialize layer interface
  73 | | And Initialize IPv4 forwarding in circular topology
  74 | | ... | remote_host1_ip=192.168.0.1 | remote_host2_ip=192.168.0.2
  75 | | Then Send packet and verify headers
  76 | | ... | ${tg} | 192.168.0.1 | 192.168.0.2
  77 | | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  78 | | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
  79
  80 *** Test Cases ***
  81 | 64B-ethipv4-ip4base-dev
  82 | | [Tags] | 64B
  83 | | frame_size=${64} | phy_cores=${0}