tests/vpp/func/honeycomb/mgmt-cfg-nsh-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables***
  15 | ${super_if}= | ${node['interfaces']['port1']['name']}
  16
  17 *** Settings ***
  18 | Resource | resources/libraries/robot/shared/default.robot
  19 | Resource | resources/libraries/robot/honeycomb/nsh.robot
  20 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  21 | Resource | resources/libraries/robot/honeycomb/vxlan_gpe.robot
  22 | Variables | resources/test_data/honeycomb/nsh.py
  23 | Variables | resources/test_data/honeycomb/vxlan_gpe.py
  24 | ...
  25 | Documentation | *Honeycomb NSH test suite.*
  26 | ...
  27 | Suite Setup | Run Keywords
  28 | ... | Enable Honeycomb Feature | ${node} | NSH | AND
  29 | ... | Set Up Honeycomb Functional Test Suite | ${node}
  30 | ...
  31 | Suite Teardown | Run Keywords
  32 | ... | Tear Down Honeycomb Functional Test Suite | ${node} | AND
  33 | ... | Disable Honeycomb Feature | ${node} | NSH
  34 | ...
  35 | Force Tags | HC_FUNC
  36
  37 *** Test Cases ***
  38 | TC01: Honeycomb can configure NSH entry
  39 | | [Documentation] | Check if Honeycomb can configure an NSH entry.
  40 | | ...
  41 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  42 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  43 | | Then NSH entry from Honeycomb should be
  44 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  45
  46 | TC02: Honeycomb can remove NSH entry
  47 | | [Documentation] | Check if Honeycomb can remove an existing NSH entry.
  48 | | ...
  49 | | Given NSH entry from Honeycomb should be
  50 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  51 | | When Honeycomb removes NSH entry | ${node} | entry1
  52 | | Then NSH Operational Data From Honeycomb Should Be empty | ${node}
  53
  54 | TC03: Honeycomb can configure new NSH entry
  55 | | [Documentation] | Check if Honeycomb can configure an NSH antry after one\
  56 | | ... | has been deleted.
  57 | | ...
  58 | | [Teardown] | Honeycomb removes NSH entry | ${node} | entry2
  59 | | ...
  60 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  61 | | When Honeycomb adds NSH entry | ${node} | entry2 | ${nsh_entry2}
  62 | | Then NSH entry from Honeycomb should be
  63 | | ... | ${node} | entry2 | ${nsh_entry2_oper}
  64
  65 | TC04: Honeycomb can configure multiple NSH entries at the same time
  66 | | [Documentation] | Check if Honeycomb can configure an NSH entry when one\
  67 | | ... | already exists.
  68 | | ...
  69 | | [Teardown] | Honeycomb clears NSH configuration | ${node}
  70 | | ...
  71 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  72 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  73 | | And Honeycomb adds NSH entry | ${node} | entry2 | ${nsh_entry2}
  74 | | Then NSH entry from Honeycomb should be
  75 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  76 | | And NSH entry from Honeycomb should be
  77 | | ... | ${node} | entry2 | ${nsh_entry2_oper}
  78
  79 | TC05: Honeycomb can configure NSH map
  80 | | [Documentation] | Check if Honeycomb can configure an NSH map.
  81 | | ...
  82 | | Given NSH Operational Data From Honeycomb Should Be empty | ${node}
  83 | | And Honeycomb creates VxLAN GPE interface
  84 | | ... | ${node} | ${vxlan_gpe_if1}
  85 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
  86 | | When Honeycomb adds NSH entry | ${node} | entry1 | ${nsh_entry1}
  87 | | And Honeycomb adds NSH map | ${node} | map1 | ${nsh_map1}
  88 | | Then NSH map from Honeycomb should be | ${node} | map1 | ${nsh_map1_oper}
  89
  90 | TC06: Honeycomb can remove NSH map
  91 | | [Documentation] | Check if Honeycomb can remove an existing NSH map.
  92 | | ...
  93 | | Given NSH entry from Honeycomb should be
  94 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
  95 | | And VxLAN GPE Operational Data From Honeycomb Should Be
  96 | | ... | ${node} | ${vxlan_gpe_if1}
  97 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
  98 | | And NSH map from Honeycomb should be | ${node} | map1 | ${nsh_map1_oper}
  99 | | When Honeycomb removes NSH map | ${node} | map1
 100 | | Then NSH map from Honeycomb should not exist | ${node} | map1
 101 | | And NSH entry from Honeycomb should be
 102 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 103
 104 | TC07: Honeycomb can modify existing NSH map
 105 | | [Documentation] | Check if Honeycomb can configure an NSH map after one\
 106 | | ... | has been deleted.
 107 | | ...
 108 | | [Teardown] | Honeycomb removes NSH map | ${node} | map1_edit
 109 | | ...
 110 | | Given NSH map from Honeycomb should not exist | ${node} | map1_edit
 111 | | And NSH entry from Honeycomb should be
 112 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 113 | | And VxLAN GPE Operational Data From Honeycomb Should Be
 114 | | ... | ${node} | ${vxlan_gpe_if1}
 115 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
 116 | | When Honeycomb adds NSH map | ${node} | map1_edit | ${nsh_map1_edit}
 117 | | Then NSH map from Honeycomb should be
 118 | | ... | ${node} | map1_edit | ${nsh_map1_edit_oper}
 119 | | And NSH entry from Honeycomb should be
 120 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 121
 122 | TC08: Honeycomb can configure multiple NSH maps at the same time
 123 | | [Documentation] | Check if Honeycomb can configure and NSH map when one\
 124 | | ... | already exists.
 125 | | ...
 126 | | [Teardown] | Run Keywords
 127 | | ... | Honeycomb clears NSH configuration | ${node} | AND
 128 | | ... | Honeycomb removes VxLAN GPE interface
 129 | | ... | ${node} | ${vxlan_gpe_if1} | AND
 130 | | ... | Honeycomb removes VxLAN GPE interface
 131 | | ... | ${node} | ${vxlan_gpe_if2}
 132 | | ...
 133 | | Given NSH map from Honeycomb should not exist | ${node} | map2
 134 | | And NSH entry from Honeycomb should be
 135 | | ... | ${node} | entry1 | ${nsh_entry1_oper}
 136 | | And VxLAN GPE Operational Data From Honeycomb Should Be
 137 | | ... | ${node} | ${vxlan_gpe_if1}
 138 | | ... | ${vxlan_gpe_base_settings1} | ${vxlan_gpe_settings1}
 139 | | And Honeycomb creates VxLAN GPE interface
 140 | | ... | ${node} | ${vxlan_gpe_if2}
 141 | | ... | ${vxlan_gpe_base_settings2} | ${vxlan_gpe_settings2}
 142 | | When Honeycomb adds NSH map | ${node} | map1 | ${nsh_map1}
 143 | | And Honeycomb adds NSH map | ${node} | map2 | ${nsh_map2}
 144 | | Then NSH map from Honeycomb should be
 145 | | ... | ${node} | map1 | ${nsh_map1_oper}
 146 | | And NSH map from Honeycomb should be
 147 | | ... | ${node} | map2 | ${nsh_map2_oper}