tests/vpp/func/honeycomb/mgmt-cfg-vxlan-apihc-apivat-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Variables ***
  15 # Interfaces to run tests on.
  16 | ${interface}= | ${node['interfaces']['port1']['name']}
  17 | ${vx_interface}= | vx_tunnel_test
  18 # Configuration which will be set and verified during tests.
  19 | &{vxlan_settings}= | src=192.168.0.2 | dst=192.168.0.3 | vni=${88}
  20 | ... | encap-vrf-id=${0}
  21 | &{vxlan_settings2}= | src=192.168.0.4 | dst=192.168.0.5 | vni=${47}
  22 | ... | encap-vrf-id=${0}
  23 | &{vxlan_settings_ipv6}= | src=10::10 | dst=10::11 | vni=${88}
  24 | ... | encap-vrf-id=${0}
  25
  26 *** Settings ***
  27 | Resource | resources/libraries/robot/shared/default.robot
  28 | Resource | resources/libraries/robot/honeycomb/honeycomb.robot
  29 | Resource | resources/libraries/robot/honeycomb/interfaces.robot
  30 | Resource | resources/libraries/robot/honeycomb/vxlan.robot
  31 # import additional VxLAN settings from resource file
  32 | Variables | resources/test_data/honeycomb/vxlan.py
  33 | ...
  34 | Force Tags | HC_FUNC
  35 | ...
  36 | Suite Setup | Set Up Honeycomb Functional Test Suite | ${node}
  37 | ...
  38 | Suite Teardown | Tear Down Honeycomb Functional Test Suite | ${node}
  39 | ...
  40 | Documentation | *Honeycomb VxLAN management test suite.*
  41
  42 *** Test Cases ***
  43 | TC01: Honeycomb configures VxLAN tunnel
  44 | | [Documentation] | Check if Honeycomb API can configure VxLAN settings.
  45 | | ...
  46 | | Given VxLAN Operational Data From Honeycomb Should Be empty
  47 | | ... | ${node} | ${vx_interface}
  48 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
  49 | | When Honeycomb sets interface VxLAN configuration
  50 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  51 | | Then VxLAN Operational Data From Honeycomb Should Be
  52 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  53 | | And VxLAN Operational Data From VAT Should Be
  54 | | ... | ${node} | ${vxlan_settings}
  55 | | ${vxlan_index}= | Get interface index from oper data
  56 | | ... | ${node} | ${vx_interface}
  57 | | Set Suite Variable | ${vxlan_index}
  58
  59 | TC02: Honeycomb disables VxLAN tunnel
  60 | | [Documentation] | Check if Honeycomb API can reset VxLAN configuration.
  61 | | ...
  62 | | Given VxLAN Operational Data From Honeycomb Should Be
  63 | | ... | ${node} | ${vx_interface} | ${vxlan_settings}
  64 | | And Honeycomb should not show disabled interface in oper data
  65 | | ... | ${node} | ${vxlan_index}
  66 | | And VxLAN Operational Data From VAT Should Be
  67 | | ... | ${node} | ${vxlan_settings}
  68 | | When Honeycomb removes VxLAN tunnel settings | ${node} | ${vx_interface}
  69 | | Then VxLAN Operational Data From Honeycomb Should Be empty
  70 | | ... | ${node} | ${vx_interface}
  71 | | And Honeycomb should show disabled interface in oper data
  72 | | ... | ${node} | ${vxlan_index}
  73 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
  74
  75 | TC03: Honeycomb can configure VXLAN tunnel after one has been disabled
  76 | | [Documentation] | Check if Honeycomb API can configure VxLAN settings again\
  77 | | ... | after previous settings have been removed.
  78 | | ...
  79 | | [Teardown] | Honeycomb removes VxLAN tunnel settings
  80 | | ... | ${node} | ${vx_interface}
  81 | | ...
  82 | | Given VxLAN Operational Data From Honeycomb Should Be empty
  83 | | ... | ${node} | ${vx_interface}
  84 | | And Honeycomb should show disabled interface in oper data
  85 | | ... | ${node} | ${vxlan_index}
  86 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
  87 | | When Honeycomb sets interface VxLAN configuration
  88 | | ... | ${node} | ${vx_interface} | ${vxlan_settings2}
  89 | | Then VxLAN Operational Data From Honeycomb Should Be
  90 | | ... | ${node} | ${vx_interface} | ${vxlan_settings2}
  91 | | And Honeycomb should not show disabled interface in oper data
  92 | | ... | ${node} | ${vxlan_index}
  93 | | And VxLAN Operational Data From VAT Should Be
  94 | | ... | ${node} | ${vxlan_settings2}
  95
  96 | TC04: Honeycomb does not set VxLAN configuration on another interface type
  97 | | [Documentation] | Check if Honeycomb API prevents setting VxLAN\
  98 | | ... | on incorrect interface.
  99 | | ...
 100 | | Given VxLAN Operational Data From Honeycomb Should Be empty
 101 | | ... | ${node} | ${interface}
 102 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
 103 | | When Honeycomb fails setting VxLan on different interface type
 104 | | ... | ${node} | ${interface} | ${vxlan_settings2}
 105 | | Then VxLAN Operational Data From Honeycomb Should Be empty
 106 | | ... | ${node} | ${interface}
 107 | | And VxLAN Operational Data From VAT Should Be empty
 108 | | ... | ${node}
 109
 110 | TC05: Honeycomb does not set invalid VxLAN configuration
 111 | | [Documentation] | Check if Honeycomb API prevents setting incorrect VxLAN\
 112 | | ... | settings.
 113 | | ...
 114 | | Given VxLAN Operational Data From Honeycomb Should Be empty
 115 | | ... | ${node} | ${vx_interface}
 116 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
 117 | | When Honeycomb fails setting invalid VxLAN configuration
 118 | | ... | ${node} | ${vx_interface} | ${vxlan_invalid}
 119 | | Then VxLAN Operational Data From Honeycomb Should Be empty
 120 | | ... | ${node} | ${vx_interface}
 121
 122 | TC06: Honeycomb configures VxLAN tunnel with ipv6
 123 | | [Documentation] | Check if Honeycomb API can configure VxLAN with\
 124 | | ... | ipv6 settings.
 125 | | ...
 126 | | [Teardown] | Honeycomb removes VxLAN tunnel settings
 127 | | ... | ${node} | ${vx_interface}
 128 | | ...
 129 | | Given VxLAN Operational Data From Honeycomb Should Be empty
 130 | | ... | ${node} | ${vx_interface}
 131 | | And VxLAN Operational Data From VAT Should Be empty | ${node}
 132 | | When Honeycomb sets interface VxLAN configuration
 133 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
 134 | | Then VxLAN Operational Data From Honeycomb Should Be
 135 | | ... | ${node} | ${vx_interface} | ${vxlan_settings_ipv6}
 136 | | And VxLAN Operational Data From VAT Should Be
 137 | | ... | ${node} | ${vxlan_settings_ipv6}