tests/vpp/func/honeycomb/mgmt-cfg-nsh-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables***
  15 | ${super_if}= | ${node['interfaces']['port1']['name']}
  16
  17 *** Settings ***
  18 | Resource | resources/libraries/robot/shared/default.robot
  19 | Resource | resources/libraries/robot/honeycomb/nsh.robot
  20 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  21 | Resource | resources/libraries/robot/honeycomb/vxlan_gpe.robot
  22 | Variables | resources/test_data/honeycomb/nsh.py
  23 | Variables | resources/test_data/honeycomb/vxlan_gpe.py
  24 | ...
  25 | Documentation | *Honeycomb NSH test suite.*
  26 | ...
  27 | Suite Setup | Run Keywords
  28 | ... | Enable Honeycomb Feature | ${node} | NSH | AND
  29 | ... | Set Up Honeycomb Functional Test Suite | ${node}
  30 | ...
  31 | Suite Teardown | Run Keywords
  32 | ... | Tear Down Honeycomb Functional Test Suite | ${node} | AND
  33 | ... | Disable Honeycomb Feature | ${node} | NSH
  34 | ...
  35 # NSH packages are not yet available in fd.io.stable.1710.* repos
  36 | Force Tags | HC_FUNC | EXPECTED_FAILING
  37
  38 *** Test Cases ***
  39 | TC01: Honeycomb can configure NSH entry
  40 | | [Documentation] | Check if Honeycomb can configure an NSH entry.
  41 | | ...
  42 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  43 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  44 | | Then NSH entry from Honeycomb should be
  45 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  46
  47 | TC02: Honeycomb can remove NSH entry
  48 | | [Documentation] | Check if Honeycomb can remove an existing NSH entry.
  49 | | ...
  50 | | Given NSH entry from Honeycomb should be
  51 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  52 | | When Honeycomb removes NSH entry | ${node} | entry1
  53 | | Then NSH Operational Data From Honeycomb Should Be empty | ${node}
  54
  55 | TC03: Honeycomb can configure new NSH entry
  56 | | [Documentation] | Check if Honeycomb can configure an NSH antry after one\
  57 | | ... | has been deleted.
  58 | | ...
  59 | | [Teardown] | Honeycomb removes NSH entry | ${node} | entry2
  60 | | ...
  61 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  62 | | When Honeycomb adds NSH entry | ${node} | entry2 | ${nsh_entry2}
  63 | | Then NSH entry from Honeycomb should be
  64 | | ... | ${node} | entry2 | ${nsh_entry2_oper}
  65
  66 | TC04: Honeycomb can configure multiple NSH entries at the same time
  67 | | [Documentation] | Check if Honeycomb can configure an NSH entry when one\
  68 | | ... | already exists.
  69 | | ...
  70 | | [Teardown] | Honeycomb clears NSH configuration | ${node}
  71 | | ...
  72 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  73 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  74 | | And Honeycomb adds NSH entry | ${node} | entry2 | ${nsh_entry2}
  75 | | Then NSH entry from Honeycomb should be
  76 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  77 | | And NSH entry from Honeycomb should be
  78 | | ... | ${node} | entry2 | ${nsh_entry2_oper}
  79
  80 | TC05: Honeycomb can configure NSH map
  81 | | [Documentation] | Check if Honeycomb can configure an NSH map.
  82 | | ...
  83 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  84 | | And Honeycomb creates VxLAN GPE interface
  85 | | ... | ${node} | ${vxlan_gpe_if1}
  86 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
  87 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  88 | | And Honeycomb adds NSH map | ${node} | map1 | ${nsh_map1}
  89 | | Then NSH map from Honeycomb should be | ${node} | map1 | ${nsh_map1_oper}
  90
  91 | TC06: Honeycomb can remove NSH map
  92 | | [Documentation] | Check if Honeycomb can remove an existing NSH map.
  93 | | ...
  94 | | Given NSH entry from Honeycomb should be
  95 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  96 | | And VxLAN GPE Operational Data From Honeycomb Should Be
  97 | | ... | ${node} | ${vxlan_gpe_if1}
  98 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
  99 | | And NSH map from Honeycomb should be | ${node} | map1 | ${nsh_map1_oper}
 100 | | When Honeycomb removes NSH map | ${node} | map1
 101 | | Then NSH map from Honeycomb should not exist | ${node} | map1
 102 | | And NSH entry from Honeycomb should be
 103 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 104
 105 | TC07: Honeycomb can modify existing NSH map
 106 | | [Documentation] | Check if Honeycomb can configure an NSH map after one\
 107 | | ... | has been deleted.
 108 | | ...
 109 | | [Teardown] | Honeycomb removes NSH map | ${node} | map1_edit
 110 | | ...
 111 | | Given NSH map from Honeycomb should not exist | ${node} | map1_edit
 112 | | And NSH entry from Honeycomb should be
 113 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 114 | | And VxLAN GPE Operational Data From Honeycomb Should Be
 115 | | ... | ${node} | ${vxlan_gpe_if1}
 116 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
 117 | | When Honeycomb adds NSH map | ${node} | map1_edit | ${nsh_map1_edit}
 118 | | Then NSH map from Honeycomb should be
 119 | | ... | ${node} | map1_edit | ${nsh_map1_edit_oper}
 120 | | And NSH entry from Honeycomb should be
 121 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 122
 123 | TC08: Honeycomb can configure multiple NSH maps at the same time
 124 | | [Documentation] | Check if Honeycomb can configure and NSH map when one\
 125 | | ... | already exists.
 126 | | ...
 127 | | [Teardown] | Run Keywords
 128 | | ... | Honeycomb clears NSH configuration | ${node} | AND
 129 | | ... | Honeycomb removes VxLAN GPE interface
 130 | | ... | ${node} | ${vxlan_gpe_if1} | AND
 131 | | ... | Honeycomb removes VxLAN GPE interface
 132 | | ... | ${node} | ${vxlan_gpe_if2}
 133 | | ...
 134 | | Given NSH map from Honeycomb should not exist | ${node} | map2
 135 | | And NSH entry from Honeycomb should be
 136 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 137 | | And VxLAN GPE Operational Data From Honeycomb Should Be
 138 | | ... | ${node} | ${vxlan_gpe_if1}
 139 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
 140 | | And Honeycomb creates VxLAN GPE interface
 141 | | ... | ${node} | ${vxlan_gpe_if2}
 142 | | ... | ${vxlan_gpe_base_settings2} | ${vxlan_gpe_settings2}
 143 | | When Honeycomb adds NSH map | ${node} | map1 | ${nsh_map1}
 144 | | And Honeycomb adds NSH map | ${node} | map2 | ${nsh_map2}
 145 | | Then NSH map from Honeycomb should be
 146 | | ... | ${node} | map1 | ${nsh_map1_oper}
 147 | | And NSH map from Honeycomb should be
 148 | | ... | ${node} | map2 | ${nsh_map2_oper}