tests/vpp/perf/ip4/10ge2p1x710-ethip4-ip4base-iacldstbase-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP4FWD | FEATURE | IACLDST
  19 | ...
  20 | Suite Setup | Set up 3-node performance topology with DUT's NIC model
  21 | ... | L3 | ${nic_name}
  22 | Suite Teardown | Tear down 3-node performance topology
  23 | ...
  24 | Test Setup | Set up performance test
  25 | Test Teardown | Tear down performance test
  26 | ...
  27 | Test Template | Local Template
  28 | ...
  29 | Documentation | *RFC2544: Pkt throughput IPv4 iAcl whitelist test cases*
  30 | ...
  31 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  32 | ... | with single links between nodes.
  33 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing.
  34 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  35 | ... | routing, two static IPv4 /24 routes and IPv4 iAcl security whitelist
  36 | ... | ingress /24 filter entries applied on links TG - DUT1 and DUT2 - TG.
  37 | ... | DUT1 and DUT2 tested with ${nic_name}.\
  38 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  39 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  40 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  41 | ... | of packets transmitted. NDR and PDR are discovered for different\
  42 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  43 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  44 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  45 | ... | flow-group) with all packets containing Ethernet header, IPv6 header
  46 | ... | and generated payload. MAC addresses are matching MAC addresses
  47 | ... | of the TG node interfaces.
  48 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  49
  50 *** Variables ***
  51 | ${nic_name}= | Intel-X710
  52 | ${overhead}= | ${0}
  53 # Traffic profile:
  54 | ${traffic_profile}= | trex-sl-3n-ethip4-ip4src253
  55
  56 *** Keywords ***
  57 | Local Template
  58 | | ...
  59 | | [Documentation]
  60 | | ... | [Cfg] DUT runs IPv4 routing config.
  61 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  62 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  63 | | ...
  64 | | ... | *Arguments:*
  65 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  66 | | ... | Type: integer, string
  67 | | ... | - phy_cores - Number of physical cores. Type: integer
  68 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  69 | | ...
  70 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  71 | | ...
  72 | | Set Test Variable | \${frame_size}
  73 | | ...
  74 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  75 | | And Add PCI devices to all DUTs
  76 | | Set Max Rate And Jumbo And Handle Multi Seg
  77 | | And Apply startup configuration on all VPP DUTs
  78 | | When Initialize IPv4 forwarding in circular topology
  79 | | ${table_idx} | ${skip_n} | ${match_n}= | And Vpp Creates Classify Table L3
  80 | | ... | ${dut1} | ip4 | dst
  81 | | And Vpp Configures Classify Session L3
  82 | | ... | ${dut1} | permit | ${table_idx} | ${skip_n} | ${match_n}
  83 | | ... | ip4 | dst | 20.20.20.2
  84 | | And Vpp Enable Input Acl Interface
  85 | | ... | ${dut1} | ${dut1_if1} | ip4 | ${table_idx}
  86 | | ${table_idx} | ${skip_n} | ${match_n}= | And Vpp Creates Classify Table L3
  87 | | ... | ${dut2} | ip4 | dst
  88 | | And Vpp Configures Classify Session L3
  89 | | ... | ${dut2} | permit | ${table_idx} | ${skip_n} | ${match_n}
  90 | | ... | ip4 | dst | 10.10.10.2
  91 | | And Vpp Enable Input Acl Interface
  92 | | ... | ${dut2} | ${dut2_if2} | ip4 | ${table_idx}
  93 | | Then Find NDR and PDR intervals using optimized search
  94
  95 *** Test Cases ***
  96 | tc01-64B-1c-ethip4-ip4base-iacldstbase-ndrpdr
  97 | | [Tags] | 64B | 1C
  98 | | frame_size=${64} | phy_cores=${1}
  99
 100 | tc02-64B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 101 | | [Tags] | 64B | 2C
 102 | | frame_size=${64} | phy_cores=${2}
 103
 104 | tc03-64B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 105 | | [Tags] | 64B | 4C
 106 | | frame_size=${64} | phy_cores=${4}
 107
 108 | tc04-1518B-1c-ethip4-ip4base-iacldstbase-ndrpdr
 109 | | [Tags] | 1518B | 1C
 110 | | frame_size=${1518} | phy_cores=${1}
 111
 112 | tc05-1518B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 113 | | [Tags] | 1518B | 2C
 114 | | frame_size=${1518} | phy_cores=${2}
 115
 116 | tc06-1518B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 117 | | [Tags] | 1518B | 4C
 118 | | frame_size=${1518} | phy_cores=${4}
 119
 120 | tc07-9000B-1c-ethip4-ip4base-iacldstbase-ndrpdr
 121 | | [Tags] | 9000B | 1C
 122 | | frame_size=${9000} | phy_cores=${1}
 123
 124 | tc08-9000B-2c-ethip4-ip4base-iacldstbase-ndrpdr
 125 | | [Tags] | 9000B | 2C
 126 | | frame_size=${9000} | phy_cores=${2}
 127
 128 | tc09-9000B-4c-ethip4-ip4base-iacldstbase-ndrpdr
 129 | | [Tags] | 9000B | 4C
 130 | | frame_size=${9000} | phy_cores=${4}
 131
 132 | tc10-IMIX-1c-ethip4-ip4base-iacldstbase-ndrpdr
 133 | | [Tags] | IMIX | 1C
 134 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 135
 136 | tc11-IMIX-2c-ethip4-ip4base-iacldstbase-ndrpdr
 137 | | [Tags] | IMIX | 2C
 138 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 139
 140 | tc12-IMIX-4c-ethip4-ip4base-iacldstbase-ndrpdr
 141 | | [Tags] | IMIX | 4C
 142 | | frame_size=IMIX_v4_1 | phy_cores=${4}