tests/vpp/device/vm_vhost/ip4/eth2p-ethipv4-ip4base-eth-2vhost-1vm-dev.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | IP4FWD | BASE | VHOST | 1VM | DRV_VFIO_PCI
  19 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  20 | ... | ethipv4-ip4base-eth-2vhost-1vm
  21 |
  22 | Suite Setup | Setup suite topology interfaces | scapy
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | packet_trace | vhost
  25 |
  26 | Test Template | Local Template
  27 |
  28 | Documentation | *IPv4 routing test cases with vhost user interface*
  29 |
  30 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  31 | ... | VM and single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing on both links.
  33 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and \
  34 | ... | two static IPv4 /24 route entries. Qemu Guest is connected to VPP via \
  35 | ... | vhost-user interfaces. Guest is running VPP ip4 interconnecting \
  36 | ... | vhost-user interfaces.
  37 | ... | *[Ver] TG verification:* Test IPv4 packet with IP protocol=61 is sent \
  38 | ... | in one direction by TG on links to DUT1; on receive TG verifies packet \
  39 | ... | for correctness and their IPv4 src-addr, dst-addr and MAC addresses.
  40 | ... | *[Ref] Applicable standard specifications:* RFC791, RFC826, RFC792
  41
  42 *** Variables ***
  43 | @{plugins_to_enable}= | dpdk_plugin.so
  44 | ${crypto_type}= | ${None}
  45 | ${nic_name}= | virtual
  46 | ${nic_driver}= | vfio-pci
  47 | ${nic_rxq_size}= | 0
  48 | ${nic_txq_size}= | 0
  49 | ${nic_pfs}= | 2
  50 | ${nic_vfs}= | 0
  51 | ${overhead}= | ${0}
  52 | ${nf_chains}= | ${1}
  53 | ${nf_nodes}= | ${1}
  54 | ${nf_dtc} | ${1}
  55 | ${nf_dtcr} | ${1}
  56 | ${tg_if1_ip}= | 10.10.10.2
  57 | ${tg_if2_ip}= | 20.20.20.2
  58
  59 *** Keywords ***
  60 | Local Template
  61 | | [Documentation]
  62 | | ... | Test uses two VRFs to route IPv4 traffic through two vhost-user \
  63 | | ... | nterfaces. Both interfaces are configured with IP addresses from \
  64 | | ... | the same network. The VM is running VPP IPv4 forwarding to pass \
  65 | | ... | packet from one vhost-user interface to the other one.
  66 | |
  67 | | ... | *Arguments:*
  68 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  69 | | ... | - phy_cores - Number of physical cores. Type: integer
  70 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  71 | |
  72 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  73 | |
  74 | | Set Test Variable | \${frame_size}
  75 | |
  76 | | Given Set Max Rate And Jumbo
  77 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  78 | | And Pre-initialize layer driver | ${nic_driver}
  79 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  80 | | When Initialize layer driver | ${nic_driver}
  81 | | And Initialize layer interface
  82 | | And Initialize IPv4 forwarding with vhost in 2-node circular topology
  83 | | ... | nf_nodes=${nf_nodes}
  84 | | And Configure chains of NFs connected via vhost-user
  85 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes}
  86 | | ... | vnf=vppip4noarp_2vhostvr1024 | pinning=${False}
  87 | | Then Send packet and verify headers
  88 | | ... | ${tg} | ${tg_if1_ip} | ${tg_if2_ip}
  89 | | ... | ${TG_pf1}[0] | ${TG_pf1_mac}[0] | ${DUT1_vf1_mac}[0]
  90 | | ... | ${TG_pf2}[0] | ${DUT1_vf2_mac}[0] | ${TG_pf2_mac}[0]
  91
  92 *** Test Cases ***
  93 | 64B-ethip4-ip4base-eth-2vhost-1vm-dev
  94 | | [Tags] | 64B
  95 | | frame_size=${64} | phy_cores=${0}