tests/vpp/device/l2patch/eth2p-ethip4-l2patch-dev.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2PATCH | BASE | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | ethip4-l2patch
  21 |
  22 | Suite Setup | Setup suite topology interfaces | scapy
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | packet_trace
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | *L2 cross-connect test cases*
  29 |
  30 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
  31 | ... | with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of \
  33 | ... | IPv4. Both apply to all links.
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 patch switching.
  35 | ... | *[Ver] TG verification:* Test IPv4 packets with IP protocol=61 \
  36 | ... | are sent in both directions by TG on links to DUT1; on receive TG \
  37 | ... | verifies packets for correctness and their IPv4 src-addr, \
  38 | ... | dst-addr and MAC addresses.
  39 | ... | *[Ref] Applicable standard specifications:* RFC792
  40
  41 *** Variables ***
  42 | @{plugins_to_enable}= | dpdk_plugin.so
  43 | ${crypto_type}= | ${None}
  44 | ${nic_name}= | virtual
  45 | ${nic_driver}= | vfio-pci
  46 | ${nic_rxq_size}= | 0
  47 | ${nic_txq_size}= | 0
  48 | ${nic_pfs}= | 2
  49 | ${nic_vfs}= | 0
  50 | ${overhead}= | ${0}
  51
  52 *** Keywords ***
  53 | Local Template
  54 | | [Documentation]
  55 | | ... | [Ver] Make TG send IPv4 packets in both directions between two\
  56 | | ... | of its interfaces to be switched by DUT to and from docker; verify\
  57 | | ... | all packets are received.
  58 | |
  59 | | ... | *Arguments:*
  60 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  61 | | ... | - phy_cores - Number of physical cores. Type: integer
  62 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  63 | |
  64 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  65 | |
  66 | | Set Test Variable | \${frame_size}
  67 | |
  68 | | Given Set Max Rate And Jumbo
  69 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  70 | | And Pre-initialize layer driver | ${nic_driver}
  71 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  72 | | When Initialize layer driver | ${nic_driver}
  73 | | And Initialize layer interface
  74 | | And Initialize L2 patch
  75 | | Then Send IPv4 bidirectionally and verify received packets
  76 | | ... | ${tg} | ${TG_pf1}[0] | ${TG_pf2}[0]
  77
  78 *** Test Cases ***
  79 | tc01-64B-ethip4-l2patch-dev
  80 | | [Tags] | 64B
  81 | | frame_size=${64} | phy_cores=${0}