tests/vpp/func/l2bd/eth4p-eth-l2bdbasemaclrn-l2shg-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  17 | Resource | resources/libraries/robot/shared/testing_path.robot
  18 | Resource | resources/libraries/robot/vm/qemu.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | HW_ENV | VM_ENV
  21 | Test Setup | Set up functional test
  22 | Test Teardown | Tear down functional test
  23 | Documentation | *L2 bridge-domain test cases*
  24 | ...
  25 | ... | *[Top] Network Topologies:* TG=DUT1=DUT2=TG 3-node circular topology
  26 | ... | with double parallel links.
  27 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-ICMPv4 for L2 switching of
  28 | ... | IPv4; Eth-IPv6-ICMPv6 for L2 switching of IPv6 use. Both apply
  29 | ... | to all links.
  30 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  31 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled
  32 | ... | and Split Horizon Groups (SHG).
  33 | ... | *[Ver] TG verification:* Test ICMPv4 (or ICMPv6) Echo Request packets
  34 | ... | are sent in both directions by TG on links to DUT1 and DUT2; on
  35 | ... | receive TG verifies packets for correctness and their IPv4 (IPv6)
  36 | ... | src-addr, dst-addr and MAC addresses.
  37 | ... | *[Ref] Applicable standard specifications:*
  38
  39 *** Variables ***
  40 | ${bd_id1}= | 1
  41 | ${bd_id2}= | 2
  42
  43 | ${shg1}= | 3
  44 | ${shg2}= | 4
  45
  46 *** Test Cases ***
  47 | TC01: DUT1 and DUT2 with L2BD (MAC learn) and SHG switch between four TG links
  48 | | [Documentation]
  49 | | ... | [Top] TG=DUT1=DUT2=TG. [Enc] Eth-IPv4-ICMPv4. [Cfg] On DUT1 and \
  50 | | ... | DUT2 configure four i/fs into L2BD with MAC learning and the
  51 | | ... | same SHG on i/fs towards TG. [Ver] Make TG verify ICMPv4 Echo
  52 | | ... | Req pkts are switched thru DUT1 and DUT2 in both directions and
  53 | | ... | are correct on receive; verify no pkts are switched thru SHG
  54 | | ... | isolated interfaces. [Ref]
  55 | | [Tags] | 3_NODE_DOUBLE_LINK_TOPO
  56 | | Given Configure path for 3-node BD-SHG test | ${nodes['TG']}
  57 | | ... | ${nodes['DUT1']} | ${nodes['DUT2']}
  58 | | And Set interfaces in 3-node BD-SHG test up
  59 | | When Create bridge domain | ${dut1_node} | ${bd_id1}
  60 | | And Add interface to bridge domain | ${dut1_node} | ${dut1_to_tg_if1}
  61 | | ... | ${bd_id1} | ${shg1}
  62 | | And Add interface to bridge domain | ${dut1_node} | ${dut1_to_tg_if2}
  63 | | ... | ${bd_id1} | ${shg1}
  64 | | And Add interface to bridge domain | ${dut1_node} | ${dut1_to_dut2}
  65 | | ... | ${bd_id1}
  66 | | And Create bridge domain | ${dut2_node} | ${bd_id2}
  67 | | And Add interface to bridge domain | ${dut2_node} | ${dut2_to_tg_if1}
  68 | | ... | ${bd_id2} | ${shg2}
  69 | | And Add interface to bridge domain | ${dut2_node} | ${dut2_to_tg_if2}
  70 | | ... | ${bd_id2} | ${shg2}
  71 | | And Add interface to bridge domain | ${dut2_node} | ${dut2_to_dut1}
  72 | | ... | ${bd_id2}
  73 | | Then Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
  74 | | ... | ${tg_to_dut1_if1} | ${tg_to_dut2_if1}
  75 | | And Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
  76 | | ... | ${tg_to_dut1_if1} | ${tg_to_dut2_if2}
  77 | | And Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
  78 | | ... | ${tg_to_dut1_if2} | ${tg_to_dut2_if1}
  79 | | And Send ICMPv4 bidirectionally and verify received packets | ${tg_node}
  80 | | ... | ${tg_to_dut1_if2} | ${tg_to_dut2_if2}
  81 | | And Run Keyword And Expect Error | ICMP echo Rx timeout
  82 | | ... | Send ICMPv4 bidirectionally and verify received packets
  83 | | | ... | ${tg_node} | ${tg_to_dut1_if1} | ${tg_to_dut1_if2}
  84 | | And Run Keyword And Expect Error | ICMP echo Rx timeout
  85 | | ... | Send ICMPv4 bidirectionally and verify received packets
  86 | | | ... | ${tg_node} | ${tg_to_dut2_if1} | ${tg_to_dut2_if2}