tests/vpp/device/ip6_tunnels/lisp/eth2p-ethip6lispgpe-ip6base-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Variables | resources/test_data/lisp/lisp.py
  18 |
  19 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  20 | ... | NIC_Virtual | IP6FWD | LISPGPE_IP6o6 | DRV_VFIO_PCI
  21 |
  22 | Suite Setup | Setup suite single link | scapy
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | packet_trace
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | *ip6-lispgpe-ip6 encapsulation test cases*
  29 |
  30 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node\
  31 | ... | circular topology with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISPGPE-IPv6-ICMPv6\
  33 | ... | on DUT1-TG, Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing\
  34 | ... | over LISPoIPv6 tunnel.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and TG(if2) are configured\
  36 | ... | with IPv6 routing and static routes. LISPoIPv6 tunnel is\
  37 | ... | configured between DUT1 and TG.
  38 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets\
  39 | ... | are sent in TG->DUT(if1); On receive TG(if2) verifies\
  40 | ... | packets for correctness and their IPv6 src-addr,\
  41 | ... | dst-addr and MAC addresses.
  42 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  43
  44 *** Variables ***
  45 | @{plugins_to_enable}= | dpdk_plugin.so
  46 | ${crypto_type}= | ${None}
  47 | ${nic_name}= | virtual
  48 | ${nic_driver}= | vfio-pci
  49 | ${overhead}= | ${54}
  50 | ${is_gpe}= | ${1}
  51
  52 *** Keywords ***
  53 | Local Template
  54 | | [Documentation]
  55 | | ... | [Cfg] On DUT1 configure LISP.
  56 | |
  57 | | ... | *Arguments:*
  58 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  59 | | ... | - phy_cores - Number of physical cores. Type: integer
  60 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  61 | |
  62 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  63 | |
  64 | | Set Test Variable | \${frame_size}
  65 | |
  66 | | Given Set Max Rate And Jumbo
  67 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  68 | | And Pre-initialize layer driver | ${nic_driver}
  69 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  70 | | When Initialize layer driver | ${nic_driver}
  71 | | And Initialize layer interface
  72 | | And Configure topology for IPv6 LISP testing
  73 | | And Configure LISP in 2-node circular topology
  74 | | ... | ${dut1} | ${dut1_if2} | ${NONE}
  75 | | ... | ${duts_locator_set} | ${dut1_ip6_eid}
  76 | | ... | ${dut1_to_tg_ip6_static_adjacency} | ${is_gpe}
  77 | | Then Send packet and verify LISP GPE encap
  78 | | ... | ${tg} | ${tg_if1_ip6} | ${dst_ip6}
  79 | | ... | ${tg_if1} | ${tg_if1_mac} | ${dut1_if1_mac}
  80 | | ... | ${tg_if2} | ${dut1_if2_mac} | ${tg_if2_mac}
  81 | | ... | ${src_rloc6} | ${dst_rloc6}
  82
  83 *** Test Cases ***
  84 | tc01-62B-ethip6lispgpe-ip6base-dev
  85 | | [Tags] | 62B
  86 | | frame_size=${62} | phy_cores=${0}