tests/vpp/perf/container_memif/10ge2p1x520-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X520-DA2 | DOT1Q | L2BDMACLRN | BASE | MEMIF | DOCKER
  19 | ...
  20 | Suite Setup | Run Keywords
  21 | ... | Set up 3-node performance topology with DUT's NIC model | L2
  22 | ... | Intel-X520-DA2
  23 | ... | AND | Set up performance test suite with MEMIF
  24 | ... | AND | Set up performance topology with containers
  25 | ...
  26 | Suite Teardown | Tear down 3-node performance topology with container
  27 | ...
  28 | Test Setup | Run Keywords
  29 | ... | Set up performance test
  30 | ... | AND | Restart VPP in all 'VNF' containers
  31 | ...
  32 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  33 | ... | ${framesize} | ${traffic_profile}
  34 | ...
  35 | Test Template | Local Template
  36 | ...
  37 | Documentation | *RFC2544: Pkt throughput L2BD with memif and IEEE 802.1Q test
  38 | ... | cases*
  39 | ...
  40 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology\
  41 | ... | with single links between nodes.
  42 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for L2 bridge domain. IEEE\
  43 | ... | 802.1Q tagging is applied on link between DUT1 and DUT2.
  44 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with two L2\
  45 | ... | bridge domains and MAC learning enabled. Container is connected to VPP\
  46 | ... | via Memif interface. Container is running same VPP version as running\
  47 | ... | on DUT. Container is limited via cgroup to use 3 cores allocated from\
  48 | ... | pool of isolated CPUs. There are no memory constraints. DUT1 and DUT2\
  49 | ... | tested with 2p10GE NIC X520 Niantic by Intel.
  50 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  51 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop\
  52 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  53 | ... | of packets transmitted. NDR and PDR are discovered for different\
  54 | ... | Ethernet L2 frame sizes using MLRsearch library. Test packets are\
  55 | ... | generated by TG on links to DUTs. TG traffic profile contains two L3\
  56 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  57 | ... | all packets containing Ethernet header, IPv4 header with IP\
  58 | ... | protocol=61 and static payload. MAC addresses are matching MAC\
  59 | ... | addresses of the TG node interfaces.
  60 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  61
  62 *** Variables ***
  63 | ${subid}= | 10
  64 | ${tag_rewrite}= | pop-1
  65 | ${bd_id1}= | 1
  66 | ${bd_id2}= | 2
  67 | ${overhead}= | ${4}
  68 # X520-DA2 bandwidth limit
  69 | ${s_limit}= | ${10000000000}
  70 # Traffic profile:
  71 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src254
  72 # LXC container
  73 | ${container_count}= | ${1}
  74 | ${container_engine}= | Docker
  75 | ${container_image}= | ubuntu:xenial-20180412
  76 | ${container_install_dkms}= | ${FALSE}
  77 | ${container_chain_topology}= | chain
  78 # CPU settings
  79 | ${system_cpus}= | ${1}
  80 | ${vpp_cpus}= | ${5}
  81 | ${container_cpus}= | ${5}
  82
  83 *** Keywords ***
  84 | Local Template
  85 | | [Documentation]
  86 | | ... | [Cfg] Each DUT runs L2BD switching with VLAN and uses ${phy_cores}\
  87 | | ... | physical core(s) for worker threads.
  88 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.
  89 | | ...
  90 | | ... | *Arguments:*
  91 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  92 | | ... | Type: integer, string
  93 | | ... | - phy_cores - Number of physical cores. Type: integer
  94 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  95 | | ...
  96 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  97 | | ...
  98 | | Set Test Variable | ${framesize}
  99 | | Set Test Variable | ${min_rate} | ${10000}
 100 | | ...
 101 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 102 | | And Add PCI devices to all DUTs
 103 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 104 | | ... | ${s_limit} | ${framesize} | overhead=${overhead}
 105 | | And Apply startup configuration on all VPP DUTs
 106 | | When Initialize L2 Bridge Domain with memif pairs and VLAN in circular topology
 107 | | ... | ${bd_id1} | ${bd_id2} | ${subid} | ${tag_rewrite}
 108 | | Then Find NDR and PDR intervals using optimized search
 109 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 110
 111 *** Test Cases ***
 112 | tc01-64B-1c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 113 | | [Tags] | 64B | 1C
 114 | | framesize=${64} | phy_cores=${1}
 115
 116 | tc02-64B-2c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 117 | | [Tags] | 64B | 2C
 118 | | framesize=${64} | phy_cores=${2}
 119
 120 | tc03-64B-4c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 121 | | [Tags] | 64B | 4C
 122 | | framesize=${64} | phy_cores=${4}
 123
 124 | tc04-1518B-1c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 125 | | [Tags] | 1518B | 1C
 126 | | framesize=${1518} | phy_cores=${1}
 127
 128 | tc05-1518B-2c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 129 | | [Tags] | 1518B | 2C
 130 | | framesize=${1518} | phy_cores=${2}
 131
 132 | tc06-1518B-4c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 133 | | [Tags] | 1518B | 4C
 134 | | framesize=${1518} | phy_cores=${4}
 135
 136 | tc07-9000B-1c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 137 | | [Tags] | 9000B | 1C
 138 | | framesize=${9000} | phy_cores=${1}
 139
 140 | tc08-9000B-2c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 141 | | [Tags] | 9000B | 2C
 142 | | framesize=${9000} | phy_cores=${2}
 143
 144 | tc09-9000B-4c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 145 | | [Tags] | 9000B | 4C
 146 | | framesize=${9000} | phy_cores=${4}
 147
 148 | tc10-IMIX-1c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 149 | | [Tags] | IMIX | 1C
 150 | | framesize=IMIX_v4_1 | phy_cores=${1}
 151
 152 | tc11-IMIX-2c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 153 | | [Tags] | IMIX | 2C
 154 | | framesize=IMIX_v4_1 | phy_cores=${2}
 155
 156 | tc12-IMIX-4c-dot1q-l2bdbasemaclrn-eth-2memif-1dcr-ndrpdr
 157 | | [Tags] | IMIX | 4C
 158 | | framesize=IMIX_v4_1 | phy_cores=${4}