tests/vpp/perf/hoststack/2n1l-10ge2p1x710-eth-ip4tcphttp-wrk8u8c50con-rps.robot

   1 # Copyright (c) 2020 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15
  16 | Library  | resources.tools.wrk.wrk
  17 | Resource | resources/libraries/robot/wrk/wrk_utils.robot
  18 | Resource | resources/libraries/robot/shared/default.robot
  19 | Resource | resources/libraries/robot/hoststack/tcp_setup.robot
  20 |
  21 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV
  22 | ... | HTTP | TCP | TCP_RPS | NIC_Intel-X710 | DRV_VFIO_PCI
  23 | ... | eth-ip4tcphttp-wrk8u8c50con
  24 |
  25 | Suite Setup | Setup suite single link | wrk
  26 | Suite Teardown | Tear down suite | wrk
  27 | Test Setup | Setup test
  28 | Test Teardown | Tear down test
  29 |
  30 | Test Template | Local template
  31 |
  32 | Documentation | *HTTP requests per seconds.*
  33 |
  34 | ... | *[Top] Network Topologies:* TG-DUT-TG 2-node topology
  35 | ... | with single link between nodes.
  36 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-TCP-HTTP for TCP Host Stack
  37 | ... | *[Cfg] DUT configuration:*
  38 | ... | *[Ver] TG verification:*
  39 | ... | *[Ref] Applicable standard specifications:*
  40
  41 *** Variables ***
  42 | @{plugins_to_enable}= | dpdk_plugin.so | http_static_plugin.so
  43 | ... | hs_apps_plugin.so
  44 | ${crypto_type}= | ${None}
  45 | ${nic_name}= | Intel-X710
  46 | ${nic_driver}= | vfio-pci
  47 | ${overhead}= | ${0}
  48 | ${frame_size}= | IMIX_v4_1
  49 | ${traffic_profile}= | wrk-sf-2n-ethip4tcphttp-8u8c50con-rps
  50 | ${http_static_plugin}= | ${true}
  51
  52 *** Keywords ***
  53 | Local template
  54 | | [Arguments] | ${phy_cores} | ${rxq}=${None}
  55 | |
  56 | | Given Set Max Rate And Jumbo
  57 | | And Add worker threads to all DUTs | ${phy_cores} | ${rxq}
  58 | | And Pre-initialize layer driver | ${nic_driver}
  59 | | FOR | ${dut} | IN | @{duts}
  60 | | | Import Library | resources.libraries.python.VppConfigGenerator
  61 | | | ... | WITH NAME | ${dut}
  62 | | | Run keyword | ${dut}.Add api segment global size | 2G
  63 | | | Run keyword | ${dut}.Add api segment api size | 1G
  64 | | | Run keyword | ${dut}.Add TCP preallocated connections | 1000000
  65 | | | Run keyword | ${dut}.Add TCP preallocated half open connections | 1000000
  66 | | | Run keyword | ${dut}.Add session event queue length | 1000000
  67 | | | Run keyword | ${dut}.Add session preallocated sessions | 1000000
  68 | | | Run keyword | ${dut}.Add session v4 session table buckets | 500000
  69 | | | Run keyword | ${dut}.Add session v4 session table memory | 1g
  70 | | | Run keyword | ${dut}.Add session v4 halfopen table buckets | 2500000
  71 | | | Run keyword | ${dut}.Add session v4 halfopen table memory | 3g
  72 | | | Run keyword | ${dut}.Add session local endpoints table buckets | 2500000
  73 | | | Run keyword | ${dut}.Add session local endpoints table memory | 3g
  74 | | END
  75 | | And Apply startup configuration on all VPP DUTs
  76 | | When Initialize layer driver | ${nic_driver}
  77 | | And Initialize layer interface
  78 | | And Set up HTTP server with parameters on the VPP node
  79 | | ... | ${http_static_plugin} | 500000 | 4 | 4000m
  80 | | Then Measure requests per second | ${traffic_profile}
  81
  82 *** Test Cases ***
  83 | tc01-IMIX-1c-eth-ip4tcphttp-wrk8u8c50con-rps
  84 | | [Tags] | 1C
  85 | | phy_cores=${1}
  86
  87 | tc02-IMIX-2c-eth-ip4tcphttp-wrk8u8c50con-rps
  88 | | [Tags] | 2C
  89 | | phy_cores=${2}
  90
  91 | tc03-IMIX-4c-eth-ip4tcphttp-wrk8u8c50con-rps
  92 | | [Tags] | 4C
  93 | | phy_cores=${4}