tests/vpp/perf/crypto/40ge2p1xl710-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECTUN | NIC_Intel-XL710 | BASE
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | Intel-XL710
  22 | ... | HW_cryptodev
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | ...
  27 | Test Teardown | Tear down performance mrr test
  28 | ...
  29 | Test Template | Local template
  30 | ...
  31 | Documentation | *Raw results IPv4 IPsec tunnel mode performance test suite.*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  34 | ... | with single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  36 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  37 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  38 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  39 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  40 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  41 | ... | at line rate and reports total received/sent packets over trial period.
  42 | ... | Test packets are generated by TG on
  43 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  44 | ... | (flow-group per direction, number of flows per flow-group equals to
  45 | ... | number of IPSec tunnels) with all packets
  46 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  47 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  48 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  49 | ... | is applied to both streams.
  50 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  51
  52 *** Variables ***
  53 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  54 | ${s_24.5G}= | ${24500000000}
  55 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  56 | ${s_18.75Mpps}= | ${18750000}
  57 | ${tg_if1_ip4}= | 192.168.10.2
  58 | ${dut1_if1_ip4}= | 192.168.10.1
  59 | ${dut1_if2_ip4}= | 172.168.1.1
  60 | ${dut2_if1_ip4}= | 172.168.1.2
  61 | ${dut2_if2_ip4}= | 192.168.20.1
  62 | ${tg_if2_ip4}= | 192.168.20.2
  63 | ${raddr_ip4}= | 20.0.0.0
  64 | ${laddr_ip4}= | 10.0.0.0
  65 | ${addr_range}= | ${32}
  66 | ${ipsec_overhead}= | ${58}
  67 | ${n_tunnels}= | ${1}
  68 # Traffic profile:
  69 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  70
  71 *** Keywords ***
  72 | Local template
  73 | | [Documentation]
  74 | | ... | [Cfg] DUT runs IPSec tunneling CBC-SHA1 config.
  75 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  76 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  77 | | ... | trial throughput test.
  78 | | ...
  79 | | ... | *Arguments:*
  80 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  81 | | ... | Type: integer, string
  82 | | ... | - phy_cores - Number of physical cores. Type: integer
  83 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  84 | | ...
  85 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  86 | | ...
  87 | | Set Test Variable | ${framesize}
  88 | | ${get_framesize}= | Get Frame Size | ${framesize}
  89 | | ${max_rate}= | Calculate pps | ${s_24.5G}
  90 | | ... | ${get_framesize} + ${ipsec_overhead}
  91 | | ${max_rate}= | Set Variable If
  92 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
  93 | | ${encr_alg}= | Crypto Alg AES CBC 128
  94 | | ${auth_alg}= | Integ Alg SHA1 96
  95 | | ...
  96 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  97 | | And Add PCI devices to all DUTs
  98 | | And Run Keyword If | ${get_framesize} + ${ipsec_overhead} < ${1522}
  99 | | ... | Add no multi seg to all DUTs
 100 | | And Add cryptodev to all DUTs | ${${phy_cores}}
 101 | | And Add DPDK dev default RXD to all DUTs | 2048
 102 | | And Add DPDK dev default TXD to all DUTs | 2048
 103 | | And Apply startup configuration on all VPP DUTs
 104 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 105 | | And Initialize IPSec in 3-node circular topology
 106 | | And VPP IPsec Create Tunnel Interfaces
 107 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 108 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
 109 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 110 | | And Set interfaces in path in 3-node circular topology up
 111 | | Then Traffic should pass with maximum rate
 112 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 113
 114 *** Test Cases ***
 115 | tc01-64B-1t1c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 116 | | [Tags] | 64B | 1C
 117 | | framesize=${64} | phy_cores=${1}
 118
 119 | tc02-1518B-1t1c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 120 | | [Tags] | 1518B | 1C
 121 | | framesize=${1518} | phy_cores=${1}
 122
 123 | tc04-IMIX-1t1c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 124 | | [Tags] | IMIX | 1C
 125 | | framesize=IMIX_v4_1 | phy_cores=${1}
 126
 127 | tc05-64B-2t2c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 128 | | [Tags] | 64B | 2C
 129 | | framesize=${64} | phy_cores=${2}
 130
 131 | tc06-1518B-2t2c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 132 | | [Tags] | 1518B | 2C
 133 | | framesize=${1518} | phy_cores=${2}
 134
 135 | tc08-IMIX-2t2c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 136 | | [Tags] | IMIX | 2C
 137 | | framesize=IMIX_v4_1 | phy_cores=${2}
 138
 139 | tc09-64B-4t4c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 140 | | [Tags] | 64B | 4C
 141 | | framesize=${64} | phy_cores=${4}
 142
 143 | tc10-1518B-4t4c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 144 | | [Tags] | 1518B | 4C
 145 | | framesize=${1518} | phy_cores=${4}
 146
 147 | tc12-IMIX-4t4c-ethip4ipsecbasetnl-ip4base-int-cbc-sha1-mrr
 148 | | [Tags] | IMIX | 4C
 149 | | framesize=IMIX_v4_1 | phy_cores=${4}