tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | BASE | AES_GCM
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | ${nic_name}
  22 | ... | SW_cryptodev
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput IPv4 IPsec tunnel mode.*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  35 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
  37 | ... | crypto devices and multiple IPsec tunnels between them.
  38 | ... | DUTs get IPv4 traffic from TG, encrypt it
  39 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | Test packets are generated by TG on
  46 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  47 | ... | (flow-group per direction, number of flows per flow-group equals to
  48 | ... | number of IPSec tunnels) with all packets
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  50 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  51 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  52 | ... | is applied to both streams.
  53 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  54
  55 *** Variables ***
  56 | ${nic_name}= | Intel-X710
  57 | ${overhead}= | ${54}
  58 | ${tg_if1_ip4}= | 192.168.10.2
  59 | ${dut1_if1_ip4}= | 192.168.10.1
  60 | ${dut1_if2_ip4}= | 172.168.1.1
  61 | ${dut2_if1_ip4}= | 172.168.1.2
  62 | ${dut2_if2_ip4}= | 192.168.20.1
  63 | ${tg_if2_ip4}= | 192.168.20.2
  64 | ${raddr_ip4}= | 20.0.0.0
  65 | ${laddr_ip4}= | 10.0.0.0
  66 | ${addr_range}= | ${32}
  67 | ${n_tunnels}= | ${1}
  68 # Traffic profile:
  69 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  70
  71 *** Keywords ***
  72 | Local Template
  73 | | [Documentation]
  74 | | ... | [Cfg] DUT runs IPSec tunneling AES GCM config.
  75 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  76 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  80 | | ... | Type: integer, string
  81 | | ... | - phy_cores - Number of physical cores. Type: integer
  82 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  83 | | ...
  84 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  85 | | ...
  86 | | Set Test Variable | \${frame_size}
  87 | | ...
  88 | | # These are enums (not strings) so they cannot be in Variables table.
  89 | | ${encr_alg} = | Crypto Alg AES GCM 128
  90 | | ${auth_alg} = | Integ Alg AES GCM 128
  91 | | ${ipsec_proto} = | IPsec Proto ESP
  92 | | ...
  93 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  94 | | And Add PCI devices to all DUTs
  95 | | Set Max Rate And Jumbo And Handle Multi Seg
  96 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
  97 | | ... | aesni_gcm | ${phy_cores}
  98 | | And Add DPDK dev default RXD to all DUTs | 2048
  99 | | And Add DPDK dev default TXD to all DUTs | 2048
 100 | | And Apply startup configuration on all VPP DUTs
 101 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 102 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
 103 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
 104 | | And VPP IPsec Backend Dump | ${dut1}
 105 | | And VPP IPsec Backend Dump | ${dut2}
 106 | | And Initialize IPSec in 3-node circular topology
 107 | | And VPP IPsec Create Tunnel Interfaces
 108 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 109 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
 110 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 111 | | Then Find NDR and PDR intervals using optimized search
 112
 113 *** Test Cases ***
 114 | tc01-64B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 115 | | [Tags] | 64B | 1C
 116 | | frame_size=${64} | phy_cores=${1}
 117
 118 | tc02-64B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 119 | | [Tags] | 64B | 2C
 120 | | frame_size=${64} | phy_cores=${2}
 121
 122 | tc03-64B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 123 | | [Tags] | 64B | 4C
 124 | | frame_size=${64} | phy_cores=${4}
 125
 126 | tc04-1518B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 127 | | [Tags] | 1518B | 1C
 128 | | frame_size=${1518} | phy_cores=${1}
 129
 130 | tc05-1518B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 131 | | [Tags] | 1518B | 2C
 132 | | frame_size=${1518} | phy_cores=${2}
 133
 134 | tc06-1518B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 135 | | [Tags] | 1518B | 4C
 136 | | frame_size=${1518} | phy_cores=${4}
 137
 138 | tc07-9000B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 139 | | [Tags] | 9000B | 1C
 140 | | frame_size=${9000} | phy_cores=${1}
 141
 142 | tc08-9000B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 143 | | [Tags] | 9000B | 2C
 144 | | frame_size=${9000} | phy_cores=${2}
 145
 146 | tc09-9000B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 147 | | [Tags] | 9000B | 4C
 148 | | frame_size=${9000} | phy_cores=${4}
 149
 150 | tc10-IMIX-1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 151 | | [Tags] | IMIX | 1C
 152 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 153
 154 | tc11-IMIX-2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 155 | | [Tags] | IMIX | 2C
 156 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 157
 158 | tc12-IMIX-4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdr
 159 | | [Tags] | IMIX | 4C
 160 | | frame_size=IMIX_v4_1 | phy_cores=${4}