tests/vpp/device/vm_vhost/l2bd/eth2p-ethicmpv4-l2bdbasemaclrn-eth-2vhost-1vm-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2BDMACLRN | BASE | ICMP | VHOST | 1VM
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | vhost
  23 | ...
  24 | Test Template | Local Template
  25 | ...
  26 | Documentation | *L2 bridge-domain test cases with vhost user interface*
  27 | ...
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  29 | ... | VM and single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of \
  31 | ... | IPv4.
  32 | ... | *[Cfg] DUT configuration:* DUT1 is configured with two L2 \
  33 | ... | bridge-domains (L2BD) switching combined with MAC learning enabled. \
  34 | ... | Qemu Guest is connected to VPP via vhost-user interfaces. Guest is \
  35 | ... | configured with VPP l2 cross-connect interconnecting vhost-user \
  36 | ... | interfaces.
  37 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  38 | ... | both directions by TG on links to DUT1 via VM; on receive TG verifies \
  39 | ... | packets for correctness and their IPv4 src-addr, dst-addr and MAC \
  40 | ... | addresses.
  41 | ... | *[Ref] Applicable standard specifications:* RFC792
  42
  43 *** Variables ***
  44 | @{plugins_to_enable}= | dpdk_plugin.so
  45 | ${nic_name}= | virtual
  46 | ${nf_chains}= | ${1}
  47 | ${nf_nodes}= | ${1}
  48 | ${nf_dtc} | ${1}
  49 | ${nf_dtcr} | ${1}
  50
  51 *** Keywords ***
  52 | Local Template
  53 | | [Documentation]
  54 | | ... | [Top] TG=DUT=VM. [Enc] Eth-IPv4-ICMPv4. [Cfg] On DUT1 configure \
  55 | | ... | two L2BDs with MAC learning, each with vhost-user i/f to local \
  56 | | ... | VM and i/f to TG; configure VPP in VM to loop pkts back betwen its \
  57 | | ... | two virtio i/fs. [Ver] Make TG verify ICMPv4 Echo Req pkts are \
  58 | | ... | switched thru DUT1 and VM in both directions and are correct on \
  59 | | ... | receive. [Ref]
  60 | | ...
  61 | | ... | *Arguments:*
  62 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  63 | | ... | - phy_cores - Number of physical cores. Type: integer
  64 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  65 | | ...
  66 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  67 | | ...
  68 | | Set Test Variable | \${frame_size}
  69 | | ...
  70 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  71 | | And Add PCI devices to all DUTs
  72 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  73 | | When Initialize L2 bridge domains with Vhost-User | nf_nodes=${nf_nodes}
  74 | | And Configure chains of NFs connected via vhost-user
  75 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes} | vnf=vpp_chain_l2xc
  76 | | ... | pinning=${False}
  77 | | Then Send ICMPv4 bidirectionally and verify received packets | ${tg}
  78 | | ... | ${tg_if1} | ${tg_if2}
  79
  80 *** Test Cases ***
  81 | tc01-64B-ethicmpv4-l2bdbasemaclrn-eth-2vhost-1vm-dev
  82 | | [Tags] | 64B
  83 | | frame_size=${64} | phy_cores=${0}