tests/vpp/perf/crypto/40ge2p1xl710-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrpdrdisc.robot

   1 # Copyright (c) 2017 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDRDISC
  19 | ... | IP4FWD | IPSEC | IPSECSW | IPSECTUN | NIC_Intel-XL710 | BASE
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | Intel-XL710
  22 | ... | SW_cryptodev
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  29 | ... | ${framesize} | ${traffic_profile}
  30 | ...
  31 | Test Template | Local template
  32 | ...
  33 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  34 | ...
  35 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  36 | ... | with single links between nodes.
  37 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  38 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  39 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with DPDK SW
  40 | ... | crypto devices and multiple IPsec tunnels between them. DUTs get IPv4
  41 | ... | traffic from TG, encrypt it and send to another DUT, where packets are
  42 | ... | decrypted and sent back to TG.
  43 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  44 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  45 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in number
  46 | ... | of packets transmitted. NDR is discovered for different
  47 | ... | number of IPsec tunnels using binary search algorithms with configured
  48 | ... | starting rate and final step that determines throughput measurement
  49 | ... | resolution. Test packets are generated by TG on
  50 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  51 | ... | (flow-group per direction, number of flows per flow-group equals to
  52 | ... | number of IPSec tunnels) with all packets
  53 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  54 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  55 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  56 | ... | is applied to both streams.
  57 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  58
  59 *** Variables ***
  60 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  61 | ${s_limit}= | ${24500000000}
  62 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  63 | ${s_18.75Mpps}= | ${18750000}
  64 | ${tg_if1_ip4}= | 192.168.10.2
  65 | ${dut1_if1_ip4}= | 192.168.10.1
  66 | ${dut1_if2_ip4}= | 172.168.1.1
  67 | ${dut2_if1_ip4}= | 172.168.1.2
  68 | ${dut2_if2_ip4}= | 192.168.20.1
  69 | ${tg_if2_ip4}= | 192.168.20.2
  70 | ${raddr_ip4}= | 20.0.0.0
  71 | ${laddr_ip4}= | 10.0.0.0
  72 | ${addr_range}= | ${32}
  73 | ${ipsec_overhead_gcm}= | ${54}
  74 | ${n_tunnels}= | ${1}
  75 # Traffic profile:
  76 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  77
  78 *** Keywords ***
  79 | Local template
  80 | | [Documentation]
  81 | | ... | [Cfg] DUT runs IPSec tunneling AES GCM config.
  82 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  83 | | ... | [Ver] Find ${search_type} for ${framesize}B frames using binary search\
  84 | | ... | start at linerate, step ${min_rate}pps.
  85 | | ...
  86 | | ... | *Arguments:*
  87 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  88 | | ... | Type: integer, string
  89 | | ... | - phy_cores - Number of physical cores. Type: integer
  90 | | ... | - search_type - NDR or PDR. Type: string
  91 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  92 | | ... | - min_rate - Min rate for binary search, default value: ${50000}.
  93 | | ... | Type: integer
  94 | | ...
  95 | | [Arguments] | ${framesize} | ${phy_cores} | ${search_type}
  96 | | ... | ${rxq}=${None} | ${min_rate}=${50000}
  97 | | Set Test Variable | ${framesize}
  98 | | Set Test Variable | ${min_rate}
  99 | | ${get_framesize}= | Get Frame Size | ${framesize}
 100 | | ${max_rate}= | Calculate pps | ${s_limit}
 101 | | ... | ${get_framesize} + ${ipsec_overhead_gcm}
 102 | | ${max_rate}= | Set Variable If
 103 | | ... | ${max_rate} > ${s_18.75Mpps} | ${s_18.75Mpps} | ${max_rate}
 104 | | ${binary_min}= | Set Variable | ${min_rate}
 105 | | ${binary_max}= | Set Variable | ${max_rate}
 106 | | ${threshold}= | Set Variable | ${min_rate}
 107 | | ${encr_alg}= | Crypto Alg AES GCM 128
 108 | | ${auth_alg}= | Integ Alg AES GCM 128
 109 | | ...
 110 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
 111 | | And Add PCI devices to all DUTs
 112 | | And Run Keyword If | ${get_framesize} + ${ipsec_overhead_gcm} < ${1522}
 113 | | ... | Add no multi seg to all DUTs
 114 | | And Add DPDK SW cryptodev on DUTs in 3-node single-link circular topology
 115 | | ... | aesni_gcm | ${${phy_cores}}
 116 | | And Add DPDK dev default RXD to all DUTs | 2048
 117 | | And Add DPDK dev default TXD to all DUTs | 2048
 118 | | And Apply startup configuration on all VPP DUTs
 119 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 120 | | And Initialize IPSec in 3-node circular topology
 121 | | And VPP IPsec Create Tunnel Interfaces
 122 | | ... | ${dut1} | ${dut2} | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${dut1_if2}
 123 | | ... | ${dut2_if1} | ${n_tunnels} | ${encr_alg} | ${encr_key} | ${auth_alg}
 124 | | ... | ${auth_key} | ${laddr_ip4} | ${raddr_ip4} | ${addr_range}
 125 | | And Set interfaces in path in 3-node circular topology up
 126 | | Then Run Keyword If | '${search_type}' == 'NDR'
 127 | | ... | Find NDR using binary search and pps
 128 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 129 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 130 | | ... | ELSE IF | '${search_type}' == 'PDR'
 131 | | ... | Find PDR using binary search and pps
 132 | | ... | ${framesize} | ${binary_min} | ${binary_max} | ${traffic_profile}
 133 | | ... | ${min_rate} | ${max_rate} | ${threshold}
 134 | | ... | ${perf_pdr_loss_acceptance} | ${perf_pdr_loss_acceptance_type}
 135
 136 *** Test Cases ***
 137 | tc01-64B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrdisc
 138 | | [Tags] | 64B | 1C | NDRDISC
 139 | | framesize=${64} | phy_cores=${1} | search_type=NDR
 140
 141 | tc02-64B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-pdrdisc
 142 | | [Tags] | 64B | 1C | PDRDISC | SKIP_PATCH
 143 | | framesize=${64} | phy_cores=${1} | search_type=PDR
 144
 145 | tc03-1518B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrdisc
 146 | | [Tags] | 1518B | 1C | NDRDISC
 147 | | framesize=${1518} | phy_cores=${1} | search_type=NDR
 148
 149 | tc04-1518B-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-pdrdisc
 150 | | [Tags] | 1518B | 1C | PDRDISC | SKIP_PATCH
 151 | | framesize=${1518} | phy_cores=${1} | search_type=PDR
 152
 153 | tc05-IMIX-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrdisc
 154 | | [Tags] | IMIX | 1C | NDRDISC
 155 | | framesize=IMIX_v4_1 | phy_cores=${1} | search_type=NDR
 156
 157 | tc06-IMIX-1t1c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-pdrdisc
 158 | | [Tags] | IMIX | 1C | PDRDISC | SKIP_PATCH
 159 | | framesize=IMIX_v4_1 | phy_cores=${1} | search_type=PDR
 160
 161 | tc07-64B-2t2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-ndrdisc
 162 | | [Tags] | 64B | 2C | NDRDISC
 163 | | framesize=${64} | phy_cores=${2} | search_type=NDR
 164
 165 | tc08-64B-2t2c-ethip4ipsecbasetnlsw-ip4base-int-aes-gcm-pdrdisc
 166 | | [Tags] | 64B | 2C | PDRDISC | SKIP_PATCH
 167 | | framesize=${64} | phy_cores=${2} | search_type=PDR