tests/vpp/device/vm_vhost/l2bd/eth2p-ethipv4-l2bdbasemaclrn-eth-2vhost-1vm-dev.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Intel-X710 | ETH | L2BDMACLRN | BASE | VHOST | 1VM
  19 | ... | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethipv4-l2bdbasemaclrn-eth-2vhost-1vm
  22 |
  23 | Suite Setup | Setup suite topology interfaces | scapy
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | packet_trace | vhost
  26 |
  27 | Test Template | Local Template
  28 |
  29 | Documentation | *L2 bridge-domain test cases with vhost user interface*
  30 |
  31 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  32 | ... | VM and single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 switching of IPv4.
  34 | ... | *[Cfg] DUT configuration:* DUT1 is configured with two L2 \
  35 | ... | bridge-domains (L2BD) switching combined with MAC learning enabled. \
  36 | ... | Qemu Guest is connected to VPP via vhost-user interfaces. Guest is \
  37 | ... | configured with VPP l2 cross-connect interconnecting vhost-user \
  38 | ... | interfaces.
  39 | ... | *[Ver] TG verification:* Test IPv4 packets with IP protocol=61 are \
  40 | ... | sent in both directions by TG on links to DUT1 via VM; on receive TG \
  41 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr \
  42 | ... | and MAC addresses.
  43 | ... | *[Ref] Applicable standard specifications:* RFC792
  44
  45 *** Variables ***
  46 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  47 | ${crypto_type}= | ${None}
  48 | ${nic_name}= | Intel-X710
  49 | ${nic_driver}= | vfio-pci
  50 | ${nic_rxq_size}= | 0
  51 | ${nic_txq_size}= | 0
  52 | ${nic_pfs}= | 2
  53 | ${nic_vfs}= | 0
  54 | ${overhead}= | ${0}
  55 | ${nf_chains}= | ${1}
  56 | ${nf_nodes}= | ${1}
  57 | ${nf_dtc} | ${1}
  58 | ${nf_dtcr} | ${1}
  59
  60 *** Keywords ***
  61 | Local Template
  62 | | [Documentation]
  63 | | ... | [Top] TG=DUT=VM. [Enc] Eth-IPv4. [Cfg] On DUT1 configure \
  64 | | ... | two L2BDs with MAC learning, each with vhost-user i/f to local \
  65 | | ... | VM and i/f to TG; configure VPP in VM to loop pkts back betwen its \
  66 | | ... | two virtio i/fs. [Ver] Make TG verify IPv4 packets are switched \
  67 | | ... | thru DUT1 and VM in both directions and are correct on receive.
  68 | |
  69 | | ... | *Arguments:*
  70 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  71 | | ... | - phy_cores - Number of physical cores. Type: integer
  72 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  73 | |
  74 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  75 | |
  76 | | Set Test Variable | \${frame_size}
  77 | |
  78 | | Given Set Max Rate And Jumbo
  79 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  80 | | And Pre-initialize layer driver | ${nic_driver}
  81 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  82 | | When Initialize layer driver | ${nic_driver}
  83 | | And Initialize layer interface
  84 | | ... | count=${nf_chains}
  85 | | And Initialize L2 bridge domains with Vhost-User | nf_nodes=${nf_nodes}
  86 | | And Configure chains of NFs connected via vhost-user
  87 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes}
  88 | | ... | vnf=vppl2xc_2vhostvr1024 | pinning=${False}
  89 | | Then Send IPv4 bidirectionally and verify received packets | ${tg}
  90 | | ... | ${TG_pf1}[0] | ${TG_pf2}[0]
  91
  92 *** Test Cases ***
  93 | 64B-ethipv4-l2bdbasemaclrn-eth-2vhost-1vm-dev
  94 | | [Tags] | 64B
  95 | | frame_size=${64} | phy_cores=${0}