tests/vpp/device/vm_vhost/l2xc/eth2p-ethicmpv4-l2xcbase-eth-2vhost-1vm-dev.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | DEVICETEST | HW_ENV | DCR_ENV | SCAPY
  18 | ... | NIC_Virtual | ETH | L2XCFWD | BASE | ICMP | VHOST | 1VM
  19 | ...
  20 | Suite Setup | Setup suite single link | scapy
  21 | Test Setup | Setup test
  22 | Test Teardown | Tear down test | packet_trace | vhost
  23 | ...
  24 | Test Template | Local Template
  25 | ...
  26 | Documentation | *L2 cross-connect test cases with vhost user interface*
  27 | ...
  28 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with \
  29 | ... | VM and single links between nodes.
  30 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of \
  31 | ... | IPv4.
  32 | ... | *[Cfg] DUT configuration:* DUT1 is configured with L2 cross-connect \
  33 | ... | (L2XC) switching. Qemu Guest is connected to VPP via vhost-user \
  34 | ... | interfaces. Guest is configured with VPP l2 cross-connect \
  35 | ... | interconnecting vhost-user interfaces.
  36 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent in \
  37 | ... | both directions by TG on links to DUT1 via VM; on receive TG verifies \
  38 | ... | packets for correctness and their IPv4 src-addr, dst-addr and MAC \
  39 | ... | addresses.
  40 | ... | *[Ref] Applicable standard specifications:* RFC792
  41
  42 *** Variables ***
  43 | @{plugins_to_enable}= | dpdk_plugin.so
  44 | ${nic_name}= | virtual
  45 | ${nf_chains}= | ${1}
  46 | ${nf_nodes}= | ${1}
  47 | ${nf_dtc} | ${1}
  48 | ${nf_dtcr} | ${1}
  49
  50 *** Keywords ***
  51 | Local Template
  52 | | [Documentation]
  53 | | ... | [Top] TG=DUT=VM. [Enc] Eth-IPv4-ICMPv4. [Cfg] On DUT configure \
  54 | | ... | two L2 cross-connects (L2XC), each with one untagged interface \
  55 | | ... | to TG and untagged i/f to local VM over vhost-user. [Ver] Make \
  56 | | ... | TG send ICMPv4 Echo Reqs in both directions between two of its \
  57 | | ... | i/fs to be switched by DUT to and from VM; verify all packets \
  58 | | ... | are received. [Ref]
  59 | | ...
  60 | | ... | *Arguments:*
  61 | | ... | - frame_size - Framesize in Bytes in integer. Type: integer
  62 | | ... | - phy_cores - Number of physical cores. Type: integer
  63 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  64 | | ...
  65 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  66 | | ...
  67 | | Set Test Variable | \${frame_size}
  68 | | ...
  69 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  70 | | And Add PCI devices to all DUTs
  71 | | And Apply startup configuration on all VPP DUTs | with_trace=${True}
  72 | | When Initialize L2 xconnect with Vhost-User | nf_nodes=${nf_nodes}
  73 | | And Configure chains of NFs connected via vhost-user
  74 | | ... | nf_chains=${nf_chains} | nf_nodes=${nf_nodes} | vnf=vpp_chain_l2xc
  75 | | ... | pinning=${False}
  76 | | Then Send ICMPv4 bidirectionally and verify received packets | ${tg}
  77 | | ... | ${tg_if1} | ${tg_if2}
  78
  79 *** Test Cases ***
  80 | tc01-eth2p-ethicmpv4-l2xcbase-eth-2vhost-1vm-dev
  81 | | [Tags] | 64B
  82 | | frame_size=${64} | phy_cores=${0}