tests/vpp/func/ip6_tunnels/vxlan/eth2p-ethip6vxlan-l2bdbasemaclrn-func.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library  | resources.libraries.python.IPUtil
  16 | Library  | resources.libraries.python.Trace
  17 | ...
  18 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  19 | Resource | resources/libraries/robot/overlay/vxlan.robot
  20 | Resource | resources/libraries/robot/shared/default.robot
  21 | Resource | resources/libraries/robot/shared/testing_path.robot
  22 | ...
  23 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV
  24 | ...
  25 | Test Setup | Set up functional test
  26 | ...
  27 | Test Teardown | Tear down functional test
  28 | ...
  29 | Documentation | *Bridge-domain with VXLAN test cases - IPv6*
  30 | ...
  31 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet encapsulations:* Eth-IPv6-VXLAN-Eth-IPv6-ICMPv6 on
  34 | ... | DUT1-DUT2, Eth-IPv6-ICMPv6 on TG-DUTn for L2 switching of IPv6.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  36 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled;
  37 | ... | VXLAN tunnels are configured between L2BDs on DUT1 and DUT2.
  38 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent
  39 | ... | in both directions by TG on links to DUT1 and DUT2; on receive TG
  40 | ... | verifies packets for correctness and their IPv6 src-addr, dst-addr
  41 | ... | and MAC addresses.
  42 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  43
  44 *** Variables ***
  45 | ${vni_1}= | 23
  46
  47 | ${bd_id1}= | 10
  48
  49 | ${ip6_addr1}= | 3ffe:64::1
  50 | ${ip6_addr2}= | 3ffe:64::2
  51 | ${ip6_prefix}= | 64
  52
  53 *** Test Cases ***
  54 | TC01: DUT1 and DUT2 with L2BD and VXLANoIPv6 tunnels switch ICMPv6 between TG links
  55 | | [Documentation]
  56 | | ... | [Top] TG=DUT1=DUT2=TG.[Enc] Eth-IPv6-VXLAN-Eth-IPv6-ICMPv6 on \
  57 | | ... | DUT1-DUT2, Eth-IPv6-ICMPv6 on TG-DUTn. [Cfg] On DUT1 and DUT2
  58 | | ... | configure L2 bridge-domain (MAC learning enabled), each with one
  59 | | ... | interface to TG and one VXLAN tunnel interface towards the other
  60 | | ... | DUT. [Ver] Make TG send ICMPv6 Echo Req between two of its
  61 | | ... | interfaces to be switched by DUT1 and DUT2; verify all packets
  62 | | ... | are received. [Ref] RFC7348.
  63 | | [Tags] | 3_NODE_DOUBLE_LINK_TOPO
  64 | | Given Configure path in 3-node circular topology
  65 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  66 | | And Set interfaces in 3-node circular topology up
  67 | | And VPP Interface Set IP Address
  68 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${ip6_addr1} | ${ip6_prefix}
  69 | | And VPP Interface Set IP Address
  70 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${ip6_addr2} | ${ip6_prefix}
  71 | | And VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${ip6_addr2}
  72 | | And VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${ip6_addr1}
  73 | | And Vpp All RA Suppress Link Layer | ${nodes}
  74 | | ${dut1s_vxlan}= | When Create VXLAN interface
  75 | | ... | ${dut1_node} | ${vni_1} | ${ip6_addr1} | ${ip6_addr2}
  76 | | And Add interfaces to L2BD
  77 | | ... | ${dut1_node} | ${bd_id1} | ${dut1_to_tg} | ${dut1s_vxlan}
  78 | | ${dut2s_vxlan}= | And Create VXLAN interface
  79 | | ... | ${dut2_node} | ${vni_1} | ${ip6_addr2} | ${ip6_addr1}
  80 | | And Add interfaces to L2BD
  81 | | ... | ${dut2_node} | ${bd_id1} | ${dut2_to_tg} | ${dut2s_vxlan}
  82 | | Then Send ICMPv6 bidirectionally and verify received packets
  83 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}
  84 | | And Get VXLAN dump | ${dut1_node}
  85 | | And Get VXLAN dump | ${dut1_node} | interface=vxlan_tunnel0
  86 | | And Get VXLAN dump | ${dut2_node} | interface=${dut2s_vxlan}