tests/vpp/func/honeycomb/mgmt-cfg-proxynd6-apihc-func.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Interface to run configuration tests on.
  16 | ${interface}= | ${node['interfaces']['port1']['name']}
  17 # IPv6 addresses to configure on DUT.
  18 | ${dut_to_tg_if1_ip}= | 10::1
  19 | ${dut_to_tg_if2_ip}= | 11::1
  20 # IPv6 addresses used for TG interfaces.
  21 | ${test_src_ip}= | 10::2
  22 | ${test_dst_ip}= | 11::2
  23 | ${test_dst_ip2}= | 11::3
  24 # IPv6 subnet prefix length
  25 | ${prefix_length}= | 64
  26
  27 *** Settings ***
  28 | Resource | resources/libraries/robot/shared/default.robot
  29 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  30 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  31 | Resource | resources/libraries/robot/honeycomb/proxyarp.robot
  32 | Resource | resources/libraries/robot/shared/testing_path.robot
  33 | Resource | resources/libraries/robot/ip/ip6.robot
  34 | Resource | resources/libraries/robot/shared/traffic.robot
  35 | Resource | resources/libraries/robot/features/dhcp_proxy.robot
  36 | Library | resources.libraries.python.Trace
  37 | ...
  38 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
  39 | ...
  40 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
  41 | ...
  42 | Force Tags | HC_FUNC
  43 | ...
  44 | Documentation | *Honeycomb IPv6 neighbor discovery proxy test suite.*
  45
  46 *** Test Cases ***
  47 | TC01: Honeycomb can configure IPv6 ND proxy on an interface
  48 | | [Documentation] | Check if Honeycomb can configure the IPv6 ND proxy\
  49 | | ... | feature on an interface.
  50 | | ...
  51 | | Given IPv6 ND proxy from Honeycomb should be empty | ${node} | ${interface}
  52 | | And Honeycomb configures interface state | ${node} | ${interface} | up
  53 | | When Honeycomb configures IPv6 ND proxy on interface
  54 | | ... | ${node} | ${interface} | ${test_dst_ip}
  55 | | Then IPv6 ND proxy from Honeycomb should be
  56 | | ... | ${node} | ${interface} | ${test_dst_ip}
  57
  58 | TC02: Honeycomb can disable IPv6 ND proxy on an interface
  59 | | [Documentation] | Check if Honeycomb can remove IPv6 ND proxy feature\
  60 | | ... | configuration from an interface.
  61 | | ...
  62 | | Given IPv6 ND proxy from Honeycomb should be
  63 | | ... | ${node} | ${interface} | ${test_dst_ip}
  64 | | When Honeycomb disables IPv6 ND proxy on interface | ${node} | ${interface}
  65 | | Then IPv6 ND proxy from Honeycomb should be empty | ${node} | ${interface}
  66
  67 | TC03: Honeycomb can configure multiple IPv6 ND proxies on an interface
  68 | | [Documentation] | Check if Honeycomb can configure two ND proxies\
  69 | | ... | on one interface.
  70 | | ...
  71 | | [Teardown] | Honeycomb disables IPv6 ND proxy on interface
  72 | | ... | ${node} | ${interface}
  73 | | ...
  74 | | Given IPv6 ND proxy from Honeycomb should be empty | ${node} | ${interface}
  75 | | And Honeycomb configures interface state | ${node} | ${interface} | up
  76 | | When Honeycomb configures IPv6 ND proxy on interface
  77 | | ... | ${node} | ${interface} | ${test_dst_ip} | ${test_dst_ip2}
  78 | | Then IPv6 ND proxy from Honeycomb should be
  79 | | ... | ${node} | ${interface} | ${test_dst_ip} | ${test_dst_ip2}
  80
  81 | TC04: VPP proxies valid ICMPv6 Neighbor Discovery request
  82 | | [Documentation] |
  83 | | ... | [Top] TG=DUT
  84 | | ... | [Cfg] On DUT configure IPv6 addresses and neighbors, supress router\
  85 | | ... | advertisement and configure IPv6 Neighbor Discovery proxy.
  86 | | ... | [Ver] Make TG send a neighbor solicitation packet to it's other\
  87 | | ... | interface through DUT, verify DUT responds to the packet instead\
  88 | | ... | of forwarding it. Then exchange ICMPv6 Echo request/reply to verify\
  89 | | ... | connectivity between interfaces.
  90 | | ... | [Ref] RFC 4389
  91 | | ...
  92 | | [Teardown] | Run Keywords
  93 | | ... | Show Packet Trace on All DUTs | ${nodes} | AND
  94 | | ... | Honeycomb disables IPv6 ND proxy on interface
  95 | | ... | ${dut_node} | ${dut_to_tg_if2}
  96 | | ...
  97 | | Given Configure path in 2-node circular topology
  98 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['TG']}
  99 | | Honeycomb configures interface state | ${dut_node} | ${dut_to_tg_if1} | up
 100 | | Honeycomb configures interface state | ${dut_node} | ${dut_to_tg_if2} | up
 101 | | Honeycomb sets interface IPv6 address | ${dut_node}
 102 | | ... | ${dut_to_tg_if1} | ${dut_to_tg_if1_ip} | ${prefix_length}
 103 | | Honeycomb sets interface IPv6 address | ${dut_node}
 104 | | ... | ${dut_to_tg_if2} | ${dut_to_tg_if2_ip} | ${prefix_length}
 105 | | And Vpp Ra Suppress Link Layer | ${dut_node} | ${dut_to_tg_if1}
 106 | | And Vpp Ra Suppress Link Layer | ${dut_node} | ${dut_to_tg_if2}
 107 | | And Honeycomb adds interface IPv6 neighbor | ${dut_node} | ${dut_to_tg_if1}
 108 | | ... | ${test_src_ip} | ${tg_to_dut_if1_mac}
 109 | | And Honeycomb adds interface IPv6 neighbor | ${dut_node} | ${dut_to_tg_if2}
 110 | | ... | ${test_dst_ip} | ${tg_to_dut_if2_mac}
 111 | | When Honeycomb configures IPv6 ND proxy on interface
 112 | | ... | ${dut_node} | ${dut_to_tg_if2} | ${test_dst_ip}
 113 | | Then Verify IPv6ND proxy | ${tg_node}
 114 | | ... | ${tg_to_dut_if1} | ${tg_to_dut_if2}
 115 | | ... | ${test_src_ip} | ${test_dst_ip}
 116 | | ... | ${tg_to_dut_if1_mac} | ${tg_to_dut_if2_mac}
 117 | | ... | ${dut_to_tg_if1_mac} | ${dut_to_tg_if2_mac}