tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr.robot

   1 # Copyright (c) 2024 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 |
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR | TNL_4
  18 | ... | IP4FWD | IPSEC | IPSECSW | IPSECTUN | NIC_Intel-X710 | SCALE
  19 | ... | AES_256_GCM | AES | DRV_VFIO_PCI
  20 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  21 | ... | ethip4ipsec4tnlsw-ip4base-policy-aes256gcm
  22 |
  23 | Suite Setup | Setup suite topology interfaces | performance
  24 | Suite Teardown | Tear down suite | performance
  25 | Test Setup | Setup test | performance
  26 | Test Teardown | Tear down test | performance | ipsec_all
  27 |
  28 | Test Template | Local Template
  29 |
  30 | Documentation | **IPv4 IPsec tunnel mode performance test suite.**
  31 | ... |
  32 | ... | - **[Top] Network Topologies:** TG-DUT1-DUT2-TG 3-node circular \
  33 | ... | topology with single links between nodes.
  34 | ... |
  35 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 on TG-DUTn, \
  36 | ... | Eth-IPv4-IPSec on DUT1-DUT2.
  37 | ... |
  38 | ... | - **[Cfg] DUT configuration:** DUT1 and DUT2 are configured with \
  39 | ... | multiple IPsec tunnels between them. DUTs get IPv4 traffic from TG, \
  40 | ... | encrypt it and send to another DUT, where packets are decrypted and \
  41 | ... | sent back to TG.
  42 | ... |
  43 | ... | - **[Ver] TG verification:** TG finds and reports throughput NDR (Non \
  44 | ... | Drop Rate) with zero packet loss tolerance and throughput PDR \
  45 | ... | (Partial Drop Rate) with non-zero packet loss tolerance (LT) \
  46 | ... | expressed in percentage of packets transmitted. NDR and PDR are \
  47 | ... | discovered for different Ethernet L2 frame sizes using MLRsearch \
  48 | ... | library.
  49 | ... | Test packets are generated by TG on \
  50 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups \
  51 | ... | (flow-group per direction, number of flows per flow-group equals to \
  52 | ... | number of IPSec tunnels) with all packets \
  53 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and \
  54 | ... | static payload. MAC addresses are matching MAC addresses of the TG \
  55 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) \
  56 | ... | is applied to both streams.
  57 | ... |
  58 | ... | - **[Ref] Applicable standard specifications:** RFC4303 and RFC2544.
  59
  60 *** Variables ***
  61 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  62 | ... | crypto_native_plugin.so
  63 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  64 | ${crypto_type}= | ${None}
  65 | ${nic_name}= | Intel-X710
  66 | ${nic_driver}= | vfio-pci
  67 | ${nic_rxq_size}= | 0
  68 | ${nic_txq_size}= | 0
  69 | ${nic_pfs}= | 2
  70 | ${nic_vfs}= | 0
  71 | ${osi_layer}= | L3
  72 | ${overhead}= | ${54}
  73 | ${tg_if1_ip4}= | 192.168.10.254
  74 | ${dut1_if1_ip4}= | 192.168.10.11
  75 | ${dut1_if2_ip4}= | 100.0.0.1
  76 | ${dut2_if1_ip4}= | 200.0.0.102
  77 | ${dut2_if2_ip4}= | 192.168.20.11
  78 | ${tg_if2_ip4}= | 192.168.20.254
  79 | ${raddr_ip4}= | 20.0.0.0
  80 | ${laddr_ip4}= | 10.0.0.0
  81 | ${addr_range}= | ${24}
  82 | ${n_tunnels}= | ${4}
  83 # Traffic profile:
  84 | ${traffic_profile}= | trex-stl-ethip4-ip4dst${n_tunnels}
  85
  86 *** Keywords ***
  87 | Local Template
  88 | | [Documentation]
  89 | | ... | - **[Cfg]** DUT runs IPSec tunneling AES_256_GCM config. \
  90 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  91 | | ... | - **[Ver]** Measure NDR and PDR values using MLRsearch algorithm.
  92 | |
  93 | | ... | *Arguments:*
  94 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  95 | | ... | Type: integer, string
  96 | | ... | - phy_cores - Number of physical cores. Type: integer
  97 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  98 | |
  99 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
 100 | |
 101 | | Set Test Variable | \${frame_size}
 102 | |
 103 | | # These are enums (not strings) so they cannot be in Variables table.
 104 | | ${encr_alg}= | Crypto Alg AES GCM 256
 105 | | ${auth_alg}= | Set Variable | ${NONE}
 106 | | ${ipsec_proto}= | IPsec Proto ESP
 107 | |
 108 | | Given Set Max Rate And Jumbo
 109 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 110 | | And Pre-initialize layer driver | ${nic_driver}
 111 | | And Apply startup configuration on all VPP DUTs
 112 | | When Initialize layer driver | ${nic_driver}
 113 | | And Initialize layer interface
 114 | | And Initialize IPSec in 3-node circular topology
 115 | | And VPP IPsec Add Multiple Tunnels
 116 | | ... | ${nodes} | ${DUT1_${int}2}[0] | ${DUT2_${int}1}[0] | ${n_tunnels}
 117 | | ... | ${encr_alg} | ${auth_alg} | ${dut1_if2_ip4} | ${dut2_if1_ip4}
 118 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 119 | | Then Find NDR and PDR intervals using optimized search
 120
 121 *** Test Cases ***
 122 | 64B-1c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 123 | | [Tags] | 64B | 1C
 124 | | frame_size=${64} | phy_cores=${1}
 125
 126 | 64B-2c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 127 | | [Tags] | 64B | 2C
 128 | | frame_size=${64} | phy_cores=${2}
 129
 130 | 64B-4c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 131 | | [Tags] | 64B | 4C
 132 | | frame_size=${64} | phy_cores=${4}
 133
 134 | 1518B-1c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 135 | | [Tags] | 1518B | 1C
 136 | | frame_size=${1518} | phy_cores=${1}
 137
 138 | 1518B-2c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 139 | | [Tags] | 1518B | 2C
 140 | | frame_size=${1518} | phy_cores=${2}
 141
 142 | 1518B-4c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 143 | | [Tags] | 1518B | 4C
 144 | | frame_size=${1518} | phy_cores=${4}
 145
 146 | 9000B-1c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 147 | | [Tags] | 9000B | 1C
 148 | | frame_size=${9000} | phy_cores=${1}
 149
 150 | 9000B-2c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 151 | | [Tags] | 9000B | 2C
 152 | | frame_size=${9000} | phy_cores=${2}
 153
 154 | 9000B-4c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 155 | | [Tags] | 9000B | 4C
 156 | | frame_size=${9000} | phy_cores=${4}
 157
 158 | IMIX-1c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 159 | | [Tags] | IMIX | 1C
 160 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 161
 162 | IMIX-2c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 163 | | [Tags] | IMIX | 2C
 164 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 165
 166 | IMIX-4c-ethip4ipsec4tnlsw-ip4base-policy-aes256gcm-ndrpdr
 167 | | [Tags] | IMIX | 4C
 168 | | frame_size=IMIX_v4_1 | phy_cores=${4}