tests/vpp/perf/ip4/10ge2p1x82599es-ethip4udp-ip4base-nat44-ndrpdr.robot

   1 # Copyright (c) 2019 PANTHEON.tech and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | Resource | resources/libraries/robot/ip/nat.robot
  17 | Resource | resources/libraries/robot/shared/traffic.robot
  18 | ...
  19 | Force Tags | 3_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  20 | ... | NIC_Intel-82599ES | ETH | IP4FWD | FEATURE | NAT44 | BASE
  21 | ...
  22 | Suite Setup | Run Keywords
  23 | ... | Set up 3-node performance topology with DUT's NIC model | L3
  24 | ... | Intel-82599ES
  25 | ... | AND | Set up performance test suite with NAT
  26 | Suite Teardown | Tear down 3-node performance topology
  27 | ...
  28 | Test Setup | Set up performance test
  29 | ...
  30 | Test Teardown | Tear down performance discovery test | ${min_rate}pps
  31 | ... | ${framesize} | ${traffic_profile}
  32 | ...
  33 | Test Template | Local Template
  34 | ...
  35 | Documentation | *RFC2544: Pkt throughput NAT44 performance test cases*
  36 | ...
  37 | ... | *[Top] Network Topologies:* TG-DUT1-DUT2-TG 3-node circular topology
  38 | ... | with single links between nodes.
  39 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4-UDP for IPv4 routing.
  40 | ... | *[Cfg] DUT configuration:* DUT1 and DUT2 are configured with IPv4
  41 | ... | routing and two static IPv4 /24 and IPv4/20 route entries. DUT1 and DUT2
  42 | ... | tested with 2p10GE NIC 82599ES by Intel.
  43 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop
  44 | ... | Rate) with zero packet loss tolerance or throughput PDR (Partial Drop
  45 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage
  46 | ... | of packets transmitted. NDR and PDR are discovered for different
  47 | ... | Ethernet L2 frame sizes using MLRsearch library.
  48 | ... | Test packets are generated by TG on links to DUTs. TG traffic profile
  49 | ... | contains two L3 flow-groups (flow-group per direction, 253 flows per
  50 | ... | flow-group) with all packets containing Ethernet header, IPv4 header
  51 | ... | with IP protocol=61 and static payload. MAC addresses are matching MAC
  52 | ... | addresses of the TG node interfaces.
  53 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  54
  55 *** Variables ***
  56 # 82599ES bandwidth limit
  57 | ${s_limit}= | ${10000000000}
  58 # Traffic profile:
  59 | ${traffic_profile}= | trex-sl-3n-ethip4udp-1u1p
  60
  61 *** Keywords ***
  62 | Local Template
  63 | | ...
  64 | | [Documentation]
  65 | | ... | [Cfg] DUT runs IPv4 routing config.
  66 | | ... | Each DUT uses ${phy_cores} physical core(s) for worker threads.
  67 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  68 | | ...
  69 | | ... | *Arguments:*
  70 | | ... | - framesize - Framesize in Bytes in integer or string (IMIX_v4_1).
  71 | | ... | Type: integer, string
  72 | | ... | - phy_cores - Number of physical cores. Type: integer
  73 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  74 | | ...
  75 | | [Arguments] | ${framesize} | ${phy_cores} | ${rxq}=${None}
  76 | | ...
  77 | | Set Test Variable | ${framesize}
  78 | | Set Test Variable | ${min_rate} | ${10000}
  79 | | ...
  80 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Add PCI devices to all DUTs
  82 | | ${max_rate} | ${jumbo} = | Get Max Rate And Jumbo And Handle Multi Seg
  83 | | ... | ${s_limit} | ${framesize}
  84 | | And Add NAT to all DUTs
  85 | | And Apply startup configuration on all VPP DUTs
  86 | | When Initialize NAT44 in circular topology
  87 | | Then Find NDR and PDR intervals using optimized search
  88 | | ... | ${framesize} | ${traffic_profile} | ${min_rate} | ${max_rate}
  89
  90 *** Test Cases ***
  91 | tc01-64B-1c-ethip4udp-ip4base-nat44-ndrpdr
  92 | | [Tags] | 64B | 1C
  93 | | framesize=${64} | phy_cores=${1}
  94
  95 | tc02-64B-2c-ethip4udp-ip4base-nat44-ndrpdr
  96 | | [Tags] | 64B | 2C
  97 | | framesize=${64} | phy_cores=${2}
  98
  99 | tc03-64B-4c-ethip4udp-ip4base-nat44-ndrpdr
 100 | | [Tags] | 64B | 4C
 101 | | framesize=${64} | phy_cores=${4}
 102
 103 | tc04-1518B-1c-ethip4udp-ip4base-nat44-ndrpdr
 104 | | [Tags] | 1518B | 1C
 105 | | framesize=${1518} | phy_cores=${1}
 106
 107 | tc05-1518B-2c-ethip4udp-ip4base-nat44-ndrpdr
 108 | | [Tags] | 1518B | 2C
 109 | | framesize=${1518} | phy_cores=${2}
 110
 111 | tc06-1518B-4c-ethip4udp-ip4base-nat44-ndrpdr
 112 | | [Tags] | 1518B | 4C
 113 | | framesize=${1518} | phy_cores=${4}
 114
 115 | tc07-9000B-1c-ethip4udp-ip4base-nat44-ndrpdr
 116 | | [Tags] | 9000B | 1C
 117 | | framesize=${9000} | phy_cores=${1}
 118
 119 | tc08-9000B-2c-ethip4udp-ip4base-nat44-ndrpdr
 120 | | [Tags] | 9000B | 2C
 121 | | framesize=${9000} | phy_cores=${2}
 122
 123 | tc09-9000B-4c-ethip4udp-ip4base-nat44-ndrpdr
 124 | | [Tags] | 9000B | 4C
 125 | | framesize=${9000} | phy_cores=${4}
 126
 127 | tc10-IMIX-1c-ethip4udp-ip4base-nat44-ndrpdr
 128 | | [Tags] | IMIX | 1C
 129 | | framesize=IMIX_v4_1 | phy_cores=${1}
 130
 131 | tc11-IMIX-2c-ethip4udp-ip4base-nat44-ndrpdr
 132 | | [Tags] | IMIX | 2C
 133 | | framesize=IMIX_v4_1 | phy_cores=${2}
 134
 135 | tc12-IMIX-4c-ethip4udp-ip4base-nat44-ndrpdr
 136 | | [Tags] | IMIX | 4C
 137 | | framesize=IMIX_v4_1 | phy_cores=${4}