tests/vpp/device/ip4_tunnels/lisp/eth2p-ethip4lisp-ip4base-dev.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Variables | resources/test_data/lisp/lisp.py
  18 |
  19 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  20 | ... | NIC_Virtual | IP4FWD | LISP | LISP_IP4o4 | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4lisp-ip4base
  23 |
  24 | Suite Setup | Setup suite topology interfaces | scapy
  25 | Test Setup | Setup test
  26 | Test Teardown | Tear down test | packet_trace
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | *ip4-lisp-ip4 encapsulation test cases*
  31 |
  32 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node\
  33 | ... | circular topology with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-LISP-IPv4-ICMPv4\
  35 | ... | on DUT1-TG, Eth-IPv4-ICMPv4 on TG-DUTn for IPv4 routing\
  36 | ... | over LISPoIPv4 tunnel.
  37 | ... | *[Cfg] DUT configuration:* DUT is configured with IPv4\
  38 | ... | routing and static routes. LISPoIPv4 tunnel is\
  39 | ... | configured between DUT1 and TG2.
  40 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets\
  41 | ... | are sent by TG on if1 link to DUT1; on receive TG verifies\
  42 | ... | packets for correctness and their IPv4 src-addr, dst-addr\
  43 | ... | and MAC addresses.
  44 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  45
  46 *** Variables ***
  47 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so | lisp_plugin.so
  48 | ${crypto_type}= | ${None}
  49 | ${nic_name}= | virtual
  50 | ${nic_driver}= | vfio-pci
  51 | ${nic_rxq_size}= | 0
  52 | ${nic_txq_size}= | 0
  53 | ${nic_pfs}= | 2
  54 | ${nic_vfs}= | 0
  55 | ${overhead}= | ${54}
  56
  57 *** Keywords ***
  58 | Local Template
  59 | | [Documentation]
  60 | | ... | [Cfg] On DUT1 configure LISP.\
  61 | |
  62 | | ... | *Arguments:*
  63 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  64 | | ... | - phy_cores - Number of physical cores. Type: integer
  65 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  66 | |
  67 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  68 | |
  69 | | Set Test Variable | \${frame_size}
  70 | |
  71 | | Given Set Max Rate And Jumbo
  72 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  73 | | And Pre-initialize layer driver | ${nic_driver}
  74 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  75 | | When Initialize layer driver | ${nic_driver}
  76 | | And Initialize layer interface
  77 | | And Configure topology for IPv4 LISP testing
  78 | | And Configure LISP in 2-node circular topology
  79 | | ... | ${dut1} | ${DUT1_${int}2}[0] | ${NONE}
  80 | | ... | ${duts_locator_set} | ${dut1_ip4_eid}
  81 | | ... | ${dut1_to_tg_ip4_static_adjacency}
  82 | | Then Send packet and verify LISP encap
  83 | | ... | ${tg} | ${tg_if1_ip4} | ${dst_ip4}
  84 | | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  85 | | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
  86 | | ... | ${src_rloc4} | ${dst_rloc4}
  87
  88 *** Test Cases ***
  89 | 46B-ethip4lisp-ip4base-dev
  90 | | [Tags] | 46B
  91 | | frame_size=${46} | phy_cores=${0}