tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 |
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | RECONF | TNL_40
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | SCALE
  20 | ... | AES_128_GCM | AES | 1_ADDED_TUNNEL | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm
  23 |
  24 | Suite Setup | Setup suite topology interfaces | performance
  25 | Suite Teardown | Tear down suite | performance
  26 | Test Setup | Setup test | performance
  27 | Test Teardown | Tear down test | performance | ipsec_sa
  28 |
  29 | Test Template | Local Template
  30 |
  31 | Documentation | **RFC2544: Packet loss IPv4 IPsec tunnel mode.**
  32 | ... |
  33 | ... | - **[Top] Network Topologies:** TG-DUT1-DUT2-TG 3-node circular \
  34 | ... | topology with single links between nodes.
  35 | ... |
  36 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 on TG-DUTn, \
  37 | ... | Eth-IPv4-IPSec on DUT1-DUT2.
  38 | ... |
  39 | ... | - **[Cfg] DUT configuration:** DUT1 and DUT2 are configured with \
  40 | ... | multiple IPsec tunnels between them. DUTs get IPv4 traffic from TG, \
  41 | ... | encrypt it and send to another DUT, where packets are decrypted and \
  42 | ... | sent back to TG.
  43 | ... |
  44 | ... | - **[Ver] TG verification:** TG finds throughput NDR (Non Drop Rate) \
  45 | ... | with zero packet loss tolerance, then measures loss at this load \
  46 | ... | while additional chain is configured. \
  47 | ... | Test packets are generated by TG on \
  48 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups \
  49 | ... | (flow-group per direction, number of flows per flow-group equals to \
  50 | ... | number of IPSec tunnels) with all packets \
  51 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and \
  52 | ... | static payload. MAC addresses are matching MAC addresses of the TG \
  53 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) \
  54 | ... | is applied to both streams.
  55 | ... |
  56 | ... | - **[Ref] Applicable standard specifications:** RFC4303 and RFC2544.
  57
  58 *** Variables ***
  59 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  60 | ... | crypto_native_plugin.so
  61 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  62 | ${crypto_type}= | ${None}
  63 | ${nic_name}= | Intel-X710
  64 | ${nic_driver}= | vfio-pci
  65 | ${nic_rxq_size}= | 0
  66 | ${nic_txq_size}= | 0
  67 | ${nic_pfs}= | 2
  68 | ${nic_vfs}= | 0
  69 | ${osi_layer}= | L3
  70 | ${overhead}= | ${54}
  71 | ${tg_if1_ip4}= | 192.168.10.254
  72 | ${dut1_if1_ip4}= | 192.168.10.11
  73 | ${dut1_if2_ip4}= | 100.0.0.1
  74 | ${dut2_if1_ip4}= | 200.0.0.102
  75 | ${dut2_if2_ip4}= | 192.168.20.11
  76 | ${tg_if2_ip4}= | 192.168.20.254
  77 | ${raddr_ip4}= | 20.0.0.0
  78 | ${laddr_ip4}= | 10.0.0.0
  79 | ${addr_range}= | ${24}
  80 | ${n_tunnels}= | ${40}
  81 | ${n_added_tunnels}= | ${1}
  82 # Traffic profile:
  83 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4dst${n_tunnels}
  84
  85 *** Keywords ***
  86 | Local Template
  87 | | [Documentation]
  88 | | ... | - **[Cfg]** DUT runs IPSec tunneling AES_128_GCM config. \
  89 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  90 | | ... | - **[Ver]** Measure packet loss during reconfig at NDR load.
  91 | |
  92 | | ... | *Arguments:*
  93 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  94 | | ... | Type: integer, string
  95 | | ... | - phy_cores - Number of physical cores. Type: integer
  96 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  97 | |
  98 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  99 | |
 100 | | Set Test Variable | \${frame_size}
 101 | |
 102 | | # These are enums (not strings) so they cannot be in Variables table.
 103 | | ${encr_alg}= | Crypto Alg AES GCM 128
 104 | | ${auth_alg}= | Set Variable | ${NONE}
 105 | | ${ipsec_proto} = | IPsec Proto ESP
 106 | |
 107 | | ${n_total_tunnels} = | Evaluate | ${n_tunnels} + ${n_added_tunnels}
 108 | | Given Set Max Rate And Jumbo
 109 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 110 | | And Pre-initialize layer driver | ${nic_driver}
 111 | | And Apply startup configuration on all VPP DUTs
 112 | | When Initialize layer driver | ${nic_driver}
 113 | | And Initialize layer interface
 114 | | And Initialize IPSec in 3-node circular topology
 115 | | And VPP IPsec Create Tunnel Interfaces
 116 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${DUT1_${int}2}[0]
 117 | | ... | ${DUT2_${int}1}[0] | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 118 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 119 | | ${unidirectional_throughput} = | Find Throughput Using MLRsearch
 120 | | Start Traffic on Background | ${unidirectional_throughput}
 121 | | And VPP IPsec Create Tunnel Interfaces
 122 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${DUT1_${int}2}[0]
 123 | | ... | ${DUT2_${int}1}[0] | ${n_total_tunnels} | ${encr_alg} | ${auth_alg}
 124 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range} | ${n_tunnels}
 125 | | ${result}= | Stop Running Traffic
 126 | | Display Reconfig Test Message | ${result}
 127
 128 *** Test Cases ***
 129 | 64B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 130 | | [Tags] | 64B | 1C
 131 | | frame_size=${64} | phy_cores=${1}
 132
 133 | 64B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 134 | | [Tags] | 64B | 2C
 135 | | frame_size=${64} | phy_cores=${2}
 136
 137 | 64B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 138 | | [Tags] | 64B | 4C
 139 | | frame_size=${64} | phy_cores=${4}
 140
 141 | 1518B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 142 | | [Tags] | 1518B | 1C
 143 | | frame_size=${1518} | phy_cores=${1}
 144
 145 | 1518B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 146 | | [Tags] | 1518B | 2C
 147 | | frame_size=${1518} | phy_cores=${2}
 148
 149 | 1518B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 150 | | [Tags] | 1518B | 4C
 151 | | frame_size=${1518} | phy_cores=${4}
 152
 153 | 9000B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 154 | | [Tags] | 9000B | 1C
 155 | | frame_size=${9000} | phy_cores=${1}
 156
 157 | 9000B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 158 | | [Tags] | 9000B | 2C
 159 | | frame_size=${9000} | phy_cores=${2}
 160
 161 | 9000B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 162 | | [Tags] | 9000B | 4C
 163 | | frame_size=${9000} | phy_cores=${4}
 164
 165 | IMIX-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 166 | | [Tags] | IMIX | 1C
 167 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 168
 169 | IMIX-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 170 | | [Tags] | IMIX | 2C
 171 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 172
 173 | IMIX-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes128gcm-reconf
 174 | | [Tags] | IMIX | 4C
 175 | | frame_size=IMIX_v4_1 | phy_cores=${4}