tests/vpp/func/interfaces/api-crud-tap-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/ip/ip4.robot
  17 | Resource | resources/libraries/robot/ip/ip6.robot
  18 | Resource | resources/libraries/robot/shared/interfaces.robot
  19 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  20 | Resource | resources/libraries/robot/shared/testing_path.robot
  21 | Resource | resources/libraries/robot/shared/traffic.robot
  22 | Library  | resources.libraries.python.Trace
  23 | Library  | resources.libraries.python.Tap
  24 | Library  | resources.libraries.python.Namespaces
  25 | Library  | resources.libraries.python.IPUtil
  26 | ...
  27 | Force Tags | HW_ENV | VM_ENV | 3_NODE_DOUBLE_LINK_TOPO
  28 | ...
  29 | Test Setup | Set up TAP functional test
  30 | ...
  31 | Test Teardown | Tear down TAP functional test
  32 | ...
  33 | Documentation | *Tap Interface CRUD Tests*
  34 | ... | *[Top] Network Topologies:* TG=DUT1 2-node topology with two links
  35 | ... | between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* No packet sent.
  37 | ... | *[Cfg] DUT configuration:* Add/Modify/Delete linux-TAP on DUT1.
  38 | ... | *[Ver] Verification:* Check dump of tap interfaces for correctness.
  39 | ... | *[Ref] Applicable standard specifications:*
  40
  41 *** Variables ***
  42 | ${tap_int1}= | tap_int1
  43 | ${tap_int2}= | tap_int2
  44 | ${mod_tap_name}= | tap_int1MOD
  45
  46 *** Test Cases ***
  47 | TC01: Tap Interface Modify And Delete
  48 | | [Documentation]
  49 | | ... | [Top] TG-DUT1-TG.
  50 | | ... | [Enc] Eth-IPv4-ICMPv4.
  51 | | ... | [Cfg] Set two TAP interfaces.
  52 | | ... | [Ver] Verify that TAP interface can be modified, deleted, and no\
  53 | | ... | other TAP interface is affected.
  54 | | ...
  55 | | Given Configure path in 2-node circular topology | ${nodes['TG']}
  56 | | ... | ${nodes['DUT1']} | ${nodes['TG']}
  57 | | And Set interfaces in 2-node circular topology up
  58 | | ${int1}= | And Add Tap Interface | ${dut_node} | ${tap_int1}
  59 | | ${int2}= | And Add Tap Interface | ${dut_node} | ${tap_int2}
  60 | | And Set Interface State | ${dut_node} | ${int1} | up
  61 | | And Set Interface State | ${dut_node} | ${int2} | up
  62 | | When Modify Tap Interface | ${dut_node} | ${int1} | ${mod_tap_name}
  63 | | Then Check Tap Present | ${dut_node} | ${mod_tap_name}
  64 | | When Delete Tap Interface | ${dut_node} | ${int1}
  65 | | Then Run Keyword And Expect Error
  66 | | ... | Tap interface :${mod_tap_name} does not exist
  67 | | ... | Check Tap Present | ${dut_node} | ${mod_tap_name}
  68 | | And Check Tap Present | ${dut_node} | ${tap_int2}
  69 | | When Delete Tap Interface | ${dut_node} | ${int2}
  70 | | Then Run Keyword And Expect Error
  71 | | ... | ValueError: No JSON object could be decoded
  72 | | ... | Check Tap Present | ${dut_node} | ${tap_int2}