tests/vpp/device/vm_vhost/ip4/eth2p-ethip4-ip4base-eth-2vhost-1vm-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.InterfaceUtil
  16 | Library | resources.libraries.python.IPUtil
  17 | Library | resources.libraries.python.NodePath
  18 | Library | resources.libraries.python.topology.Topology
  19 | Library | resources.libraries.python.Trace
  20 | Library | resources.libraries.python.VhostUser
  21 | Library | resources.libraries.python.VPPUtil
  22 | Resource | resources/libraries/robot/ip/ip4.robot
  23 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  24 | Resource | resources/libraries/robot/shared/default.robot
  25 | Resource | resources/libraries/robot/shared/interfaces.robot
  26 | Resource | resources/libraries/robot/shared/testing_path.robot
  27 | Resource | resources/libraries/robot/shared/traffic.robot
  28 | Resource | resources/libraries/robot/vm/qemu.robot
  29 | ...
  30 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV
  31 | ... | FUNCTEST | IP4FWD | BASE | ETH | VHOST | 1VM
  32 | ...
  33 | Test Setup | Set up VPP device test
  34 | ...
  35 | Test Teardown | Run Keywords
  36 | ... | Stop and clear QEMU | ${dut_node} | ${vm_node}
  37 | ... | AND | Tear down VPP device test
  38 | ...
  39 | Documentation | *IPv4 routing test cases with vhost user interface*
  40 | ...
  41 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  42 | ... | VM and single links between nodes.
  43 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for IPv4 routing on \
  44 | ... | both links.
  45 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  46 | ... | two static IPv4 /24 route entries. Qemu Guest is connected to VPP via \
  47 | ... | vhost-user interfaces. Guest is configured with linux bridge \
  48 | ... | interconnecting vhost-user interfaces.
  49 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  50 | ... | one direction by TG on links to DUT1; on receive TG verifies packets \
  51 | ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
  52 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  53
  54 *** Variables ***
  55 | ${net1}= | 10.0.1.0
  56 | ${net3}= | 10.0.3.0
  57 | ${net1_ip1}= | 10.0.1.1
  58 | ${net1_ip2}= | 10.0.1.2
  59 | ${net2_ip1}= | 10.0.2.1
  60 | ${net2_ip2}= | 10.0.2.2
  61 | ${net3_ip1}= | 10.0.3.1
  62 | ${net3_ip2}= | 10.0.3.2
  63 | ${prefix_length}= | 24
  64 | ${fib_table_2}= | 20
  65 | ${sock1}= | /tmp/sock1
  66 | ${sock2}= | /tmp/sock2
  67
  68 *** Test Cases ***
  69 | tc01-eth2p-ethip4-ip4base-eth-2vhost-1vm-device
  70 | | [Documentation]
  71 | | ... | Test uses two VRFs to route IPv4 traffic through two vhost-user \
  72 | | ... | interfaces. Both interfaces are configured with IP addresses from \
  73 | | ... | the same network. There is created linux bridge on VM to pass packet \
  74 | | ... | from one vhost-user interface to another one.
  75 | | ...
  76 | | Given Configure path in 2-node circular topology
  77 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  78 | | And Configure interfaces in path up
  79 | | ${vhost1}= | And Vpp Create Vhost User Interface | ${dut_node} | ${sock1}
  80 | | ${vhost2}= | And Vpp Create Vhost User Interface | ${dut_node} | ${sock2}
  81 | | And Set Interface State | ${dut_node} | ${vhost1} | up
  82 | | And Set Interface State | ${dut_node} | ${vhost2} | up
  83 | | And Add Fib Table | ${dut_node} | ${fib_table_2}
  84 | | And Assign Interface To Fib Table | ${dut_node}
  85 | | ... | ${vhost2} | ${fib_table_2}
  86 | | And Assign Interface To Fib Table | ${dut_node}
  87 | | ... | ${dut_to_tg_if2} | ${fib_table_2}
  88 | | And Configure IP addresses on interfaces
  89 | | ... | ${dut_node} | ${dut_to_tg_if1} | ${net1_ip1} | ${prefix_length}
  90 | | ... | ${dut_node} | ${vhost1} | ${net2_ip1} | ${prefix_length}
  91 | | ... | ${dut_node} | ${vhost2} | ${net2_ip2} | ${prefix_length}
  92 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip1} | ${prefix_length}
  93 | | ${vhost2_mac}= | And Get Vhost User Mac By SW Index
  94 | | ... | ${dut_node} | ${vhost2}
  95 | | And Vpp Route Add | ${dut_node} | ${net3} | ${prefix_length} | ${net2_ip2}
  96 | | ... | ${vhost1} | resolve_attempts=${NONE} | count=${NONE}
  97 | | And Vpp Route Add | ${dut_node} | ${net1} | ${prefix_length} | ${net2_ip1}
  98 | | ... | ${vhost2} | resolve_attempts=${NONE} | count=${NONE}
  99 | | ... | vrf=${fib_table_2}
 100 | | Add IP Neighbor | ${dut_node} | ${vhost1} | ${net2_ip2} | ${vhost2_mac}
 101 | | Add IP Neighbor | ${dut_node} | ${dut_to_tg_if2} | ${net3_ip2}
 102 | | ... | ${tg_to_dut_if2_mac}
 103 | | When Configure VM for vhost L2BD forwarding
 104 | | ... | ${dut_node} | ${sock1} | ${sock2}
 105 | | Then Send packet and verify headers
 106 | | ... | ${tg_node} | ${net1_ip2} | ${net3_ip2}
 107 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if1_mac} | ${dut_to_tg_if1_mac}
 108 | | ... | ${tg_to_dut_if2} | ${dut_to_tg_if2_mac} | ${tg_to_dut_if2_mac}