tests/vpp/perf/crypto/40ge2p1xl710-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECTUN | NIC_Intel-XL710 | BASE
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | Intel-XL710
  22 | ... | SW_cryptodev
  23 | Suite Teardown | Tear down 3-node performance topology
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Documentation | *Raw results IPv4 IPsec tunnel mode performance test suite.*
  29 | ...
  30 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  31 | ... | with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  33 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  34 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
  35 | ... | crypto devices and multiple IPsec tunnels between them.
  36 | ... | DUTs get IPv4 traffic from TG, encrypt it
  37 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  39 | ... | at line rate and reports total received/sent packets over trial period.
  40 | ... | Test packets are generated by TG on
  41 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  42 | ... | (flow-group per direction, number of flows per flow-group equals to
  43 | ... | number of IPSec tunnels) with all packets
  44 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  45 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  46 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  47 | ... | is applied to both streams.
  48 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  49
  50 *** Variables ***
  51 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  52 | ${s_24.5G}= | ${24500000000}
  53 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  54 | ${s_18.75Mpps}= | ${18750000}
  55 | ${tg_if1_ip4}= | 192.168.10.2
  56 | ${dut1_if1_ip4}= | 192.168.10.1
  57 | ${dut1_if2_ip4}= | 172.168.1.1
  58 | ${dut2_if1_ip4}= | 172.168.1.2
  59 | ${dut2_if2_ip4}= | 192.168.20.1
  60 | ${tg_if2_ip4}= | 192.168.20.2
  61 | ${raddr_ip4}= | 20.0.0.0
  62 | ${laddr_ip4}= | 10.0.0.0
  63 | ${addr_range}= | ${32}
  64 | ${ipsec_overhead}= | ${54}
  65 | ${n_tunnels}= | ${1}
  66 # Traffic profile:
  67 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  68
  69 *** Keywords ***
  70 | Check RR for IPv4 routing with IPSec SW cryptodev
  71 | | [Documentation]
  72 | | ... | [Cfg] DUT runs IPSec tunneling AES GCM config with ${wt} thread(s),\
  73 | | ... | ${wt} phy core(s), ${rxq} receive queue(s) per NIC port.
  74 | | ... | [Ver] Measure MaxReceivedRate for ${framesize} frames using single\
  75 | | ... | trial throughput test.
  76 | | ...
  77 | | [Arguments] | ${framesize} | ${wt} | ${rxq}
  78 | | ...
  79 | | # Test Variables required for test teardown
  80 | | Set Test Variable | ${framesize}
  81 | | ${get_framesize}= | Get Frame Size | ${framesize}
  82 | | ${max_rate}= | Calculate pps | ${s_24.5G}
  83 | | ... | ${get_framesize} + ${ipsec_overhead}
  84 | | ${max_rate}= | Set Variable If
  85 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
  86 | | ${encr_alg}= | Crypto Alg AES GCM 128
  87 | | ${auth_alg}= | Integ Alg AES GCM 128
  88 | | ...
  89 | | Given Add '${wt}' worker threads and '${rxq}' rxqueues in 3-node single-link circular topology
  90 | | And Add PCI devices to DUTs in 3-node single link topology
  91 | | And Run Keyword If | ${get_framesize} < ${1522}
  92 | | ... | Add no multi seg to all DUTs
  93 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
  94 | | ... | aesni_gcm | ${${wt}}
  95 | | And Add DPDK dev default RXD to all DUTs | 2048
  96 | | And Add DPDK dev default TXD to all DUTs | 2048
  97 | | And Apply startup configuration on all VPP DUTs
  98 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
  99 | | And Initialize IPSec in 3-node circular topology
 100 | | And VPP IPsec Create Tunnel Interfaces
 101 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 102 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
 103 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 104 | | And Set interfaces in path in 3-node circular topology up
 105 | | Then Traffic should pass with maximum rate | ${perf_trial_duration}
 106 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 107
 108 *** Test Cases ***
 109 | tc01-64B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 110 | | [Documentation]
 111 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 112 | | ... | with 1 thread, 1 phy core, 1 receive queue per NIC port.
 113 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single trial\
 114 | | ... | throughput test.
 115 | | [Tags] | 64B | 1T1C | STHREAD
 116 | | ...
 117 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 118 | | framesize=${64} | wt=1 | rxq=1
 119
 120 | tc02-1518B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 121 | | [Documentation]
 122 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 123 | | ... | with 1 thread, 1 phy core, 1 receive queue per NIC port.
 124 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 125 | | ... | trial throughput test.
 126 | | [Tags] | 1518B | 1T1C | STHREAD
 127 | | ...
 128 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 129 | | framesize=${1518} | wt=1 | rxq=1
 130
 131 # TODO: Add check to make test fail if rx=0.
 132 # TODO: Add 9000B test cases when they start passing.
 133
 134 | tc04-IMIX-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 135 | | [Documentation]
 136 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 137 | | ... | with 1 thread, 1 phy core, 1 receive queue per NIC port.
 138 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 139 | | ... | trial throughput test.
 140 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 141 | | [Tags] | IMIX | 1T1C | STHREAD
 142 | | ...
 143 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 144 | | framesize=IMIX_v4_1 | wt=1 | rxq=1
 145
 146 | tc05-64B-2t2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 147 | | [Documentation]
 148 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 149 | | ... | with 2 threads, 2 phy cores, 1 receive queue per NIC port.
 150 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single trial\
 151 | | ... | throughput test.
 152 | | [Tags] | 64B | 2T2C | MTHREAD
 153 | | ...
 154 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 155 | | framesize=${64} | wt=2 | rxq=1
 156
 157 | tc06-1518B-2t2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 158 | | [Documentation]
 159 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 160 | | ... | with 2 threads, 2 phy cores, 1 receive queue per NIC port.
 161 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 162 | | ... | trial throughput test.
 163 | | [Tags] | 1518B | 2T2C | MTHREAD
 164 | | ...
 165 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 166 | | framesize=${1518} | wt=2 | rxq=1
 167
 168 | tc08-IMIX-2t2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 169 | | [Documentation]
 170 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 171 | | ... | with 2 threads, 2 phy cores, 1 receive queue per NIC port.
 172 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 173 | | ... | trial throughput test.
 174 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 175 | | [Tags] | IMIX | 2T2C | MTHREAD
 176 | | ...
 177 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 178 | | framesize=IMIX_v4_1 | wt=2 | rxq=1
 179
 180 | tc09-64B-4t4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 181 | | [Documentation]
 182 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 183 | | ... | with 4 threads, 4 phy cores, 2 receive queues per NIC port.
 184 | | ... | [Ver] Measure MaxReceivedRate for 64B frames using single trial\
 185 | | ... | throughput test.
 186 | | [Tags] | 64B | 4T4C | MTHREAD
 187 | | ...
 188 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 189 | | framesize=${64} | wt=4 | rxq=2
 190
 191 | tc10-1518B-4t4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 192 | | [Documentation]
 193 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 194 | | ... | with 4 threads, 4 phy cores, 2 receive queues per NIC port.
 195 | | ... | [Ver] Measure MaxReceivedRate for 1518B frames using single\
 196 | | ... | trial throughput test.
 197 | | [Tags] | 1518B | 4T4C | MTHREAD
 198 | | ...
 199 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 200 | | framesize=${1518} | wt=4 | rxq=2
 201
 202 | tc12-IMIX-4t4c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-mrr
 203 | | [Documentation]
 204 | | ... | [Cfg] DUTs run 1 IPsec tunnel AES GCM in each direction, configured\
 205 | | ... | with 4 threads, 4 phy cores, 2 receive queues per NIC port.
 206 | | ... | [Ver] Measure MaxReceivedRate for IMIX_v4_1 frames using single\
 207 | | ... | trial throughput test.
 208 | | ... | IMIX_v4_1 = (28x64B; 16x570B; 4x1518B)
 209 | | [Tags] | IMIX | 4T4C | MTHREAD
 210 | | ...
 211 | | [Template] | Check RR for IPv4 routing with IPSec SW cryptodev
 212 | | framesize=IMIX_v4_1 | wt=4 | rxq=2