CSIT-1506: Rework IPsec base testcases
[csit.git] / tests / vpp / perf / crypto / 10ge2p1x710-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr.robot
1 # Copyright (c) 2019 Cisco and/or its affiliates.
2 # Licensed under the Apache License, Version 2.0 (the "License");
3 # you may not use this file except in compliance with the License.
4 # You may obtain a copy of the License at:
5 #
6 #     http://www.apache.org/licenses/LICENSE-2.0
7 #
8 # Unless required by applicable law or agreed to in writing, software
9 # distributed under the License is distributed on an "AS IS" BASIS,
10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
11 # See the License for the specific language governing permissions and
12 # limitations under the License.
13
14 *** Settings ***
15 | Resource | resources/libraries/robot/performance/performance_setup.robot
16 | Resource | resources/libraries/robot/crypto/ipsec.robot
17 | ...
18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | BASE
20 | ... | AES_128_GCM | AES
21 | ...
22 | Suite Setup | Run Keywords
23 | ... | Set up IPSec performance test suite | L3 | ${nic_name} | SW_cryptodev
24 | ... | AND | Set up performance test suite with crypto ipsecmb
25 | Suite Teardown | Tear down 3-node performance topology
26 | ...
27 | Test Setup | Set up performance test
28 | Test Teardown | Tear down performance test
29 | ...
30 | Test Template | Local Template
31 | ...
32 | Documentation | *RFC2544: Pkt throughput IPv4 IPsec tunnel mode.*
33 | ...
34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
35 | ... | with single links between nodes.
36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
37 | ... | Eth-IPv4-IPSec on DUT1-DUT2
38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
39 | ... | crypto devices and multiple IPsec tunnels between them.
40 | ... | DUTs get IPv4 traffic from TG, encrypt it
41 | ... | and send to another DUT, where packets are decrypted and sent back to TG
42 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
43 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
44 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
45 | ... | of packets transmitted. NDR and PDR are discovered for different\
46 | ... | Ethernet L2 frame sizes using MLRsearch library.\
47 | ... | Test packets are generated by TG on
48 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
49 | ... | (flow-group per direction, number of flows per flow-group equals to
50 | ... | number of IPSec tunnels) with all packets
51 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
52 | ... | static payload. MAC addresses are matching MAC addresses of the TG
53 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
54 | ... | is applied to both streams.
55 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
56
57 *** Variables ***
58 | ${nic_name}= | Intel-X710
59 | ${overhead}= | ${54}
60 | ${tg_if1_ip4}= | 192.168.10.2
61 | ${dut1_if1_ip4}= | 192.168.10.1
62 | ${dut1_if2_ip4}= | 172.168.1.1
63 | ${dut2_if1_ip4}= | 172.168.1.2
64 | ${dut2_if2_ip4}= | 192.168.20.1
65 | ${tg_if2_ip4}= | 192.168.20.2
66 | ${raddr_ip4}= | 20.0.0.0
67 | ${laddr_ip4}= | 10.0.0.0
68 | ${addr_range}= | ${32}
69 | ${n_tunnels}= | ${1}
70 # Traffic profile:
71 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
72
73 *** Keywords ***
74 | Local Template
75 | | [Documentation]
76 | | ... | [Cfg] DUT runs IPSec tunneling AES_128_GCM config.\
77 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
78 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
79 | | ...
80 | | ... | *Arguments:*
81 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
82 | | ... | Type: integer, string
83 | | ... | - phy_cores - Number of physical cores. Type: integer
84 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
85 | | ...
86 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
87 | | ...
88 | | Set Test Variable | \${frame_size}
89 | | ...
90 | | # These are enums (not strings) so they cannot be in Variables table.
91 | | ${encr_alg} = | Crypto Alg AES GCM 128
92 | | ${auth_alg} = | Integ Alg AES GCM 128
93 | | ${ipsec_proto} = | IPsec Proto ESP
94 | | ...
95 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
96 | | And Add PCI devices to all DUTs
97 | | Set Max Rate And Jumbo And Handle Multi Seg
98 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
99 | | ... | aesni_gcm | ${phy_cores}
100 | | And Apply startup configuration on all VPP DUTs
101 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
102 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
103 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
104 | | And Initialize IPSec in 3-node circular topology
105 | | And VPP IPsec Create Tunnel Interfaces
106 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
107 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
108 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
109 | | Then Find NDR and PDR intervals using optimized search
110
111 *** Test Cases ***
112 | tc01-64B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
113 | | [Tags] | 64B | 1C
114 | | frame_size=${64} | phy_cores=${1}
115
116 | tc02-64B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
117 | | [Tags] | 64B | 2C
118 | | frame_size=${64} | phy_cores=${2}
119
120 | tc03-64B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
121 | | [Tags] | 64B | 4C
122 | | frame_size=${64} | phy_cores=${4}
123
124 | tc04-1518B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
125 | | [Tags] | 1518B | 1C
126 | | frame_size=${1518} | phy_cores=${1}
127
128 | tc05-1518B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
129 | | [Tags] | 1518B | 2C
130 | | frame_size=${1518} | phy_cores=${2}
131
132 | tc06-1518B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
133 | | [Tags] | 1518B | 4C
134 | | frame_size=${1518} | phy_cores=${4}
135
136 | tc07-9000B-1c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
137 | | [Tags] | 9000B | 1C
138 | | frame_size=${9000} | phy_cores=${1}
139
140 | tc08-9000B-2c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
141 | | [Tags] | 9000B | 2C
142 | | frame_size=${9000} | phy_cores=${2}
143
144 | tc09-9000B-4c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
145 | | [Tags] | 9000B | 4C
146 | | frame_size=${9000} | phy_cores=${4}
147
148 | tc10-IMIX-1c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
149 | | [Tags] | IMIX | 1C
150 | | frame_size=IMIX_v4_1 | phy_cores=${1}
151
152 | tc11-IMIX-2c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
153 | | [Tags] | IMIX | 2C
154 | | frame_size=IMIX_v4_1 | phy_cores=${2}
155
156 | tc12-IMIX-4c-ethip4ipsecbasetnlsw-ip4base-int-aes128gcm-ndrpdr
157 | | [Tags] | IMIX | 4C
158 | | frame_size=IMIX_v4_1 | phy_cores=${4}

©2016 FD.io a Linux Foundation Collaborative Project. All Rights Reserved.
Linux Foundation is a registered trademark of The Linux Foundation. Linux is a registered trademark of Linus Torvalds.
Please see our privacy policy and terms of use.