tests/vpp/perf/crypto/40ge2p1xl710-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/crypto/ipsec.robot
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | SCALE | MR
  19 | ... | IP4FWD | IPSEC | IPSECHW | IPSECTUN | NIC_Intel-XL710 | TNL_1000
  20 | ...
  21 | Suite Setup | Set up IPSec performance test suite | L3 | Intel-XL710
  22 | ... | HW_cryptodev
  23 | ...
  24 | Suite Teardown | Tear down 3-node performance topology
  25 | ...
  26 | Test Setup | Set up performance test
  27 | ...
  28 | Test Teardown | Tear down performance mrr test
  29 | ...
  30 | Test Template | Local Template
  31 | ...
  32 | Documentation | *IPv4 IPsec tunnel mode performance test suite.*
  33 | ...
  34 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  35 | ... | with single links between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 on TG-DUTn,
  37 | ... | Eth-IPv4-IPSec on DUT1-DUT2
  38 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with multiple
  39 | ... | IPsec tunnels between them. DUTs get IPv4 traffic from TG, encrypt it
  40 | ... | and send to another DUT, where packets are decrypted and sent back to TG
  41 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  42 | ... | at line rate and reports total received/sent packets over trial period.
  43 | ... | Test packets are generated by TG on
  44 | ... | links to DUTs. TG traffic profile contains two L3 flow-groups
  45 | ... | (flow-group per direction, number of flows per flow-group equals to
  46 | ... | number of IPSec tunnels) with all packets
  47 | ... | containing Ethernet header, IPv4 header with IP protocol=61 and
  48 | ... | static payload. MAC addresses are matching MAC addresses of the TG
  49 | ... | node interfaces. Incrementing of IP.dst (IPv4 destination address) field
  50 | ... | is applied to both streams.
  51 | ... | *[Ref] Applicable standard specifications:* RFC4303 and RFC2544.
  52
  53 *** Variables ***
  54 # XL710-DA2 bandwidth limit ~49Gbps/2=24.5Gbps
  55 | ${s_24.5G}= | ${24500000000}
  56 # XL710-DA2 Mpps limit 37.5Mpps/2=18.75Mpps
  57 | ${s_18.75Mpps}= | ${18750000}
  58 | ${tg_if1_ip4}= | 192.168.10.2
  59 | ${dut1_if1_ip4}= | 192.168.10.1
  60 | ${dut1_if2_ip4}= | 172.168.1.1
  61 | ${dut2_if1_ip4}= | 172.168.1.2
  62 | ${dut2_if2_ip4}= | 192.168.20.1
  63 | ${tg_if2_ip4}= | 192.168.20.2
  64 | ${raddr_ip4}= | 20.0.0.0
  65 | ${laddr_ip4}= | 10.0.0.0
  66 | ${addr_range}= | ${32}
  67 | ${overhead}= | ${54}
  68 | ${n_tunnels}= | ${1000}
  69 # Traffic profile:
  70 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${n_tunnels}
  71
  72 *** Keywords ***
  73 | Local Template
  74 | | [Documentation]
  75 | | ... | [Cfg] DUTs run 1000 IPsec tunnels AES GCM in each direction.
  76 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  77 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  78 | | ... | trial throughput test.
  79 | | ...
  80 | | ... | *Arguments:*
  81 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  82 | | ... | Type: integer, string
  83 | | ... | - phy_cores - Number of physical cores. Type: integer
  84 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  85 | | ...
  86 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  87 | | ...
  88 | | ${encr_alg} = | Crypto Alg AES GCM 128
  89 | | ${auth_alg} = | Integ Alg AES GCM 128
  90 | | ${ipsec_proto} = | IPsec Proto ESP
  91 | | ...
  92 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  93 | | And Add PCI devices to all DUTs
  94 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  95 | | ... | ${s_24.5G} | ${framesize} | overhead=${overhead}
  96 | | ... | pps_limit=${s_18.75Mpps}
  97 | | And Add cryptodev to all DUTs | ${phy_cores}
  98 | | And Add DPDK dev default RXD to all DUTs | 2048
  99 | | And Add DPDK dev default TXD to all DUTs | 2048
 100 | | And Apply startup configuration on all VPP DUTs
 101 | | When Generate keys for IPSec | ${encr_alg} | ${auth_alg}
 102 | | And VPP IPsec Backend Dump | ${dut1}
 103 | | And VPP IPsec Backend Dump | ${dut2}
 104 | | And VPP IPsec Select Backend | ${dut1} | ${ipsec_proto} | index=${1}
 105 | | And VPP IPsec Select Backend | ${dut2} | ${ipsec_proto} | index=${1}
 106 | | And VPP IPsec Backend Dump | ${dut1}
 107 | | And VPP IPsec Backend Dump | ${dut2}
 108 | | And Initialize IPSec in 3-node circular topology
 109 | | And Vpp Route Add | ${dut1} | ${raddr_ip4} | 8 | gateway=${dut2_if1_ip4}
 110 | | ... | interface=${dut1_if2}
 111 | | And Vpp Route Add | ${dut2} | ${laddr_ip4} | 8 | gateway=${dut1_if2_ip4}
 112 | | ... | interface=${dut2_if1}
 113 | | And VPP IPsec Add Multiple Tunnels
 114 | | ... | ${dut1} | ${dut2} | ${dut1_if2} | ${dut2_if1} | ${n_tunnels}
 115 | | ... | ${encr_alg} | ${encr_key} | ${auth_alg} | ${auth_key}
 116 | | ... | ${dut1_if2_ip4} | ${dut2_if1_ip4} | ${laddr_ip4} | ${raddr_ip4}
 117 | | ... | ${addr_range}
 118 | | Then Traffic should pass with maximum rate
 119 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
 120
 121 *** Test Cases ***
 122 | tc01-64B-1c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 123 | | [Tags] | 64B | 1C
 124 | | framesize=${64} | phy_cores=${1}
 125
 126 | tc02-64B-2c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 127 | | [Tags] | 64B | 2C
 128 | | framesize=${64} | phy_cores=${2}
 129
 130 | tc03-64B-4c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 131 | | [Tags] | 64B | 4C
 132 | | framesize=${64} | phy_cores=${4}
 133
 134 | tc04-1518B-1c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 135 | | [Tags] | 1518B | 1C
 136 | | framesize=${1518} | phy_cores=${1}
 137
 138 | tc05-1518B-2c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 139 | | [Tags] | 1518B | 2C
 140 | | framesize=${1518} | phy_cores=${2}
 141
 142 | tc06-1518B-4c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 143 | | [Tags] | 1518B | 4C
 144 | | framesize=${1518} | phy_cores=${4}
 145
 146 | tc07-9000B-1c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 147 | | [Tags] | 9000B | 1C
 148 | | framesize=${9000} | phy_cores=${1}
 149
 150 | tc08-9000B-2c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 151 | | [Tags] | 9000B | 2C
 152 | | framesize=${9000} | phy_cores=${2}
 153
 154 | tc09-9000B-4c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 155 | | [Tags] | 9000B | 4C
 156 | | framesize=${9000} | phy_cores=${4}
 157
 158 | tc10-IMIX-1c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 159 | | [Tags] | IMIX | 1C
 160 | | framesize=IMIX_v4_1 | phy_cores=${1}
 161
 162 | tc11-IMIX-2c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 163 | | [Tags] | IMIX | 2C
 164 | | framesize=IMIX_v4_1 | phy_cores=${2}
 165
 166 | tc12-IMIX-4c-ethip4ipsecscale1000tnl-ip4base-tnl-aes-gcm-mrr
 167 | | [Tags] | IMIX | 4C
 168 | | framesize=IMIX_v4_1 | phy_cores=${4}