tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 |
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | RECONF | TNL_60000
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | SCALE
  20 | ... | AES_128_CBC | HMAC_SHA_256 | HMAC | AES | 1_ADDED_TUNNEL | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha
  23 |
  24 | Suite Setup | Setup suite topology interfaces | performance
  25 | Suite Teardown | Tear down suite | performance
  26 | Test Setup | Setup test | performance
  27 | Test Teardown | Tear down test | performance | ipsec_sa
  28 |
  29 | Test Template | Local Template
  30 |
  31 | Documentation | *RFC2544: Packet loss IPv4 IPsec tunnel mode.*
  32 |
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  36 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple\
  38 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it\
  39 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  40 | ... | *[Ver] TG verification:* TG finds throughput NDR (Non Drop Rate)\
  41 | ... | with zero packet loss tolerance, then measures loss at this load\
  42 | ... | while additional chain is configured.\
  43 | ... | Test packets are generated by TG on
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  45 | ... | (flow-group per direction, number of flows per flow-group equals to
  46 | ... | number of IPSec tunnels) with all packets
  47 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  48 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  49 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  50 | ... | is applied to both streams.
  51 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  52
  53 *** Variables ***
  54 | @{plugins_to_enable}= | dpdk_plugin.so | crypto_native_plugin.so
  55 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  56 | ${crypto_type}= | ${None}
  57 | ${nic_name}= | Intel-X710
  58 | ${nic_driver}= | vfio-pci
  59 | ${nic_rxq_size}= | 0
  60 | ${nic_txq_size}= | 0
  61 | ${nic_pfs}= | 2
  62 | ${nic_vfs}= | 0
  63 | ${osi_layer}= | L3
  64 | ${overhead}= | ${62}
  65 | ${tg_if1_ip4}= | 192.168.10.2
  66 | ${dut1_if1_ip4}= | 192.168.10.1
  67 | ${dut1_if2_ip4}= | 100.0.0.1
  68 | ${dut2_if1_ip4}= | 200.0.0.2
  69 | ${dut2_if2_ip4}= | 192.168.20.1
  70 | ${tg_if2_ip4}= | 192.168.20.2
  71 | ${raddr_ip4}= | 20.0.0.0
  72 | ${laddr_ip4}= | 10.0.0.0
  73 | ${addr_range}= | ${24}
  74 | ${n_tunnels}= | ${60000}
  75 | ${n_added_tunnels}= | ${1}
  76 # Traffic profile:
  77 | ${traffic_profile}= | trex-stl-3n-ethip4-ip4dst${n_tunnels}
  78
  79 *** Keywords ***
  80 | Local Template
  81 | | [Documentation]
  82 | | ... | [Cfg] DUT runs IPSec tunneling AES_128_CBC / HMAC_SHA_256 config.\
  83 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  84 | | ... | [Ver] Measure packet loss during reconfig at NDR load.\
  85 | |
  86 | | ... | *Arguments:*
  87 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  88 | | ... | Type: integer, string
  89 | | ... | - phy_cores - Number of physical cores. Type: integer
  90 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  91 | |
  92 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  93 | |
  94 | | Set Test Variable | \${frame_size}
  95 | |
  96 | | # These are enums (not strings) so they cannot be in Variables table.
  97 | | ${encr_alg}= | Crypto Alg AES CBC 128
  98 | | ${auth_alg}= | Integ Alg SHA 256 128
  99 | |
 100 | | ${n_total_tunnels} = | Evaluate | ${n_tunnels} + ${n_added_tunnels}
 101 | | Given Set Max Rate And Jumbo
 102 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 103 | | And Pre-initialize layer driver | ${nic_driver}
 104 | | And Apply startup configuration on all VPP DUTs
 105 | | When Initialize layer driver | ${nic_driver}
 106 | | And Initialize layer interface
 107 | | And Initialize IPSec in 3-node circular topology
 108 | | And VPP IPsec Create Tunnel Interfaces
 109 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${DUT1_${int}2}[0]
 110 | | ... | ${DUT2_${int}1}[0] | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 111 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 112 | | ${unidirectional_throughput} = | Find Throughput Using MLRsearch
 113 | | Start Traffic on Background | ${unidirectional_throughput}
 114 | | And VPP IPsec Create Tunnel Interfaces
 115 | | ... | ${nodes} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${DUT1_${int}2}[0]
 116 | | ... | ${DUT2_${int}1}[0] | ${n_total_tunnels} | ${encr_alg} | ${auth_alg}
 117 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range} | ${n_tunnels}
 118 | | ${result}= | Stop Running Traffic
 119 | | Display Reconfig Test Message | ${result}
 120
 121 *** Test Cases ***
 122 | 64B-1c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 123 | | [Tags] | 64B | 1C
 124 | | frame_size=${64} | phy_cores=${1}
 125
 126 | 64B-2c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 127 | | [Tags] | 64B | 2C
 128 | | frame_size=${64} | phy_cores=${2}
 129
 130 | 64B-4c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 131 | | [Tags] | 64B | 4C
 132 | | frame_size=${64} | phy_cores=${4}
 133
 134 | 1518B-1c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 135 | | [Tags] | 1518B | 1C
 136 | | frame_size=${1518} | phy_cores=${1}
 137
 138 | 1518B-2c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 139 | | [Tags] | 1518B | 2C
 140 | | frame_size=${1518} | phy_cores=${2}
 141
 142 | 1518B-4c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 143 | | [Tags] | 1518B | 4C
 144 | | frame_size=${1518} | phy_cores=${4}
 145
 146 | 9000B-1c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 147 | | [Tags] | 9000B | 1C
 148 | | frame_size=${9000} | phy_cores=${1}
 149
 150 | 9000B-2c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 151 | | [Tags] | 9000B | 2C
 152 | | frame_size=${9000} | phy_cores=${2}
 153
 154 | 9000B-4c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 155 | | [Tags] | 9000B | 4C
 156 | | frame_size=${9000} | phy_cores=${4}
 157
 158 | IMIX-1c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 159 | | [Tags] | IMIX | 1C
 160 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 161
 162 | IMIX-2c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 163 | | [Tags] | IMIX | 2C
 164 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 165
 166 | IMIX-4c-ethip4ipsec60000tnlsw-1atnl-ip4base-int-aes128cbc-hmac256sha-reconf
 167 | | [Tags] | IMIX | 4C
 168 | | frame_size=IMIX_v4_1 | phy_cores=${4}