tests/vpp/func/ip4_tunnels/vxlan/eth2p-ethip4vxlan-l2bdbasemaclrn-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/shared/testing_path.robot
  17 | Resource | resources/libraries/robot/overlay/vxlan.robot
  18 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV | SKIP_VPP_PATCH
  21 | Test Setup | Set up functional test
  22 | Test Teardown | Tear down functional test
  23 | Documentation | *Bridge-domain with VXLAN test cases - IPv4*
  24 | ...
  25 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  26 | ... | with single links between nodes.
  27 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on
  28 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for L2 switching of IPv4.
  29 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  30 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled;
  31 | ... | VXLAN tunnels are configured between L2BDs on DUT1 and DUT2.
  32 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent
  33 | ... | in both directions by TG on links to DUT1 and DUT2; on receive TG
  34 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr
  35 | ... | and MAC addresses.
  36 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  37
  38 *** Variables ***
  39 | ${vni_1}= | 23
  40 | ${vni_2}= | 35
  41
  42 | ${bd_id1}= | 10
  43 | ${bd_id2}= | 20
  44 | ${bd_id3}= | 30
  45 | ${shg1}= | 1
  46 | ${shg2}= | 2
  47
  48 | ${ip4_addr1}= | 172.16.0.1
  49 | ${ip4_addr2}= | 172.16.0.2
  50 | ${ip4_prefix}= | 24
  51
  52 *** Test Cases ***
  53 | TC01: DUT1 and DUT2 with L2BD and VXLANoIPv4 tunnels switch ICMPv4 between TG links
  54 | | [Documentation]
  55 | | ... | [Top] TG-DUT1-DUT2-TG. [Enc] Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on \
  56 | | ... | DUT1-DUT2; Eth-IPv4-ICMPv4 on TG-DUTn. [Cfg] On DUT1 and DUT2
  57 | | ... | configure two i/fs into L2BD with MAC learning. [Ver] Make TG
  58 | | ... | verify ICMPv4 Echo Req pkts are switched thru DUT1 and DUT2 in
  59 | | ... | both directions and are correct on receive. [Ref] RFC7348.
  60 | | Given Configure path in 3-node circular topology
  61 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  62 | | And Set interfaces in 3-node circular topology up
  63 | | ${dut1_to_dut2_name}= | Get interface name | ${dut1_node} | ${dut1_to_dut2}
  64 | | ${dut2_to_dut1_name}= | Get interface name | ${dut2_node} | ${dut2_to_dut1}
  65 | | And Configure IP addresses and neighbors on interfaces
  66 | | ... | ${dut1_node} | ${dut1_to_dut2_name} | ${NONE} | ${dut2_node}
  67 | | ... | ${dut2_to_dut1_name} | ${NONE}
  68 | | ${dut1s_vxlan}= | When Create VXLAN interface     | ${dut1_node} | ${vni_1}
  69 | |                 | ... | ${dut1s_ip_address} | ${dut2s_ip_address}
  70 | | And Add interfaces to L2BD
  71 | | ... | ${dut1_node} | ${bd_id1} | ${dut1_to_tg} | ${dut1s_vxlan}
  72 | | ${dut2s_vxlan}= | And Create VXLAN interface | ${dut2_node} | ${vni_1}
  73 | |                 | ... | ${dut2s_ip_address} | ${dut1s_ip_address}
  74 | | And Add interfaces to L2BD
  75 | | ... | ${dut2_node} | ${bd_id1} | ${dut2_to_tg} | ${dut2s_vxlan}
  76 | | Then Send ICMPv4 bidirectionally and verify received packets
  77 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}