tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 |
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | SCALE | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECINT | NIC_Intel-X710 | TNL_1000
  20 | ... | AES_256_GCM | AES | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4ipsec1000tnlhw-ip4base-int-aes256gcm
  23 |
  24 | Suite Setup | Setup suite topology interfaces | performance | ipsechw
  25 | Suite Teardown | Tear down suite | performance
  26 | Test Setup | Setup test | performance
  27 | Test Teardown | Tear down test | performance
  28 |
  29 | Test Template | Local Template
  30 |
  31 | Documentation | *RFC2544: Pkt throughput IPv4 IPsec tunnel mode.*
  32 |
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  36 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  38 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  39 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | Test packets are generated by TG on
  46 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  47 | ... | (flow-group per direction, number of flows per flow-group equals to
  48 | ... | number of IPSec tunnels) with all packets
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  50 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  51 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  52 | ... | is applied to both streams.
  53 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  54
  55 *** Variables ***
  56 | @{plugins_to_enable}= | dpdk_plugin.so | crypto_native_plugin.so
  57 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  58 | ${crypto_type}= | HW_DH895xcc
  59 | ${nic_name}= | Intel-X710
  60 | ${nic_driver}= | vfio-pci
  61 | ${nic_rxq_size}= | 0
  62 | ${nic_txq_size}= | 0
  63 | ${nic_pfs}= | 2
  64 | ${nic_vfs}= | 0
  65 | ${osi_layer}= | L3
  66 | ${overhead}= | ${54}
  67 | ${tg_if1_ip4}= | 192.168.10.2
  68 | ${dut1_if1_ip4}= | 192.168.10.1
  69 | ${dut1_if2_ip4}= | 100.0.0.1
  70 | ${dut2_if1_ip4}= | 200.0.0.2
  71 | ${dut2_if2_ip4}= | 192.168.20.1
  72 | ${tg_if2_ip4}= | 192.168.20.2
  73 | ${raddr_ip4}= | 20.0.0.0
  74 | ${laddr_ip4}= | 10.0.0.0
  75 | ${addr_range}= | ${24}
  76 | ${n_tunnels}= | ${1000}
  77 # Traffic profile:
  78 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4dst${n_tunnels}
  79
  80 *** Keywords ***
  81 | Local Template
  82 | | [Documentation]
  83 | | ... | [Cfg] DUT runs IPSec tunneling AES_256_GCM config.\
  84 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  85 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  86 | |
  87 | | ... | *Arguments:*
  88 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  89 | | ... | Type: integer, string
  90 | | ... | - phy_cores - Number of physical cores. Type: integer
  91 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  92 | |
  93 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  94 | |
  95 | | Set Test Variable | \${frame_size}
  96 | |
  97 | | # These are enums (not strings) so they cannot be in Variables table.
  98 | | ${encr_alg}= | Crypto Alg AES GCM 256
  99 | | ${auth_alg}= | Set Variable | ${NONE}
 100 | | ${ipsec_proto}= | IPsec Proto ESP
 101 | |
 102 | | Given Set Max Rate And Jumbo
 103 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 104 | | And Pre-initialize layer driver | ${nic_driver}
 105 | | And Apply startup configuration on all VPP DUTs
 106 | | When Initialize layer driver | ${nic_driver}
 107 | | And Initialize layer interface
 108 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
 109 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
 110 | | And Initialize IPSec in 3-node circular topology
 111 | | And VPP IPsec Create Tunnel Interfaces
 112 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${DUT1_${int}2}[0]
 113 | | ... | ${DUT2_${int}1}[0] | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 114 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 115 | | Then Find NDR and PDR intervals using optimized search
 116
 117 *** Test Cases ***
 118 | 64B-1c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 119 | | [Tags] | 64B | 1C
 120 | | frame_size=${64} | phy_cores=${1}
 121
 122 | 64B-2c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 123 | | [Tags] | 64B | 2C
 124 | | frame_size=${64} | phy_cores=${2}
 125
 126 | 64B-4c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 127 | | [Tags] | 64B | 4C
 128 | | frame_size=${64} | phy_cores=${4}
 129
 130 | 1518B-1c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 131 | | [Tags] | 1518B | 1C
 132 | | frame_size=${1518} | phy_cores=${1}
 133
 134 | 1518B-2c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 135 | | [Tags] | 1518B | 2C
 136 | | frame_size=${1518} | phy_cores=${2}
 137
 138 | 1518B-4c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 139 | | [Tags] | 1518B | 4C
 140 | | frame_size=${1518} | phy_cores=${4}
 141
 142 | 9000B-1c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 143 | | [Tags] | 9000B | 1C
 144 | | frame_size=${9000} | phy_cores=${1}
 145
 146 | 9000B-2c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 147 | | [Tags] | 9000B | 2C
 148 | | frame_size=${9000} | phy_cores=${2}
 149
 150 | 9000B-4c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 151 | | [Tags] | 9000B | 4C
 152 | | frame_size=${9000} | phy_cores=${4}
 153
 154 | IMIX-1c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 155 | | [Tags] | IMIX | 1C
 156 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 157
 158 | IMIX-2c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 159 | | [Tags] | IMIX | 2C
 160 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 161
 162 | IMIX-4c-ethip4ipsec1000tnlhw-ip4base-int-aes256gcm-ndrpdr
 163 | | [Tags] | IMIX | 4C
 164 | | frame_size=IMIX_v4_1 | phy_cores=${4}