tests/vpp/perf/ip4/10ge2p1x520-ethip4-ip4scale2m-mrr.robot

   1 # Copyright (c) 2018 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | MRR
  18 | ... | NIC_Intel-X520-DA2 | ETH | IP4FWD | SCALE | FIB_2M
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L3 | Intel-X520-DA2
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | ...
  26 | Test Teardown | Tear down performance mrr test
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *Raw results IPv4 routing test cases*
  31 | ...
  32 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  33 | ... | with single links between nodes.
  34 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  35 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  36 | ... | routing and 2x100k static IPv4 /32 route entries. DUT1 and DUT2 tested
  37 | ... | with 2p10GE NIC X520 Niantic by Intel.
  38 | ... | *[Ver] TG verification:* In MaxReceivedRate test TG sends traffic
  39 | ... | at line rate and reports total received/sent packets over trial period.
  40 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  41 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  42 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  43 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  44 | ... | addresses of the TG node interfaces.
  45 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  46
  47 *** Variables ***
  48 # X520-DA2 bandwidth limit
  49 | ${s_limit}= | ${10000000000}
  50 | ${rts_per_flow}= | ${1000000}
  51 # Traffic profile:
  52 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4dst${rts_per_flow}
  53
  54 *** Keywords ***
  55 | Local Template
  56 | | ...
  57 | | [Documentation]
  58 | | ... | [Cfg] DUT runs IPv4 routing config.
  59 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  60 | | ... | [Ver] Measure MaxReceivedRate for ${framesize}B frames using single\
  61 | | ... | trial throughput test.
  62 | | ...
  63 | | ... | *Arguments:*
  64 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  65 | | ... | Type: integer, string
  66 | | ... | - phy_cores - Number of physical cores. Type: integer
  67 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  68 | | ...
  69 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  70 | | ...
  71 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  72 | | And Add PCI devices to all DUTs
  73 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  74 | | ... | ${s_limit} | ${framesize}
  75 | | And Apply startup configuration on all VPP DUTs
  76 | | When Initialize IPv4 forwarding with scaling in 3-node circular topology
  77 | | ... | ${rts_per_flow}
  78 | | Then Traffic should pass with maximum rate
  79 | | ... | ${max_rate}pps | ${framesize} | ${traffic_profile}
  80
  81 *** Test Cases ***
  82 | tc01-64B-1c-ethip4-ip4scale2m-mrr
  83 | | [Tags] | 64B | 1C
  84 | | framesize=${64} | phy_cores=${1}
  85
  86 | tc02-64B-2c-ethip4-ip4scale2m-mrr
  87 | | [Tags] | 64B | 2C
  88 | | framesize=${64} | phy_cores=${2}
  89
  90 | tc03-64B-4c-ethip4-ip4scale2m-mrr
  91 | | [Tags] | 64B | 4C
  92 | | framesize=${64} | phy_cores=${4}
  93
  94 | tc04-1518B-1c-ethip4-ip4scale2m-mrr
  95 | | [Tags] | 1518B | 1C
  96 | | framesize=${1518} | phy_cores=${1}
  97
  98 | tc05-1518B-2c-ethip4-ip4scale2m-mrr
  99 | | [Tags] | 1518B | 2C
 100 | | framesize=${1518} | phy_cores=${2}
 101
 102 | tc06-1518B-4c-ethip4-ip4scale2m-mrr
 103 | | [Tags] | 1518B | 4C
 104 | | framesize=${1518} | phy_cores=${4}
 105
 106 | tc07-9000B-1c-ethip4-ip4scale2m-mrr
 107 | | [Tags] | 9000B | 1C
 108 | | framesize=${9000} | phy_cores=${1}
 109
 110 | tc08-9000B-2c-ethip4-ip4scale2m-mrr
 111 | | [Tags] | 9000B | 2C
 112 | | framesize=${9000} | phy_cores=${2}
 113
 114 | tc09-9000B-4c-ethip4-ip4scale2m-mrr
 115 | | [Tags] | 9000B | 4C
 116 | | framesize=${9000} | phy_cores=${4}
 117
 118 | tc10-IMIX-1c-ethip4-ip4scale2m-mrr
 119 | | [Tags] | IMIX | 1C
 120 | | framesize=IMIX_v4_1 | phy_cores=${1}
 121
 122 | tc11-IMIX-2c-ethip4-ip4scale2m-mrr
 123 | | [Tags] | IMIX | 2C
 124 | | framesize=IMIX_v4_1 | phy_cores=${2}
 125
 126 | tc12-IMIX-4c-ethip4-ip4scale2m-mrr
 127 | | [Tags] | IMIX | 4C
 128 | | framesize=IMIX_v4_1 | phy_cores=${4}