tests/vpp/func/vm_vhost/ip6/eth2p-ethip6lispgpe-ip6basevrf-eth-2vhost-1vm-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Library | resources.libraries.python.topology.Topology
  16 | Library | resources.libraries.python.NodePath
  17 | Library | resources.libraries.python.Trace
  18 | Library | resources.libraries.python.IPUtil
  19 | Library | resources.libraries.python.IPv6Setup
  20 | Library | resources.libraries.python.VPPUtil
  21 | Resource | resources/libraries/robot/shared/traffic.robot
  22 | Resource | resources/libraries/robot/shared/default.robot
  23 | Resource | resources/libraries/robot/shared/interfaces.robot
  24 | Resource | resources/libraries/robot/shared/testing_path.robot
  25 | Resource | resources/libraries/robot/l2/l2_bridge_domain.robot
  26 | Resource | resources/libraries/robot/overlay/lispgpe.robot
  27 # Import configuration and test data:
  28 | Variables | resources/test_data/lisp/ipv6_lispgpe_ipv6/ipv6_lispgpe_ipv6.py
  29 | ...
  30 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | LISP
  31 | ...
  32 | Test Setup | Run Keywords | Set up functional test
  33 | ... | AND | Vpp All Ra Suppress Link Layer | ${nodes}
  34 | ...
  35 | Test Teardown | Tear down LISP functional test with QEMU
  36 | ...
  37 | Documentation | *ip6-lispgpe-ip6 encapsulation test cases*
  38 | ...
  39 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  40 | ... | with single links between nodes.
  41 | ... | *[Enc] Packet Encapsulations:* Eth-IPv6-LISP-IPv6-ICMPv6 on DUT1-DUT2,\
  42 | ... | Eth-IPv6-ICMPv6 on TG-DUTn for IPv6 routing over LISPoIPv6 tunnel.
  43 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv6\
  44 | ... | routing and static routes. LISPoIPv6 tunnel is configured between\
  45 | ... | DUT1 and DUT2.
  46 | ... | *[Ver] TG verification:* Test ICMPv6 Echo Request packets are sent in\
  47 | ... | both directions by TG on links to DUT1 and DUT2; on receive\
  48 | ... | TG verifies packets for correctness and their IPv6 src-addr, dst-addr\
  49 | ... | and MAC addresses.
  50 | ... | *[Ref] Applicable standard specifications:* RFC6830.
  51
  52 *** Test Cases ***
  53 | TC01: DUT1 and DUT2 route IPv6 bidirectionally over LISP GPE tunnel using vhost interfaces and VRF is enabled
  54 | | [Documentation]
  55 | | ... | [Top] TG-DUT1-DUT2-TG.
  56 | | ... | [Enc] Eth-IPv6-LISPGPE-IPv6-ICMPv6 on DUT1-DUT2, Eth-IPv6-ICMPv6 on\
  57 | | ... | TG-DUTn.
  58 | | ... | [Cfg] Configure IPv6 LISP static adjacencies on DUT1 and DUT2.
  59 | | ... | [Ver] Case: ip6-lispgpe-ip6 - vrf, virt2lisp
  60 | | ... | Make TG send ICMPv6 Echo Req between its interfaces across both\
  61 | | ... | DUTs and LISP GPE tunnel between them; verify IPv6 headers on\
  62 | | ... | received packets are correct.
  63 | | ... | [Ref] RFC6830.
  64 | | ...
  65 | | ...
  66 | | Given Configure path in 3-node circular topology
  67 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  68 | | And Set interfaces in 3-node circular topology up
  69 | | And Add Fib Table | ${dut1_node} | ${fib_table_1} | ipv6=${TRUE}
  70 | | And Add Fib Table | ${dut2_node} | ${fib_table_1} | ipv6=${TRUE}
  71 | | And Assign Interface To Fib Table | ${dut1_node}
  72 | | ... | ${dut1_to_tg} | ${fib_table_1} | ipv6=${TRUE}
  73 | | And Assign Interface To Fib Table | ${dut2_node}
  74 | | ... | ${dut2_to_tg} | ${fib_table_1} | ipv6=${TRUE}
  75 | | And Vpp Set If IPv6 Addr
  76 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${dut1_to_dut2_ip6} | ${prefix6}
  77 | | And Vpp Set If IPv6 Addr
  78 | | ... | ${dut1_node} | ${dut1_to_tg} | ${dut1_to_tg_ip6} | ${prefix6}
  79 | | And Vpp Set If IPv6 Addr
  80 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${dut2_to_dut1_ip6} | ${prefix6}
  81 | | And Vpp Set If IPv6 Addr
  82 | | ... | ${dut2_node} | ${dut2_to_tg} | ${dut2_to_tg_ip6} | ${prefix6}
  83 | | And Add IP Neighbors
  84 | | And Vpp All RA Suppress Link Layer | ${nodes}
  85 | | When Configure LISP GPE topology in 3-node circular topology
  86 | | ... | ${dut1_node} | ${dut1_to_dut2} | ${NONE}
  87 | | ... | ${dut2_node} | ${dut2_to_dut1} | ${NONE}
  88 | | ... | ${duts_locator_set} | ${dut1_ip6_eid} | ${dut2_ip6_eid}
  89 | | ... | ${dut1_to_dut2_ip6_static_adjacency}
  90 | | ... | ${dut2_to_dut1_ip6_static_adjacency}
  91 | | ... | ${dut1_dut2_vni} | ${fib_table_1}
  92 | | And Setup Qemu DUT1 | ${fib_table_1}
  93 | | Then Send packet and verify headers
  94 | | ... | ${tg_node} | ${tg1_ip6} | ${tg2_ip6}
  95 | | ... | ${tg_to_dut1} | ${tg_to_dut1_mac} | ${dst_vhost_mac}
  96 | | ... | ${tg_to_dut2} | ${dut2_to_tg_mac} | ${tg_to_dut2_mac}
  97 | | And Send packet and verify headers
  98 | | ... | ${tg_node} | ${tg2_ip6} | ${tg1_ip6}
  99 | | ... | ${tg_to_dut2} | ${tg_to_dut2_mac} | ${dut2_to_tg_mac}
 100 | | ... | ${tg_to_dut1} | ${dut1_to_tg_mac} | ${tg_to_dut1_mac}
 101
 102 *** Keywords ***
 103 | Setup Qemu DUT1
 104 | | [Documentation] | Setup Vhosts on DUT1 and setup IP on one of them. Setup\
 105 | | ... | Qemu and bridge the vhosts. Optionally, you can set fib table ID\
 106 | | ... | where the vhost2 interface should be assigned to.
 107 | | ...
 108 | | [Arguments] | ${fib_table}=0
 109 | | ...
 110 | | ${vhost1}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock1}
 111 | | ${vhost2}= | Vpp Create Vhost User Interface | ${dut1_node} | ${sock2}
 112 | | And Add Fib Table | ${dut1_node} | ${fib_table} | ipv6=${TRUE}
 113 | | Assign Interface To Fib Table | ${dut1_node}
 114 | | ... | ${vhost2} | ${fib_table} | ipv6=${TRUE}
 115 | | Vpp Set If IPv6 Addr | ${dut1_node} | ${vhost2} | ${vhost_ip}
 116 | | ... | ${prefix6}
 117 | | Set Interface State | ${dut1_node} | ${vhost1} | up
 118 | | Set Interface State | ${dut1_node} | ${vhost2} | up
 119 | | Create bridge domain | ${dut1_node} | ${bid} | learn=${TRUE}
 120 | | Add interface to bridge domain | ${dut1_node}
 121 | | ... | ${dut1_to_tg} | ${bid} | 0
 122 | | Add interface to bridge domain | ${dut1_node}
 123 | | ... | ${vhost1} | ${bid} | 0
 124 | | ${vhost_mac}= | Get Vhost User Mac By SW Index | ${dut1_node} | ${vhost2}
 125 | | Set test variable | ${dst_vhost_mac} | ${vhost_mac}
 126 | | Configure VM for vhost L2BD forwarding | ${dut1_node} | ${sock1} | ${sock2}
 127
 128 | Add IP Neighbors
 129 | | [Documentation]
 130 | | ... | Add IP neighbors to physical interfaces on DUTs.
 131 | | ...
 132 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_tg} | ${tg1_ip6}
 133 | | ... | ${tg_to_dut1_mac}
 134 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_tg} | ${tg2_ip6}
 135 | | ... | ${tg_to_dut2_mac}
 136 | | Add IP Neighbor | ${dut1_node} | ${dut1_to_dut2} | ${dut2_to_dut1_ip6}
 137 | | ... | ${dut2_to_dut1_mac}
 138 | | Add IP Neighbor | ${dut2_node} | ${dut2_to_dut1} | ${dut1_to_dut2_ip6}
 139 | | ... | ${dut1_to_dut2_mac}