tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECINT | NIC_Intel-X710 | BASE | AES_GCM
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | ${nic_name}
  22 | ... | HW_DH895xcc
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput IPv4 IPsec tunnel mode.*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  35 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  37 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  38 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  39 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  40 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  41 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  42 | ... | of packets transmitted. NDR and PDR are discovered for different\
  43 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  44 | ... | Test packets are generated by TG on
  45 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  46 | ... | (flow-group per direction, number of flows per flow-group equals to
  47 | ... | number of IPSec tunnels) with all packets
  48 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  49 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  50 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  51 | ... | is applied to both streams.
  52 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  53
  54 *** Variables ***
  55 | ${nic_name}= | Intel-X710
  56 | ${overhead}= | ${54}
  57 | ${tg_if1_ip4}= | 192.168.10.2
  58 | ${dut1_if1_ip4}= | 192.168.10.1
  59 | ${dut1_if2_ip4}= | 172.168.1.1
  60 | ${dut2_if1_ip4}= | 172.168.1.2
  61 | ${dut2_if2_ip4}= | 192.168.20.1
  62 | ${tg_if2_ip4}= | 192.168.20.2
  63 | ${raddr_ip4}= | 20.0.0.0
  64 | ${laddr_ip4}= | 10.0.0.0
  65 | ${addr_range}= | ${32}
  66 | ${n_tunnels}= | ${1}
  67 # Traffic profile:
  68 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  69
  70 *** Keywords ***
  71 | Local Template
  72 | | [Documentation]
  73 | | ... | [Cfg] DUT runs IPSec tunneling AES GCM config.
  74 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  75 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  76 | | ...
  77 | | ... | *Arguments:*
  78 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  79 | | ... | Type: integer, string
  80 | | ... | - phy_cores - Number of physical cores. Type: integer
  81 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  82 | | ...
  83 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  84 | | ...
  85 | | Set Test Variable | \${frame_size}
  86 | | ...
  87 | | # These are enums (not strings) so they cannot be in Variables table.
  88 | | ${encr_alg}= | Crypto Alg AES GCM 128
  89 | | ${auth_alg}= | Integ Alg AES GCM 128
  90 | | ${ipsec_proto}= | IPsec Proto ESP
  91 | | ...
  92 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  93 | | And Add PCI devices to all DUTs
  94 | | Set Max Rate And Jumbo And Handle Multi Seg
  95 | | And Add cryptodev to all DUTs | ${phy_cores}
  96 | | And Add DPDK dev default RXD to all DUTs | 2048
  97 | | And Add DPDK dev default TXD to all DUTs | 2048
  98 | | And Apply startup configuration on all VPP DUTs
  99 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 100 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
 101 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
 102 | | And VPP IPsec Backend Dump | ${dut1}
 103 | | And VPP IPsec Backend Dump | ${dut2}
 104 | | And Initialize IPSec in 3-node circular topology
 105 | | And VPP IPsec Create Tunnel Interfaces
 106 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 107 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
 108 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 109 | | Then Find NDR and PDR intervals using optimized search
 110
 111 *** Test Cases ***
 112 | tc01-64B-1c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 113 | | [Tags] | 64B | 1C
 114 | | frame_size=${64} | phy_cores=${1}
 115
 116 | tc02-64B-2c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 117 | | [Tags] | 64B | 2C
 118 | | frame_size=${64} | phy_cores=${2}
 119
 120 | tc03-64B-4c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 121 | | [Tags] | 64B | 4C
 122 | | frame_size=${64} | phy_cores=${4}
 123
 124 | tc04-1518B-1c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 125 | | [Tags] | 1518B | 1C
 126 | | frame_size=${1518} | phy_cores=${1}
 127
 128 | tc05-1518B-2c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 129 | | [Tags] | 1518B | 2C
 130 | | frame_size=${1518} | phy_cores=${2}
 131
 132 | tc06-1518B-4c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 133 | | [Tags] | 1518B | 4C
 134 | | frame_size=${1518} | phy_cores=${4}
 135
 136 | tc07-9000B-1c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 137 | | [Tags] | 9000B | 1C
 138 | | frame_size=${9000} | phy_cores=${1}
 139
 140 | tc08-9000B-2c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 141 | | [Tags] | 9000B | 2C
 142 | | frame_size=${9000} | phy_cores=${2}
 143
 144 | tc09-9000B-4c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 145 | | [Tags] | 9000B | 4C
 146 | | frame_size=${9000} | phy_cores=${4}
 147
 148 | tc10-IMIX-1c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 149 | | [Tags] | IMIX | 1C
 150 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 151
 152 | tc11-IMIX-2c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 153 | | [Tags] | IMIX | 2C
 154 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 155
 156 | tc12-IMIX-4c-ethip4ipsecbasetnl-ip4base-int-aes-gcm-ndrpdr
 157 | | [Tags] | IMIX | 4C
 158 | | frame_size=IMIX_v4_1 | phy_cores=${4}