tests/vpp/perf/ip4/10ge2p1x710-ethip4-ip4base-copwhtlistbase-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/shared/default.robot
  16 | Library | resources.libraries.python.Cop
  17 | ...
  18 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  19 | ... | NIC_Intel-X710 | ETH | IP4FWD | FEATURE | COPWHLIST
  20 | ...
  21 | Suite Setup | Setup suite single link | performance
  22 | Suite Teardown | Tear down suite | performance
  23 | Test Setup | Setup test
  24 | Test Teardown | Tear down test | performance
  25 | ...
  26 | Test Template | Local Template
  27 | ...
  28 | Documentation | *RFC2544: Pkt throughput IPv4 whitelist test cases*
  29 | ...
  30 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  31 | ... | with single links between nodes.
  32 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  33 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  34 | ... | routing, two static IPv4 /24 routes and IPv4 COP security whitelist
  35 | ... | ingress /24 filter entries applied on links TG - DUT1 and DUT2 - TG.
  36 | ... | DUT1 and DUT2 tested with ${nic_name}.\
  37 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  38 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  39 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  40 | ... | of packets transmitted. NDR and PDR are discovered for different\
  41 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  42 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  43 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  44 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  45 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  46 | ... | addresses of the TG node interfaces.
  47 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  48
  49 *** Variables ***
  50 | @{plugins_to_enable}= | dpdk_plugin.so
  51 | ${osi_layer}= | L3
  52 | ${nic_name}= | Intel-X710
  53 | ${overhead}= | ${0}
  54 # Traffic profile:
  55 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  56
  57 *** Keywords ***
  58 | Local Template
  59 | | ...
  60 | | [Documentation]
  61 | | ... | [Cfg] DUT runs IPv4 routing config.
  62 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  63 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  64 | | ...
  65 | | ... | *Arguments:*
  66 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  67 | | ... | Type: integer, string
  68 | | ... | - phy_cores - Number of physical cores. Type: integer
  69 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  70 | | ...
  71 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  72 | | ...
  73 | | Set Test Variable | \${frame_size}
  74 | | ...
  75 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  76 | | And Add PCI devices to all DUTs
  77 | | And Set Max Rate And Jumbo And Handle Multi Seg
  78 | | And Apply startup configuration on all VPP DUTs
  79 | | When Initialize IPv4 forwarding in circular topology
  80 | | And Add Fib Table | ${dut1} | 1
  81 | | And Vpp Route Add | ${dut1} | 10.10.10.0 | 24 | vrf=1 | local=${TRUE}
  82 | | And Add Fib Table | ${dut2} | 1
  83 | | And Vpp Route Add | ${dut2} | 20.20.20.0 | 24 | vrf=1 | local=${TRUE}
  84 | | And COP Add whitelist Entry | ${dut1} | ${dut1_if1} | ip4 | 1
  85 | | And COP Add whitelist Entry | ${dut2} | ${dut2_if2} | ip4 | 1
  86 | | And COP interface enable or disable | ${dut1} | ${dut1_if1} | enable
  87 | | And COP interface enable or disable | ${dut2} | ${dut2_if2} | enable
  88 | | Then Find NDR and PDR intervals using optimized search
  89
  90 *** Test Cases ***
  91 | tc01-64B-1c-ethip4-ip4base-copwhtlistbase-ndrpdr
  92 | | [Tags] | 64B | 1C
  93 | | frame_size=${64} | phy_cores=${1}
  94
  95 | tc02-64B-2c-ethip4-ip4base-copwhtlistbase-ndrpdr
  96 | | [Tags] | 64B | 2C
  97 | | frame_size=${64} | phy_cores=${2}
  98
  99 | tc03-64B-4c-ethip4-ip4base-copwhtlistbase-ndrpdr
 100 | | [Tags] | 64B | 4C
 101 | | frame_size=${64} | phy_cores=${4}
 102
 103 | tc04-1518B-1c-ethip4-ip4base-copwhtlistbase-ndrpdr
 104 | | [Tags] | 1518B | 1C
 105 | | frame_size=${1518} | phy_cores=${1}
 106
 107 | tc05-1518B-2c-ethip4-ip4base-copwhtlistbase-ndrpdr
 108 | | [Tags] | 1518B | 2C
 109 | | frame_size=${1518} | phy_cores=${2}
 110
 111 | tc06-1518B-4c-ethip4-ip4base-copwhtlistbase-ndrpdr
 112 | | [Tags] | 1518B | 4C
 113 | | frame_size=${1518} | phy_cores=${4}
 114
 115 | tc07-9000B-1c-ethip4-ip4base-copwhtlistbase-ndrpdr
 116 | | [Tags] | 9000B | 1C
 117 | | frame_size=${9000} | phy_cores=${1}
 118
 119 | tc08-9000B-2c-ethip4-ip4base-copwhtlistbase-ndrpdr
 120 | | [Tags] | 9000B | 2C
 121 | | frame_size=${9000} | phy_cores=${2}
 122
 123 | tc09-9000B-4c-ethip4-ip4base-copwhtlistbase-ndrpdr
 124 | | [Tags] | 9000B | 4C
 125 | | frame_size=${9000} | phy_cores=${4}
 126
 127 | tc10-IMIX-1c-ethip4-ip4base-copwhtlistbase-ndrpdr
 128 | | [Tags] | IMIX | 1C
 129 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 130
 131 | tc11-IMIX-2c-ethip4-ip4base-copwhtlistbase-ndrpdr
 132 | | [Tags] | IMIX | 2C
 133 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 134
 135 | tc12-IMIX-4c-ethip4-ip4base-copwhtlistbase-ndrpdr
 136 | | [Tags] | IMIX | 4C
 137 | | frame_size=IMIX_v4_1 | phy_cores=${4}