tests/vpp/func/honeycomb/mgmt-cfg-lisp-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables***
  15 | ${ip_address}= | 192.168.0.4
  16 | @{ip_addresses}= | 192.168.0.4 | 192.168.0.5 | 192.168.0.6 | 192.168.0.7
  17 | ${state}= | enabled
  18 | ${interface}= | ${node['interfaces']['port1']['name']}
  19 | ${bd_name}= | bd_lisp
  20 | ${bd2_name}= | bd2_lisp
  21 | &{bd_settings}= | flood=${True} | forward=${True} | learn=${True}
  22 | ... | unknown-unicast-flood=${True} | arp-termination=${True}
  23
  24 *** Settings ***
  25 | Resource | resources/libraries/robot/shared/default.robot
  26 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  27 | Resource | resources/libraries/robot/honeycomb/lisp.robot
  28 | Resource | resources/libraries/robot/honeycomb/bridge_domain.robot
  29 | Variables | resources/test_data/honeycomb/lisp.py
  30 | ...
  31 | Documentation | *Honeycomb Lisp test suite.*
  32 | ...
  33 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
  34 | ...
  35 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
  36 | ...
  37 | Force Tags | HC_FUNC
  38
  39 *** Test Cases ***
  40 | TC01: Honeycomb enables LISP feature
  41 | | [Documentation] | Check if Honeycomb can enable the Lisp feature.
  42 | | ...
  43 | | Given Lisp Should Not Be Configured | ${node}
  44 | | When Honeycomb enables LISP | ${node}
  45 | | Then LISP state from Honeycomb should be | ${node} | ${state}
  46 | | And LISP state from VAT should be | ${node} | ${state}
  47
  48 | TC02: Honeycomb adds locator set and locator
  49 | | [Documentation] | Check if Honeycomb can configure a locator set.
  50 | | ...
  51 | | Given LISP state from Honeycomb should be | ${node} | ${state}
  52 | | When Honeycomb adds locator set | ${node} | ${interface} | ${locator_set}
  53 | | Then Locator Set From Honeycomb Should Be
  54 | | ... | ${node} | ${interface} | ${locator_set}
  55
  56 | TC03: Honeycomb configures Lisp - remote mapping - Bridge Domain
  57 | | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
  58 | | ... | with a bridge domain.
  59 | | ...
  60 | | Given LISP state from Honeycomb should be | ${node} | ${state}
  61 | | And Honeycomb creates first l2 bridge domain
  62 | | ... | ${node} | ${bd_name} | ${bd_settings}
  63 | | When Honeycomb adds LISP mapping | ${node} | ${lisp_settings_remote_bd}
  64 | | Then LISP mapping from Honeycomb should be
  65 | | ... | ${node} | ${remote_bd_subtable}
  66 | | And LISP mapping from VAT should be
  67 | | ... | ${node} | ${vat_remote_bd}
  68
  69 | TC04: Honeycomb can remove Lisp mapping
  70 | | [Documentation] | Check if Honeycomb can remove a configured Lisp mapping.
  71 | | ...
  72 | | Given LISP mapping from Honeycomb should be
  73 | | ... | ${node} | ${remote_bd_subtable}
  74 | | And LISP mapping from VAT should be
  75 | | ... | ${node} | ${vat_remote_bd}
  76 | | When Honeycomb removes all lisp mappings | ${node}
  77 | | Then LISP mappings from Honeycomb should not exist
  78 | | ... | ${node}
  79 | | And LISP mappings from VAT should not exist
  80 | | ... | ${node}
  81
  82 | TC05: Honeycomb configures Lisp - remote mapping - VRF
  83 | | [Documentation] | Check if Honeycomb can configure a remote Lisp mapping\
  84 | | ... | with VRF.
  85 | | ...
  86 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
  87 | | ...
  88 | | Given LISP mappings from Honeycomb should not exist
  89 | | ... | ${node}
  90 | | And LISP mappings from VAT should not exist
  91 | | ... | ${node}
  92 | | When Honeycomb adds LISP mapping | ${node} | ${lisp_settings_remote_vrf}
  93 | | Then LISP mapping from Honeycomb should be
  94 | | ... | ${node} | ${remote_vrf_subtable}
  95 | | And LISP mapping from VAT should be | ${node} | ${vat_remote_vrf}
  96
  97 | TC06: Honeycomb configures Lisp - local mapping - Bridge Domain
  98 | | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
  99 | | ... | with a bridge domain.
 100 | | ...
 101 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
 102 | | ...
 103 | | Given Locator Set From Honeycomb Should Be
 104 | | ... | ${node} | ${interface} | ${locator_set}
 105 | | And LISP mappings from Honeycomb should not exist
 106 | | ... | ${node}
 107 | | And LISP mappings from VAT should not exist
 108 | | ... | ${node}
 109 | | And Honeycomb creates first l2 bridge domain
 110 | | ... | ${node} | ${bd2_name} | ${bd_settings}
 111 | | When Honeycomb adds LISP mapping | ${node} | ${lisp_settings_local_bd}
 112 | | Then LISP mapping from Honeycomb should be | ${node} | ${local_bd_subtable}
 113 | | And LISP mapping from VAT should be | ${node} | ${vat_local_bd}
 114
 115 | TC07: Honeycomb configures Lisp - local mapping - VRF
 116 | | [Documentation] | Check if Honeycomb can configure a local Lisp mapping\
 117 | | ... | with VRF.
 118 | | ...
 119 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
 120 | | ...
 121 | | Given Locator Set From Honeycomb Should Be
 122 | | ... | ${node} | ${interface} | ${locator_set}
 123 | | And LISP mappings from Honeycomb should not exist
 124 | | ... | ${node}
 125 | | And LISP mappings from VAT should not exist
 126 | | ... | ${node}
 127 | | When Honeycomb adds LISP mapping | ${node} | ${lisp_settings_local_vrf}
 128 | | Then LISP mapping from Honeycomb should be | ${node} | ${local_vrf_subtable}
 129 | | And LISP mapping from VAT should be | ${node} | ${vat_local_vrf}
 130
 131 | TC08: Honeycomb configures Lisp mapping with adjacency
 132 | | [Documentation] | Check if Honeycomb can configure local and remote Lisp\
 133 | | ... | mappings with VRF, and configure adjacency.
 134 | | ...
 135 | | [Teardown] | Honeycomb removes all lisp mappings | ${node}
 136 | | ...
 137 | | Given Locator Set From Honeycomb Should Be
 138 | | ... | ${node} | ${interface} | ${locator_set}
 139 | | And Honeycomb creates first l2 bridge domain
 140 | | ... | ${node} | ${bd2_name} | ${bd_settings}
 141 | | And LISP mappings from Honeycomb should not exist
 142 | | ... | ${node}
 143 | | And LISP mappings from VAT should not exist
 144 | | ... | ${node}
 145 | | And Honeycomb adds LISP mapping | ${node} | ${lisp_settings_both_vrf}
 146 | | When Honeycomb adds LISP adjacency | ${node} | ${7} | remote_map_vrf
 147 | | ... | adj01 | ${vrf_adjacency}
 148 | | Then Lisp mapping from Honeycomb should be
 149 | | ... | ${node} | ${adj_subtable}
 150
 151 | TC09: Honeycomb configures Lisp Map Resolver
 152 | | [Documentation] | Check if Honeycomb can configure a Lisp Map Resolver.
 153 | | ...
 154 | | Given LISP state from Honeycomb should be | ${node} | ${state}
 155 | | And LISP state from VAT should be | ${node} | ${state}
 156 | | When Honeycomb adds Lisp Map Resolver | ${node} | ${ip_address}
 157 | | Then Map Resolver from Honeycomb should be | ${node} | ${ip_address}
 158 | | And Map Resolver from VAT should be | ${node} | ${ip_address}
 159
 160 | TC10: Honeycomb configures Lisp Map Server
 161 | | [Documentation] | Check if Honeycomb can configure a Lisp Map Server.
 162 | | ...
 163 | | Given LISP state from Honeycomb should be | ${node} | ${state}
 164 | | And LISP state from VAT should be | ${node} | ${state}
 165 | | When Honeycomb adds Lisp Map Server | ${node} | @{ip_addresses}
 166 | | Then Map Server from Honeycomb should be | ${node} | @{ip_addresses}
 167 | | And Map Server from VAT should be | ${node} | @{ip_addresses}
 168
 169 | TC11: Honeycomb configures Lisp PETR configuration
 170 | | [Documentation] | Check if Honeycomb can configure Lisp
 171 | | ... | PETR configuration.
 172 | | ...
 173 | | Given LISP state from Honeycomb should be | ${node} | ${state}
 174 | | And LISP state from VAT should be | ${node} | ${state}
 175 | | When Honeycomb enables LISP PETR feature | ${node} | ${ip_address}
 176 | | Then PETR configuration from Honeycomb should be | ${node} | ${ip_address}
 177 | | And PETR configuration from VAT should be | ${node} | enabled
 178
 179 | TC12: Honeycomb configures Lisp RLOC Probing
 180 | | [Documentation] | Check if Honeycomb can configure Lisp RLOC Probing.
 181 | | ...
 182 | | Given LISP state from Honeycomb should be | ${node} | ${state}
 183 | | And LISP state from VAT should be | ${node} | ${state}
 184 | | When Honeycomb enables LISP RLOC feature | ${node}
 185 | | Then RLOC Probing from Honeycomb should be | ${node} | ${True}
 186 | | And RLOC Probing from VAT should be | ${node} | enabled
 187
 188 | TC13: Honeycomb configures Lisp Map Register
 189 | | [Documentation] | Check if Honeycomb can configure a Lisp Map Register.
 190 | | ...
 191 | | Given LISP state from Honeycomb should be | ${node} | ${state}
 192 | | And LISP state from VAT should be | ${node} | ${state}
 193 | | When Honeycomb adds Lisp Map Register | ${node} | ${True}
 194 | | Then Map Register from Honeycomb should be | ${node} | ${True}
 195 | | And Map Register from VAT should be | ${node} | enabled
 196
 197 | TC14: Honeycomb enabled Lisp PITR feature
 198 | | [Documentation] | Check if Honeycomb can configure the Lisp PITR feature.
 199 | | ...
 200 | | Given Locator Set From Honeycomb Should Be
 201 | | ... | ${node} | ${interface} | ${locator_set}
 202 | | When Honeycomb enables LISP PITR feature | ${node} | ${locator_set}
 203 | | Then PITR config from Honeycomb should be | ${node} | ${locator_set}
 204 | | And PITR config from VAT should be | ${node} | ${locator_set}
 205
 206 | TC15: Honeycomb can remove configuration of Lisp features
 207 | | [Documentation] | Check if Honeycomb can disable all Lisp features.
 208 | | ...
 209 | | Given Map resolver from Honeycomb should be | ${node} | ${ip_address}
 210 | | And PITR config from Honeycomb should be | ${node} | ${locator_set}
 211 | | When Honeycomb disables all LISP features | ${node}
 212 | | Then Lisp Should Not Be Configured | ${node}
 213
 214 | TC16: Honeycomb configures Lisp Map Request Mode
 215 | | [Documentation] | Check if Honeycomb can configure Lisp Map Request mode.
 216 | | ... | Note: Map Request Mode cannot be removed once configured.
 217 | | ...
 218 | | [Teardown] | Honeycomb disables LISP | ${node}
 219 | | ...
 220 | | Given Honeycomb enables LISP | ${node}
 221 | | When Honeycomb sets Lisp Map Request Mode | ${node} | ${True}
 222 | | Then Map Request Mode from Honeycomb should be
 223 | | ... | ${node} | source-destination
 224 | | And Map Request Mode from VAT should be | ${node} | src-dst