tests/vpp/func/vm_vhost/l2bd/eth2p-ethip4vxlan-l2bdbasemaclrn-eth-2vhost-1vm-func.robot

   1 # Copyright (c) 2016 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/shared/testing_path.robot
  17 | Resource | resources/libraries/robot/overlay/vxlan.robot
  18 | Resource | resources/libraries/robot/l2/l2_traffic.robot
  19 | Library  | resources.libraries.python.Trace
  20 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | VM_ENV | HW_ENV | VPP_VM_ENV
  21 | Test Setup | Set up functional test
  22 | Test Teardown | Run Keywords | Tear down functional test
  23 | ... | AND | Run keyword | Tear down QEMU | ${qemu1}
  24 | ... | AND | Run keyword | Tear down QEMU | ${qemu2}
  25 | Documentation | *L2BD with VM combined with VXLAN test cases - IPv4*
  26 | ...
  27 | ... | *[Top] Network topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  28 | ... | with single links between nodes.
  29 | ... | *[Enc] Packet encapsulations:* Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on
  30 | ... | DUT1-DUT2, Eth-IPv4-ICMPv4 on TG-DUTn for L2 switching of IPv4.
  31 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with L2
  32 | ... | bridge-domain (L2BD) switching combined with MAC learning enabled;
  33 | ... | VXLAN tunnels are configured between L2BDs on DUT1 and DUT2.
  34 | ... | *[Ver] TG verification:* Test ICMPv4 Echo Request packets are sent
  35 | ... | in both directions by TG on links to DUT1 and DUT2; on receive TG
  36 | ... | verifies packets for correctness and their IPv4 src-addr, dst-addr
  37 | ... | and MAC addresses.
  38 | ... | *[Ref] Applicable standard specifications:* RFC7348.
  39
  40 *** Variables ***
  41 | ${vni_1}= | 23
  42
  43 | ${bd_id1}= | 10
  44 | ${bd_id2}= | 20
  45
  46 | ${ip4_addr1}= | 172.16.0.1
  47 | ${ip4_addr2}= | 172.16.0.2
  48 | ${ip4_prefix}= | 24
  49
  50 | ${sock1}= | /tmp/sock1
  51 | ${sock2}= | /tmp/sock2
  52
  53 | ${qemu1}= | qemu_instance_1
  54 | ${qemu2}= | qemu_instance_2
  55
  56 | ${dut1_vhost1}= | dut1_vhost_if1
  57 | ${dut1_vhost2}= | dut1_vhost_if2
  58 | ${dut2_vhost1}= | dut2_vhost_if1
  59 | ${dut2_vhost2}= | dut2_vhost_if2
  60
  61 *** Test Cases ***
  62 | TC01:DUT1 and DUT2 with two L2BDs and VXLANoIPv4 tunnel switch ICMPv4 between TG links and VM links
  63 | | [Documentation]
  64 | | ... | [Top] TG-DUT1-VM-DUT1-DUT2-VM-DUT2-TG.
  65 | | ... | [Enc] Eth-IPv4-VXLAN-Eth-IPv4-ICMPv4 on DUT1-DUT2; Eth-IPv4-ICMPv4
  66 | | ... | on TG-DUTn and DUTn=VM.
  67 | | ... | [Cfg] On both DUTs configure two L2BDs (MAC learning enabled); first
  68 | | ... | L2BD with untagged interface to TG and vhost-user interface to local
  69 | | ... | VM, second one with vhost-user interface to local VM and VXLAN
  70 | | ... | interface towards the other DUT. Configure linux bridge on both VMs
  71 | | ... | to pass traffic between both vhost-user interfaces.
  72 | | ... | [Ver] Make TG send ICMPv4 Echo Req between two of its interfaces to
  73 | | ... | be switched by DUT1 and DUT2; verify packets are switched between
  74 | | ... | these TG interfaces.
  75 | | ... | [Ref] RFC7348.
  76 | | Given Configure path in 3-node circular topology
  77 | | ... | ${nodes['TG']} | ${nodes['DUT1']} | ${nodes['DUT2']} | ${nodes['TG']}
  78 | | And Set interfaces in 3-node circular topology up
  79 | | When Configure vhost interfaces for L2BD forwarding | ${dut1_node}
  80 | | ...                                                     | ${sock1}
  81 | | ...                                                     | ${sock2}
  82 | | ...                                                     | ${dut1_vhost1}
  83 | | ...                                                     | ${dut1_vhost2}
  84 | | And Configure vhost interfaces for L2BD forwarding | ${dut2_node}
  85 | | ...                                                    | ${sock1}
  86 | | ...                                                    | ${sock2}
  87 | | ...                                                    | ${dut2_vhost1}
  88 | | ...                                                    | ${dut2_vhost2}
  89 | | And Configure VM for vhost L2BD forwarding | ${dut1_node} | ${sock1}
  90 | | ...                                       | ${sock2} | ${qemu1}
  91 | | And Configure VM for vhost L2BD forwarding | ${dut2_node} | ${sock1}
  92 | | ...                                       | ${sock2} | ${qemu2}
  93 | | And Set Interface Address | ${dut1_node} | ${dut1_to_dut2} | ${ip4_addr1}
  94 | | ...                       | ${ip4_prefix}
  95 | | And Set Interface Address | ${dut2_node} | ${dut2_to_dut1} | ${ip4_addr2}
  96 | | ...                       | ${ip4_prefix}
  97 | | And VPP IP Probe | ${dut1_node} | ${dut1_to_dut2} | ${ip4_addr2}
  98 | | And VPP IP Probe | ${dut2_node} | ${dut2_to_dut1} | ${ip4_addr1}
  99 | | ${dut1s_vxlan}= | And Create VXLAN interface | ${dut1_node} | ${vni_1}
 100 | |                 | ...                        | ${ip4_addr1} | ${ip4_addr2}
 101 | | ${dut2s_vxlan}= | And Create VXLAN interface | ${dut2_node} | ${vni_1}
 102 | |                 | ...                        | ${ip4_addr2} | ${ip4_addr1}
 103 | | And Add interfaces to L2BD | ${dut1_node} | ${bd_id1}
 104 | | ...                            | ${dut1_to_tg} | ${${dut1_vhost1}}
 105 | | And Add interfaces to L2BD | ${dut1_node} | ${bd_id2}
 106 | | ...                            | ${dut1s_vxlan} | ${${dut1_vhost2}}
 107 | | And Add interfaces to L2BD | ${dut2_node} | ${bd_id1}
 108 | | ...                            | ${dut2_to_tg} | ${${dut2_vhost1}}
 109 | | And Add interfaces to L2BD | ${dut2_node} | ${bd_id2}
 110 | | ...                            | ${dut2s_vxlan} | ${${dut2_vhost2}}
 111 | | Then Send ICMPv4 bidirectionally and verify received packets
 112 | | ... | ${tg_node} | ${tg_to_dut1} | ${tg_to_dut2}