tests/vpp/device/ip6/eth2p-ethicmpv6-ip6base-dut-ingress-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP6FWD | BASE | IP6BASE
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace
  23 | ...
  24 | Test Template | Local Template
  25 | ...
  26 | Documentation | *IPv6 routing test cases*
  27 | ...
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
  29 | ... | with single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-ICMPv6 for IPv6 routing on \
  31 | ... | both links.
  32 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv6 routing and \
  33 | ... | two static IPv6 /64 route entries.
  34 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in \
  35 | ... | one direction by TG on links to DUT1; on receive TG verifies packets \
  36 | ... | for correctness and their IPv6 src-addr, dst-addr and MAC addresses.
  37 | ... | *[Ref] Applicable standard specifications:* RFC2460, RFC4443, RFC4861
  38
  39 *** Variables ***
  40 | @{plugins_to_enable}= | dpdk_plugin.so
  41 | ${nic_name}= | virtual
  42 | ${overhead}= | ${0}
  43
  44 *** Keywords ***
  45 | Local Template
  46 | | [Documentation]
  47 | | ... | [Ver ]Make TG send ICMPv6 Echo Req to DUT1 ingress interface.\
  48 | | ... | Make TG verify ICMPv6 Echo Reply is correct.
  49 | | ...
  50 | | ... | *Arguments:*
  51 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  52 | | ... | - phy_cores - Number of physical cores. Type: integer
  53 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  54 | | ...
  55 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  56 | | ...
  57 | | Set Test Variable | \${frame_size}
  58 | | ...
  59 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  60 | | And Add PCI devices to all DUTs
  61 | | And Set Max Rate And Jumbo And Handle Multi Seg
  62 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  63 | | When Initialize IPv6 forwarding in circular topology
  64 | | Then Send IPv6 echo request packet and verify headers
  65 | | ... | ${tg} | ${tg_if1} | ${dut1} | ${dut1_if1}
  66 | | ... | 2001:1::2 | 2001:1::1 | ${dut1_if1_mac} | ${0}
  67
  68 *** Test Cases ***
  69 | tc01-78B-ethicmpv6-ip6base-dut-ingress-dev
  70 | | [Tags] | 78B
  71 | | frame_size=${78} | phy_cores=${0}