tests/vpp/device/l2xc/eth2p-ethicmp-l2xcbase-dev.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/l2/l2_xconnect.robot
  17 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  18 | Resource | resources/libraries/robot/shared/testing_path.robot
  19 | ...
  20 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
  21 | ... | FUNCTEST | L2XCFWD | BASE | ETH | ICMP
  22 | ...
  23 | Suite Setup | Setup suite single link
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test
  26 | ...
  27 | Documentation | *L2 cross-connect test cases*
  28 | ...
  29 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology \
  30 | ... | with single links between nodes.
  31 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of \
  32 | ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6 use. Both apply to all \
  33 | ... | links.
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect \
  35 | ... | switching.
  36 | ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets \
  37 | ... | are sent in both directions by TG on links to DUT1; on receive TG \
  38 | ... | verifies packets for correctness and their IPv4 (IPv6) src-addr, \
  39 | ... | dst-addr and MAC addresses.
  40 | ... | *[Ref] Applicable standard specifications:* RFC792
  41
  42 *** Variables ***
  43 | @{plugins_to_enable}= | dpdk_plugin.so
  44 | ${nic_name}= | virtual
  45
  46 *** Test Cases ***
  47 | tc01-eth2p-ethicmpv4-l2xcbase-device
  48 | | [Documentation]
  49 | | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv4-ICMPv4.
  50 | | ... | [Cfg] Configure L2 cross-connects (L2XC) between both interfaces \
  51 | | ... | towards TG on DUT1.
  52 | | ... | [Ver] Make TG send ICMPv4 Echo Req in both directions between two of \
  53 | | ... | its interfaces to be switched by DUT1; verify all packets are \
  54 | | ... | received.
  55 | | ...
  56 | | Given Add PCI devices to all DUTs
  57 | | And Apply startup configuration on all VPP DUTs
  58 | | And VPP Enable Traces On All Duts | ${nodes}
  59 | | When Configure path in 2-node circular topology
  60 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  61 | | And Configure interfaces in path up
  62 | | And Configure L2XC | ${dut_node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
  63 | | And All Vpp Interfaces Ready Wait | ${nodes}
  64 | | Then Send ICMPv4 bidirectionally and verify received packets
  65 | | ... | ${tg_node} | ${tg_to_dut_if1} | ${tg_to_dut_if2}
  66
  67 | tc02-eth2p-ethicmpv6-l2xcbase-device
  68 | | [Documentation]
  69 | | ... | [Top] TG-DUT1-TG. [Enc] Eth-IPv6-ICMPv6.
  70 | | ... | [Cfg] Configure L2 cross-connects (L2XC) between both interfaces \
  71 | | ... | towards TG on DUT1.
  72 | | ... | [Ver] Make TG send ICMPv6 Echo Req in both directions between two of \
  73 | | ... | its interfaces to be switched by DUT1; verify all packets are \
  74 | | ... | received.
  75 | | ...
  76 | | Given Add PCI devices to all DUTs
  77 | | And Apply startup configuration on all VPP DUTs
  78 | | And VPP Enable Traces On All Duts | ${nodes}
  79 | | When Configure path in 2-node circular topology
  80 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  81 | | And Configure interfaces in path up
  82 | | And Configure L2XC | ${dut_node} | ${dut_to_tg_if1} | ${dut_to_tg_if2}
  83 | | And All Vpp Interfaces Ready Wait | ${nodes}
  84 | | Then Send ICMPv6 bidirectionally and verify received packets
  85 | | ... | ${tg_node} | ${tg_to_dut_if1} | ${tg_to_dut_if2}