tests/vpp/device/ip6/2n1l-10ge2p1x710-ethip6-ip6base-scapy.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Intel-X710 | ETH | IP6FWD | BASE | IP6BASE | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | ethip6-ip6base
  21 |
  22 | Suite Setup | Setup suite topology interfaces | scapy
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | packet_trace | telemetry
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | **IPv6 routing test cases**
  29 | ... |
  30 | ... | - **[Top] Network Topologies:** TG-DUT1-TG 2-node circular topology \
  31 | ... | with single links between nodes.
  32 | ... |
  33 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv6 for IPv6 routing on \
  34 | ... | both links.
  35 | ... |
  36 | ... | - **[Cfg] DUT configuration:** DUT1 is configured with IPv6 routing \
  37 | ... | two static IPv6 /64 route entries.
  38 | ... |
  39 | ... | - **[Ver] TG verification:** Test IPv6 packet is sent in one \
  40 | ... | direction by TG on links to DUT1; on receive TG verifies packet for \
  41 | ... | correctness and their IPv6 src-addr, dst-addr and MAC addresses.
  42 | ... |
  43 | ... | - **[Ref] Applicable standard specifications:** RFC2460, RFC4443, \
  44 | ... |  RFC4861.
  45
  46 *** Variables ***
  47 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  48 | ${crypto_type}= | ${None}
  49 | ${nic_name}= | Intel-X710
  50 | ${nic_driver}= | vfio-pci
  51 | ${nic_rxq_size}= | 0
  52 | ${nic_txq_size}= | 0
  53 | ${nic_pfs}= | 2
  54 | ${nic_vfs}= | 0
  55 | ${overhead}= | ${0}
  56 # Telemetry
  57 | ${telemetry_profile}= | vpp_test_teardown
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | - **[Ver]** Make TG send IPv6 packet routed over DUT1 interfaces. \
  63 | | ... | Make TG verify IPv6 packet is correct.
  64 | |
  65 | | ... | *Arguments:*
  66 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | |
  70 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  71 | |
  72 | | Set Test Variable | \${frame_size}
  73 | |
  74 | | Given Set Max Rate And Jumbo
  75 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  76 | | And Pre-initialize layer driver | ${nic_driver}
  77 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  78 | | When Initialize layer driver | ${nic_driver}
  79 | | And Initialize layer interface
  80 | | And Initialize IPv6 forwarding in circular topology
  81 | | ... | remote_host1_ip=3ffe:5f::1 | remote_host2_ip=3ffe:5f::2
  82 | | Then Send packet and verify headers
  83 | | ... | ${tg} | 3ffe:5f::1 | 3ffe:5f::2
  84 | | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  85 | | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
  86
  87 *** Test Cases ***
  88 | 78B-0c-ethip6-ip6base-scapy
  89 | | [Tags] | 78B | 0C
  90 | | frame_size=${78} | phy_cores=${0}