tests/vpp/perf/crypto/2n1l-10ge2p1x710-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf.robot

   1 # Copyright (c) 2021 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 |
  18 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | UDIR | PERFTEST | HW_ENV | RECONF
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECINT | NIC_Intel-X710 | SCALE | TNL_40
  20 | ... | AES_256_GCM | AES | 1_ADDED_TUNNEL | DRV_VFIO_PCI
  21 | ... | RXQ_SIZE_0 | TXQ_SIZE_0
  22 | ... | ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir
  23 |
  24 | Suite Setup | Setup suite topology interfaces | performance
  25 | Suite Teardown | Tear down suite | performance
  26 | Test Setup | Setup test | performance
  27 | Test Teardown | Tear down test | performance | ipsec_sa
  28 |
  29 | Test Template | Local Template
  30 |
  31 | Documentation | **RFC2544: Packet loss IPv4 IPsec tunnel mode.**
  32 | ... |
  33 | ... | - **[Top] Network Topologies:** TG-DUT1-TG 2-node circular topology \
  34 | ... | with single links between nodes.
  35 | ... |
  36 | ... | - **[Enc] Packet Encapsulations:** Eth-IPv4 on TG-DUT1, \
  37 | ... | Eth-IPv4-IPSec on DUT1-TG.
  38 | ... |
  39 | ... | - **[Cfg] DUT configuration:** DUT1 is configured with multiple IPsec \
  40 | ... | tunnels between it and TG. DUT gets IPv4 traffic from TG, encrypts it \
  41 | ... | and sends back to TG.
  42 | ... |
  43 | ... | - **[Ver] TG verification:** TG finds throughput NDR (Non Drop Rate) \
  44 | ... | with zero packet loss tolerance, then measures loss at this load \
  45 | ... | while additional tunnels are configured. \
  46 | ... | Test packets are generated by TG on \
  47 | ... | links to DUTs. TG traffic profile contains one L3 flow-groups \
  48 | ... | (flow-group per direction, number of flows per flow-group equals to \
  49 | ... | number of IPSec tunnels) with all packets \
  50 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and \
  51 | ... | static payload. MAC addresses are matching MAC addresses of the TG \
  52 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) \
  53 | ... | field is applied to the stream.
  54 | ... |
  55 | ... | - **[Ref] Applicable standard specifications:** RFC4303 and RFC2544.
  56
  57 *** Variables ***
  58 | @{plugins_to_enable}= | dpdk_plugin.so | perfmon_plugin.so
  59 | ... | crypto_native_plugin.so
  60 | ... | crypto_ipsecmb_plugin.so | crypto_openssl_plugin.so
  61 | ${crypto_type}= | ${None}
  62 | ${nic_name}= | Intel-X710
  63 | ${nic_driver}= | vfio-pci
  64 | ${nic_rxq_size}= | 0
  65 | ${nic_txq_size}= | 0
  66 | ${nic_pfs}= | 2
  67 | ${nic_vfs}= | 0
  68 | ${osi_layer}= | L3
  69 | ${overhead}= | ${54}
  70 | ${tg_if1_ip4}= | 192.168.10.2
  71 | ${dut1_if1_ip4}= | 192.168.10.1
  72 | ${tun_if1_ip4}= | 100.0.0.1
  73 | ${tun_if2_ip4}= | 200.0.0.2
  74 | ${raddr_ip4}= | 20.0.0.0
  75 | ${laddr_ip4}= | 10.0.0.0
  76 | ${addr_range}= | ${24}
  77 | ${n_tunnels}= | ${40}
  78 | ${n_added_tunnels}= | ${1}
  79 # Traffic profile:
  80 | ${traffic_profile}= | trex-stl-2n-ethip4-ip4dst${n_tunnels}-udir
  81 | ${traffic_directions}= | ${1}
  82
  83 *** Keywords ***
  84 | Local Template
  85 | | [Documentation]
  86 | | ... | - **[Cfg]** DUT runs IPSec tunneling AES_256_GCM config. \
  87 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  88 | | ... | - **[Ver]** Measure packet loss during reconfig at NDR load.
  89 | |
  90 | | ... | *Arguments:*
  91 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  92 | | ... | Type: integer, string
  93 | | ... | - phy_cores - Number of physical cores. Type: integer
  94 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  95 | |
  96 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  97 | |
  98 | | Set Test Variable | \${frame_size}
  99 | |
 100 | | # These are enums (not strings) so they cannot be in Variables table.
 101 | | ${encr_alg}= | Crypto Alg AES GCM 256
 102 | | ${auth_alg}= | Set Variable | ${NONE}
 103 | | ${ipsec_proto} = | IPsec Proto ESP
 104 | |
 105 | | ${n_total_tunnels} = | Evaluate | ${n_tunnels} + ${n_added_tunnels}
 106 | | Given Set Max Rate And Jumbo
 107 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
 108 | | And Pre-initialize layer driver | ${nic_driver}
 109 | | And Apply startup configuration on all VPP DUTs
 110 | | When Initialize layer driver | ${nic_driver}
 111 | | And Initialize layer interface
 112 | | And Initialize IPSec in 2-node circular topology
 113 | | And VPP IPsec Create Tunnel Interfaces
 114 | | ... | ${nodes} | ${tun_if1_ip4} | ${tun_if2_ip4} | ${DUT1_${int}2}[0]
 115 | | ... | ${TG_pf2}[0] | ${n_tunnels} | ${encr_alg} | ${auth_alg}
 116 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 117 | | ${unidirectional_throughput} = | Find Throughput Using MLRsearch
 118 | | Start Traffic on Background | ${unidirectional_throughput}
 119 | | And VPP IPsec Create Tunnel Interfaces
 120 | | ... | ${nodes} | ${tun_if1_ip4} | ${tun_if2_ip4} | ${DUT1_${int}2}[0]
 121 | | ... | ${TG_pf2}[0] | ${n_total_tunnels} | ${encr_alg} | ${auth_alg}
 122 | | ... | ${laddr_ip4} | ${raddr_ip4} | ${addr_range} | ${n_tunnels}
 123 | | ${result}= | Stop Running Traffic
 124 | | Display Reconfig Test Message | ${result}
 125
 126 *** Test Cases ***
 127 | 64B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 128 | | [Tags] | 64B | 1C
 129 | | frame_size=${64} | phy_cores=${1}
 130
 131 | 64B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 132 | | [Tags] | 64B | 2C
 133 | | frame_size=${64} | phy_cores=${2}
 134
 135 | 64B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 136 | | [Tags] | 64B | 4C
 137 | | frame_size=${64} | phy_cores=${4}
 138
 139 | 1518B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 140 | | [Tags] | 1518B | 1C
 141 | | frame_size=${1518} | phy_cores=${1}
 142
 143 | 1518B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 144 | | [Tags] | 1518B | 2C
 145 | | frame_size=${1518} | phy_cores=${2}
 146
 147 | 1518B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 148 | | [Tags] | 1518B | 4C
 149 | | frame_size=${1518} | phy_cores=${4}
 150
 151 | 9000B-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 152 | | [Tags] | 9000B | 1C
 153 | | frame_size=${9000} | phy_cores=${1}
 154
 155 | 9000B-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 156 | | [Tags] | 9000B | 2C
 157 | | frame_size=${9000} | phy_cores=${2}
 158
 159 | 9000B-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 160 | | [Tags] | 9000B | 4C
 161 | | frame_size=${9000} | phy_cores=${4}
 162
 163 | IMIX-1c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 164 | | [Tags] | IMIX | 1C
 165 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 166
 167 | IMIX-2c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 168 | | [Tags] | IMIX | 2C
 169 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 170
 171 | IMIX-4c-ethip4ipsec40tnlsw-1atnl-ip4base-int-aes256gcm-udir-reconf
 172 | | [Tags] | IMIX | 4C
 173 | | frame_size=IMIX_v4_1 | phy_cores=${4}