tests/vpp/device/ip4_tunnels/2n1l-10ge2p1x710-ethip4vxlan-l2bdbasemaclrn-scapy.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Intel-X710 | L2BDMACLRN | ENCAP | VXLAN | L2OVRLAY | IP4UNRLAY
  19 | ... | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethip4vxlan-l2bdbasemaclrn
  22 |
  23 | Suite Setup | Setup suite topology interfaces | scapy
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | packet_trace
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *L2BD with VXLANoIPv4 test cases*
  30 |
  31 | ... | *[Top] Network topologies:* TG-DUT1-TG 2-node circular topology\
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on\
  34 | ... | TG-DUT.
  35 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 bridge-domain\
  36 | ... | switching combined with MAC learning enable.\
  37 | ... | VXLAN tunnels are configured on links betwen TG and DUT.
  38 | ... | *[Ver] TG verification:* Test Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 packet is\
  39 | ... | sent by TG on link to DUT1; on receive TG verifies packets for\
  40 | ... | correctness and their IPv4 src-addr, dst-addr and MAC addresses.
  41 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  42
  43 *** Variables ***
  44 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  45 | ${crypto_type}= | ${None}
  46 | ${nic_name}= | Intel-X710
  47 | ${nic_driver}= | vfio-pci
  48 | ${nic_rxq_size}= | 0
  49 | ${nic_txq_size}= | 0
  50 | ${nic_pfs}= | 2
  51 | ${nic_vfs}= | 0
  52 | ${overhead}= | ${50}
  53
  54 *** Keywords ***
  55 | Local Template
  56 | | [Documentation]
  57 | | ... | [Ver] Make TG send VXLAN encapsulated Ethernet frame; verify\
  58 | | ... | all packets are received.
  59 | |
  60 | | ... | *Arguments:*
  61 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  62 | | ... | - phy_cores - Number of physical cores. Type: integer
  63 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  64 | |
  65 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  66 | |
  67 | | Set Test Variable | \${frame_size}
  68 | |
  69 | | Given Set Max Rate And Jumbo
  70 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  71 | | And Pre-initialize layer driver | ${nic_driver}
  72 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  73 | | When Initialize layer driver | ${nic_driver}
  74 | | And Initialize layer interface
  75 | | And Initialize layer ip4vxlan
  76 | | And Initialize L2 bridge domain
  77 | | Then Send VXLAN encapsulated packet and verify received packet
  78 | | ... | ${tg} | ${TG_pf1}[0] | ${TG_pf2}[0]
  79 | | ... | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  80 | | ... | 172.17.0.2 | 172.16.0.1 | ${0} | 172.26.0.1 | 172.27.0.2 | ${0}
  81
  82 *** Test Cases ***
  83 | 64B-0c-ethip4vxlan-l2bdbasemaclrn-scapy
  84 | | [Tags] | 64B | 0C
  85 | | frame_size=${64} | phy_cores=${0}