tests/vpp/func/ip4_tunnels/vxlan/eth2p-ethip4vxlan-l2bdbasemaclrn-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/shared/testing_path.robot
  17 | Resource | resources/libraries/robot/overlay/vxlan.robot
  18 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  19 | Resource | resources/libraries/robot/vm/qemu.robot
  20 | Resource | resources/libraries/robot/vm/double_qemu_setup.robot
  21 | Library  | resources.libraries.python.Trace
  22 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV | SKIP_VPP_PATCH
  23 | Test Setup | Set up functional test
  24 | Test Teardown | Tear down functional test
  25 | Documentation | *Bridge-domain with VXLAN test cases - IPv4*
  26 | ...
  27 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  28 | ... | with single links between nodes.
  29 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on
  30 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for L2 switching of IPv4.
  31 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  32 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled;
  33 | ... | VXLAN tunnels are configured between L2BDs on DUT1 and DUT2.
  34 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent
  35 | ... | in both directions by TG on links to DUT1 and DUT2; on receive TG
  36 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr
  37 | ... | and MAC addresses.
  38 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  39
  40 *** Variables ***
  41 | ${vni_1}= | 23
  42 | ${vni_2}= | 35
  43
  44 | ${bd_id1}= | 10
  45 | ${bd_id2}= | 20
  46 | ${bd_id3}= | 30
  47 | ${shg1}= | 1
  48 | ${shg2}= | 2
  49
  50 | ${ip4_addr1}= | 172.16.0.1
  51 | ${ip4_addr2}= | 172.16.0.2
  52 | ${ip4_prefix}= | 24
  53
  54 *** Test Cases ***
  55 | TC01: DUT1 and DUT2 with L2BD and VXLANoIPv4 tunnels switch ICMPv4 between TG links
  56 | | [Documentation]
  57 | | ... | [Top] TG-DUT1-DUT2-TG. [Enc] Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on \
  58 | | ... | DUT1-DUT2; Eth-IPv4-ICMPv4 on TG-DUTn. [Cfg] On DUT1 and DUT2
  59 | | ... | configure two i/fs into L2BD with MAC learning. [Ver] Make TG
  60 | | ... | verify ICMPv4 Echo Req pkts are switched thru DUT1 and DUT2 in
  61 | | ... | both directions and are correct on receive. [Ref] RFC7348.
  62 | | Given Configure path in 3-node circular topology
  63 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  64 | | And Set interfaces in 3-node circular topology up
  65 | | ${dut1_to_dut2_name}= | Get interface name | ${dut1_node} | ${dut1_to_dut2}
  66 | | ${dut2_to_dut1_name}= | Get interface name | ${dut2_node} | ${dut2_to_dut1}
  67 | | And Configure IP addresses and neighbors on interfaces
  68 | | ... | ${dut1_node} | ${dut1_to_dut2_name} | ${NONE} | ${dut2_node}
  69 | | ... | ${dut2_to_dut1_name} | ${NONE}
  70 | | ${dut1s_vxlan}= | When Create VXLAN interface     | ${dut1_node} | ${vni_1}
  71 | |                 | ... | ${dut1s_ip_address} | ${dut2s_ip_address}
  72 | | And Add interfaces to L2BD
  73 | | ... | ${dut1_node} | ${bd_id1} | ${dut1_to_tg} | ${dut1s_vxlan}
  74 | | ${dut2s_vxlan}= | And Create VXLAN interface | ${dut2_node} | ${vni_1}
  75 | |                 | ... | ${dut2s_ip_address} | ${dut1s_ip_address}
  76 | | And Add interfaces to L2BD
  77 | | ... | ${dut2_node} | ${bd_id1} | ${dut2_to_tg} | ${dut2s_vxlan}
  78 | | Then Send ICMPv4 bidirectionally and verify received packets
  79 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}