tests/vpp/perf/crypto/10ge2p1x553-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECTUN | NIC_Intel-X553 | BASE
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | Intel-X553
  22 | ... | SW_cryptodev
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local Template
  32 | ...
  33 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  38 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
  40 | ... | crypto devices and multiple IPsec tunnels between them. DUTs get IPv4
  41 | ... | traffic from TG, encrypt it and send to another DUT, where packets are
  42 | ... | decrypted and sent back to TG.
  43 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  44 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  45 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  46 | ... | of packets transmitted. NDR and PDR are discovered for different
  47 | ... | Ethernet L2 frame sizes using MLRsearch library.
  48 | ... | Test packets are generated by TG on
  49 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  50 | ... | (flow-group per direction, number of flows per flow-group equals to
  51 | ... | number of IPSec tunnels) with all packets
  52 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  53 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  54 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  55 | ... | is applied to both streams.
  56 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  57
  58 *** Variables ***
  59 # X553 bandwidth limit 20Gbps/2=10Gbps
  60 | ${s_10G}= | ${10000000000}
  61 # X553 Mpps limit 29.76Mpps/2=14.88Mpps
  62 | ${s_14.88Mpps}= | ${14880952}
  63 | ${tg_if1_ip4}= | 192.168.10.2
  64 | ${dut1_if1_ip4}= | 192.168.10.1
  65 | ${dut1_if2_ip4}= | 172.168.1.1
  66 | ${dut2_if1_ip4}= | 172.168.1.2
  67 | ${dut2_if2_ip4}= | 192.168.20.1
  68 | ${tg_if2_ip4}= | 192.168.20.2
  69 | ${raddr_ip4}= | 20.0.0.0
  70 | ${laddr_ip4}= | 10.0.0.0
  71 | ${addr_range}= | ${32}
  72 | ${overhead}= | ${54}
  73 | ${n_tunnels}= | ${1}
  74 # Traffic profile:
  75 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  76
  77 *** Keywords ***
  78 | Local Template
  79 | | [Documentation]
  80 | | ... | [Cfg] DUT runs IPSec tunneling AES GCM config.
  81 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  82 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  83 | | ...
  84 | | ... | *Arguments:*
  85 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  86 | | ... | Type: integer, string
  87 | | ... | - phy_cores - Number of physical cores. Type: integer
  88 | | ... | - search_type - NDR or PDR. Type: string
  89 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  90 | | ... | - min_rate - Min rate for binary search, default value: ${50000}.
  91 | | ... | Type: integer
  92 | | ...
  93 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  94 | | ...
  95 | | Set Test Variable | ${framesize}
  96 | | Set Test Variable | ${min_rate} | ${10000}
  97 | | ${encr_alg} = | Crypto Alg AES GCM 128
  98 | | ${auth_alg} = | Integ Alg AES GCM 128
  99 | | ${ipsec_proto} = | IPsec Proto ESP
 100 | | ...
 101 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 102 | | And Add PCI devices to all DUTs
 103 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
 104 | | ... | ${s_10G} | ${framesize} | overhead=${overhead}
 105 | | ... | pps_limit=${s_14.88Mpps}
 106 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 107 | | ... | aesni_gcm | ${phy_cores}
 108 | | And Add DPDK dev default RXD to all DUTs | 2048
 109 | | And Add DPDK dev default TXD to all DUTs | 2048
 110 | | And Apply startup configuration on all VPP DUTs
 111 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 112 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
 113 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
 114 | | And VPP IPsec Backend Dump | ${dut1}
 115 | | And VPP IPsec Backend Dump | ${dut2}
 116 | | And Initialize IPSec in 3-node circular topology
 117 | | And Vpp Route Add | ${dut1} | ${raddr_ip4} | 8 | gateway=${dut2_if1_ip4}
 118 | | ... | interface=${dut1_if2}
 119 | | And Vpp Route Add | ${dut2} | ${laddr_ip4} | 8 | gateway=${dut1_if2_ip4}
 120 | | ... | interface=${dut2_if1}
 121 | | And VPP IPsec Add Multiple Tunnels
 122 | | ... | ${dut1} | ${dut2} | ${dut1_if2} | ${dut2_if1} | ${n_tunnels}
 123 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key}
 124 | | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${laddr_ip4} | ${raddr_ip4}
 125 | | ... | ${addr_range}
 126 | | Then Find NDR and PDR intervals using optimized search
 127 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
 128
 129 *** Test Cases ***
 130 | tc01-64B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 131 | | [Tags] | 64B | 1C
 132 | | framesize=${64} | phy_cores=${1}
 133
 134 | tc02-64B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 135 | | [Tags] | 64B | 2C
 136 | | framesize=${64} | phy_cores=${2}
 137
 138 | tc03-64B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 139 | | [Tags] | 64B | 4C
 140 | | framesize=${64} | phy_cores=${4}
 141
 142 | tc04-1518B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 143 | | [Tags] | 1518B | 1C
 144 | | framesize=${1518} | phy_cores=${1}
 145
 146 | tc05-1518B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 147 | | [Tags] | 1518B | 2C
 148 | | framesize=${1518} | phy_cores=${2}
 149
 150 | tc06-1518B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 151 | | [Tags] | 1518B | 4C
 152 | | framesize=${1518} | phy_cores=${4}
 153
 154 | tc07-9000B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 155 | | [Tags] | 9000B | 1C
 156 | | framesize=${9000} | phy_cores=${1}
 157
 158 | tc08-9000B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 159 | | [Tags] | 9000B | 2C
 160 | | framesize=${9000} | phy_cores=${2}
 161
 162 | tc09-9000B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 163 | | [Tags] | 9000B | 4C
 164 | | framesize=${9000} | phy_cores=${4}
 165
 166 | tc10-IMIX-1c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 167 | | [Tags] | IMIX | 1C
 168 | | framesize=IMIX_v4_1 | phy_cores=${1}
 169
 170 | tc11-IMIX-2c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 171 | | [Tags] | IMIX | 2C
 172 | | framesize=IMIX_v4_1 | phy_cores=${2}
 173
 174 | tc12-IMIX-4c-ethip4ipsecbasetnlsw-ip4base-tnl-aes-gcm-ndrpdr
 175 | | [Tags] | IMIX | 4C
 176 | | framesize=IMIX_v4_1 | phy_cores=${4}