tests/vpp/perf/crypto/10ge2p1x710-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECTUN | NIC_Intel-X710 | BASE | CBC_SHA1
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | ${nic_name}
  22 | ... | SW_cryptodev
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance test
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  35 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  36 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
  37 | ... | crypto devices and multiple IPsec tunnels between them. DUTs get IPv4
  38 | ... | traffic from TG, encrypt it and send to another DUT, where packets are
  39 | ... | decrypted and sent back to TG.
  40 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  41 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  42 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  43 | ... | of packets transmitted. NDR and PDR are discovered for different\
  44 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  45 | ... | Test packets are generated by TG on
  46 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  47 | ... | (flow-group per direction, number of flows per flow-group equals to
  48 | ... | number of IPSec tunnels) with all packets
  49 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  50 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  51 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  52 | ... | is applied to both streams.
  53 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  54
  55 *** Variables ***
  56 | ${nic_name}= | Intel-X710
  57 | ${overhead}= | ${58}
  58 | ${tg_if1_ip4}= | 192.168.10.2
  59 | ${dut1_if1_ip4}= | 192.168.10.1
  60 | ${dut1_if2_ip4}= | 172.168.1.1
  61 | ${dut2_if1_ip4}= | 172.168.1.2
  62 | ${dut2_if2_ip4}= | 192.168.20.1
  63 | ${tg_if2_ip4}= | 192.168.20.2
  64 | ${raddr_ip4}= | 20.0.0.0
  65 | ${laddr_ip4}= | 10.0.0.0
  66 | ${addr_range}= | ${32}
  67 | ${n_tunnels}= | ${1}
  68 # Traffic profile:
  69 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  70
  71 *** Keywords ***
  72 | Local Template
  73 | | [Documentation]
  74 | | ... | [Cfg] DUT runs IPSec tunneling CBC-SHA1 config.
  75 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  76 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  77 | | ...
  78 | | ... | *Arguments:*
  79 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  80 | | ... | Type: integer, string
  81 | | ... | - phy_cores - Number of physical cores. Type: integer
  82 | | ... | - search_type - NDR or PDR. Type: string
  83 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  84 | | ... | - min_rate - Min rate for binary search, default value: ${50000}.
  85 | | ... | Type: integer
  86 | | ...
  87 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  88 | | ...
  89 | | Set Test Variable | \${frame_size}
  90 | | ...
  91 | | # These are enums (not strings) so they cannot be in Variables table.
  92 | | ${encr_alg}= | Crypto Alg AES CBC 128
  93 | | ${auth_alg}= | Integ Alg SHA1 96
  94 | | ...
  95 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  96 | | And Add PCI devices to all DUTs
  97 | | Set Max Rate And Jumbo And Handle Multi Seg
  98 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
  99 | | ... | aesni_mb | ${phy_cores}
 100 | | And Add DPDK dev default RXD to all DUTs | 2048
 101 | | And Add DPDK dev default TXD to all DUTs | 2048
 102 | | And Apply startup configuration on all VPP DUTs
 103 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 104 | | And Initialize IPSec in 3-node circular topology
 105 | | And Vpp Route Add | ${dut1} | ${raddr_ip4} | 8 | gateway=${dut2_if1_ip4}
 106 | | ... | interface=${dut1_if2}
 107 | | And Vpp Route Add | ${dut2} | ${laddr_ip4} | 8 | gateway=${dut1_if2_ip4}
 108 | | ... | interface=${dut2_if1}
 109 | | And VPP IPsec Add Multiple Tunnels
 110 | | ... | ${dut1} | ${dut2} | ${dut1_if2} | ${dut2_if1} | ${n_tunnels}
 111 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key}
 112 | | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${laddr_ip4} | ${raddr_ip4}
 113 | | ... | ${addr_range}
 114 | | Then Find NDR and PDR intervals using optimized search
 115
 116 *** Test Cases ***
 117 | tc01-64B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 118 | | [Tags] | 64B | 1C
 119 | | frame_size=${64} | phy_cores=${1}
 120
 121 | tc02-64B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 122 | | [Tags] | 64B | 2C
 123 | | frame_size=${64} | phy_cores=${2}
 124
 125 | tc03-64B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 126 | | [Tags] | 64B | 4C
 127 | | frame_size=${64} | phy_cores=${4}
 128
 129 | tc04-1518B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 130 | | [Tags] | 1518B | 1C
 131 | | frame_size=${1518} | phy_cores=${1}
 132
 133 | tc05-1518B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 134 | | [Tags] | 1518B | 2C
 135 | | frame_size=${1518} | phy_cores=${2}
 136
 137 | tc06-1518B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 138 | | [Tags] | 1518B | 4C
 139 | | frame_size=${1518} | phy_cores=${4}
 140
 141 | tc07-9000B-1c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 142 | | [Tags] | 9000B | 1C
 143 | | frame_size=${9000} | phy_cores=${1}
 144
 145 | tc08-9000B-2c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 146 | | [Tags] | 9000B | 2C
 147 | | frame_size=${9000} | phy_cores=${2}
 148
 149 | tc09-9000B-4c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 150 | | [Tags] | 9000B | 4C
 151 | | frame_size=${9000} | phy_cores=${4}
 152
 153 | tc10-IMIX-1c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 154 | | [Tags] | IMIX | 1C
 155 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 156
 157 | tc11-IMIX-2c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 158 | | [Tags] | IMIX | 2C
 159 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 160
 161 | tc12-IMIX-4c-ethip4ipsecbasetnlsw-ip4base-tnl-cbc-sha1-ndrpdr
 162 | | [Tags] | IMIX | 4C
 163 | | frame_size=IMIX_v4_1 | phy_cores=${4}