tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | SCALE | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECTUN | NIC_Intel-X710 | TNL_1000
  20 | ... | AES_128_CBC | HMAC_SHA_512 | HMAC | AES
  21 | ...
  22 | Suite Setup | Setup suite single link | performance | ipsechw
  23 | Suite Teardown | Tear down suite | performance
  24 | Test Setup | Setup test
  25 | Test Teardown | Tear down test | performance
  26 | ...
  27 | Test Template | Local Template
  28 | ...
  29 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  34 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  36 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  37 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  43 | ... | Test packets are generated by TG on
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  45 | ... | (flow-group per direction, number of flows per flow-group equals to
  46 | ... | number of IPSec tunnels) with all packets
  47 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  48 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  49 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  50 | ... | is applied to both streams.
  51 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  52
  53 *** Variables ***
  54 | @{plugins_to_enable}= | dpdk_plugin.so | crypto_ia32_plugin.so
  55 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  56 | ${osi_layer}= | L3
  57 | ${crypto_type}= | HW_DH895xcc
  58 | ${nic_name}= | Intel-X710
  59 | ${overhead}= | ${58}
  60 | ${tg_if1_ip4}= | 192.168.10.2
  61 | ${dut1_if1_ip4}= | 192.168.10.1
  62 | ${dut1_if2_ip4}= | 100.0.0.1
  63 | ${dut2_if1_ip4}= | 100.0.0.2
  64 | ${dut2_if2_ip4}= | 192.168.20.1
  65 | ${tg_if2_ip4}= | 192.168.20.2
  66 | ${raddr_ip4}= | 20.0.0.0
  67 | ${laddr_ip4}= | 10.0.0.0
  68 | ${addr_range}= | ${24}
  69 | ${n_tunnels}= | ${1000}
  70 # Traffic profile:
  71 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  72
  73 *** Keywords ***
  74 | Local Template
  75 | | [Documentation]
  76 | | ... | [Cfg] DUTs run 1000 IPsec tunnels AES_128_CBC / HMAC_SHA_512 config
  77 | | ... | in each direction.\
  78 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  79 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  80 | | ...
  81 | | ... | *Arguments:*
  82 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  83 | | ... | Type: integer, string
  84 | | ... | - phy_cores - Number of physical cores. Type: integer
  85 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  86 | | ...
  87 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  88 | | ...
  89 | | Set Test Variable | \${frame_size}
  90 | | ...
  91 | | # These are enums (not strings) so they cannot be in Variables table.
  92 | | ${encr_alg}= | Crypto Alg AES CBC 128
  93 | | ${auth_alg}= | Integ Alg SHA 512 256
  94 | | ...
  95 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  96 | | And Add PCI devices to all DUTs
  97 | | And Set Max Rate And Jumbo And Handle Multi Seg
  98 | | And Add cryptodev to all DUTs | ${phy_cores}
  99 | | And Apply startup configuration on all VPP DUTs
 100 | | When Initialize IPSec in 3-node circular topology
 101 | | And VPP IPsec Add Multiple Tunnels
 102 | | ... | ${nodes} | ${dut1_if2} | ${dut2_if1} | ${n_tunnels}
 103 | | ... | ${encr_alg} | ${auth_alg} | ${dut1_if2_ip4} | ${dut2_if1_ip4}
 104 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 105 | | Then Find NDR and PDR intervals using optimized search
 106
 107 *** Test Cases ***
 108 | tc01-64B-1c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 109 | | [Tags] | 64B | 1C
 110 | | frame_size=${64} | phy_cores=${1}
 111
 112 | tc02-64B-2c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 113 | | [Tags] | 64B | 2C
 114 | | frame_size=${64} | phy_cores=${2}
 115
 116 | tc03-64B-4c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 117 | | [Tags] | 64B | 4C
 118 | | frame_size=${64} | phy_cores=${4}
 119
 120 | tc04-1518B-1c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 121 | | [Tags] | 1518B | 1C
 122 | | frame_size=${1518} | phy_cores=${1}
 123
 124 | tc05-1518B-2c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 125 | | [Tags] | 1518B | 2C
 126 | | frame_size=${1518} | phy_cores=${2}
 127
 128 | tc06-1518B-4c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 129 | | [Tags] | 1518B | 4C
 130 | | frame_size=${1518} | phy_cores=${4}
 131
 132 | tc10-IMIX-1c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 133 | | [Tags] | IMIX | 1C
 134 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 135
 136 | tc11-IMIX-2c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 137 | | [Tags] | IMIX | 2C
 138 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 139
 140 | tc12-IMIX-4c-ethip4ipsec1000tnlhw-ip4base-policy-aes128cbc-hmac512sha-ndrpdr
 141 | | [Tags] | IMIX | 4C
 142 | | frame_size=IMIX_v4_1 | phy_cores=${4}