tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECTUN | NIC_Intel-X710 | BASE |
  20 | ... | AES_128_CBC | HMAC_SHA_256 | HMAC | AES
  21 | ...
  22 | Suite Setup | Set up IPSec performance test suite | L3 | ${nic_name}
  23 | ... | HW_DH895xcc
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | Test Teardown | Tear down performance test
  28 | ...
  29 | Test Template | Local Template
  30 | ...
  31 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  36 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  38 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  39 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | TG traffic profile contains two L3 flow-groups
  46 | ... | (flow-group per direction, number of flows per flow-group equals to
  47 | ... | number of IPSec tunnels) with all packets
  48 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  49 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  50 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  51 | ... | is applied to both streams.
  52 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  53
  54 *** Variables ***
  55 | ${nic_name}= | Intel-X710
  56 | ${overhead}= | ${58}
  57 | ${tg_if1_ip4}= | 192.168.10.2
  58 | ${dut1_if1_ip4}= | 192.168.10.1
  59 | ${dut1_if2_ip4}= | 100.0.0.1
  60 | ${dut2_if1_ip4}= | 100.0.0.2
  61 | ${dut2_if2_ip4}= | 192.168.20.1
  62 | ${tg_if2_ip4}= | 192.168.20.2
  63 | ${raddr_ip4}= | 20.0.0.0
  64 | ${laddr_ip4}= | 10.0.0.0
  65 | ${addr_range}= | ${24}
  66 | ${n_tunnels}= | ${1}
  67 # Traffic profile:
  68 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  69
  70 *** Keywords ***
  71 | Local Template
  72 | | [Documentation]
  73 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES_CBC_128 / HMAC_256_SHA in each
  74 | | ... | direction.\
  75 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  76 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  80 | | ... | Type: integer, string
  81 | | ... | - phy_cores - Number of physical cores. Type: integer
  82 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  83 | | ...
  84 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  85 | | ...
  86 | | Set Test Variable | \${frame_size}
  87 | | ...
  88 | | # These are enums (not strings) so they cannot be in Variables table.
  89 | | ${encr_alg}= | Crypto Alg AES CBC 128
  90 | | ${auth_alg}= | Integ Alg SHA 256 128
  91 | | ...
  92 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  93 | | And Add PCI devices to all DUTs
  94 | | Set Max Rate And Jumbo And Handle Multi Seg
  95 | | And Add cryptodev to all DUTs | ${phy_cores}
  96 | | And Apply startup configuration on all VPP DUTs
  97 | | And Initialize IPSec in 3-node circular topology
  98 | | And VPP IPsec Add Multiple Tunnels
  99 | | ... | ${${nodes} | ${dut1_if2} | ${dut2_if1} | ${n_tunnels}
 100 | | ... | ${encr_alg} | ${auth_alg} | ${dut1_if2_ip4} | ${dut2_if1_ip4}
 101 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 102 | | Then Find NDR and PDR intervals using optimized search
 103
 104 *** Test Cases ***
 105 | tc01-64B-1c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 106 | | [Tags] | 64B | 1C
 107 | | frame_size=${64} | phy_cores=${1}
 108
 109 | tc02-64B-2c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 110 | | [Tags] | 64B | 2C
 111 | | frame_size=${64} | phy_cores=${2}
 112
 113 | tc03-64B-4c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 114 | | [Tags] | 64B | 4C
 115 | | frame_size=${64} | phy_cores=${4}
 116
 117 | tc04-1518B-1c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 118 | | [Tags] | 1518B | 1C
 119 | | frame_size=${1518} | phy_cores=${1}
 120
 121 | tc05-1518B-2c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 122 | | [Tags] | 1518B | 2C
 123 | | frame_size=${1518} | phy_cores=${2}
 124
 125 | tc06-1518B-4c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 126 | | [Tags] | 1518B | 4C
 127 | | frame_size=${1518} | phy_cores=${4}
 128
 129 | tc07-9000B-1c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 130 | | [Tags] | 9000B | 1C
 131 | | frame_size=${9000} | phy_cores=${1}
 132
 133 | tc08-9000B-2c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 134 | | [Tags] | 9000B | 2C
 135 | | frame_size=${9000} | phy_cores=${2}
 136
 137 | tc09-9000B-4c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 138 | | [Tags] | 9000B | 4C
 139 | | frame_size=${9000} | phy_cores=${4}
 140
 141 | tc10-IMIX-1c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 142 | | [Tags] | IMIX | 1C
 143 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 144
 145 | tc11-IMIX-2c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 146 | | [Tags] | IMIX | 2C
 147 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 148
 149 | tc12-IMIX-4c-ethip4ipsec1tnlhw-ip4base-policy-aes128cbc-hmac256sha-ndrpdr
 150 | | [Tags] | IMIX | 4C
 151 | | frame_size=IMIX_v4_1 | phy_cores=${4}