tests/vpp/perf/ip4/2n1l-10ge2p1x710-dot1q-ip4base-ndrpdr.robot

   1 # Copyright (c) 2019 Cisco and/or its affiliates.
   2 # Licensed under the Apache License, Version 2.0 (the "License");
   3 # you may not use this file except in compliance with the License.
   4 # You may obtain a copy of the License at:
   5 #
   6 #     http://www.apache.org/licenses/LICENSE-2.0
   7 #
   8 # Unless required by applicable law or agreed to in writing, software
   9 # distributed under the License is distributed on an "AS IS" BASIS,
  10 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  11 # See the License for the specific language governing permissions and
  12 # limitations under the License.
  13
  14 *** Settings ***
  15 | Resource | resources/libraries/robot/performance/performance_setup.robot
  16 | ...
  17 | Force Tags | 2_NODE_SINGLE_LINK_TOPO | PERFTEST | HW_ENV | NDRPDR
  18 | ... | NIC_Intel-X710 | ETH | IP4FWD | BASE | DOT1Q | IP4BASE
  19 | ...
  20 | Suite Setup | Set up 2-node performance topology with DUT's NIC model
  21 | ... | L3 | ${nic_name}
  22 | ...
  23 | Suite Teardown | Tear down suite | performance
  24 | ...
  25 | Test Setup | Set up performance test
  26 | Test Teardown | Tear down test | performance
  27 | ...
  28 | Test Template | Local Template
  29 | ...
  30 | Documentation | *RFC2544: Pkt throughput IPv4 routing with IEEE 802.1Q test\
  31 | ... | cases*
  32 | ...
  33 | ... | *[Top] Network Topologies:* TG-DUT1-TG 2-node circular topology with\
  34 | ... | single links between nodes.
  35 | ... | *[Enc] Packet Encapsulations:* Eth-IPv4 for IPv4 routing. IEEE 802.1Q\
  36 | ... | tagging is applied on link between DUT1-if2 and TG-if2.
  37 | ... | *[Cfg] DUT configuration:* DUT1 is configured with IPv4 routing and\
  38 | ... | two static IPv4 /30 route entries. DUT1 is tested with ${nic_name}.\
  39 | ... | *[Ver] TG verification:* TG finds and reports throughput NDR (Non Drop\
  40 | ... | Rate) with zero packet loss tolerance and throughput PDR (Partial Drop\
  41 | ... | Rate) with non-zero packet loss tolerance (LT) expressed in percentage\
  42 | ... | of packets transmitted. NDR and PDR are discovered for different\
  43 | ... | Ethernet L2 frame sizes using MLRsearch library.\
  44 | ... | Test packets are\
  45 | ... | generated by TG on links to DUT1. TG traffic profile contains two L3\
  46 | ... | flow-groups (flow-group per direction, 254 flows per flow-group) with\
  47 | ... | all packets containing Ethernet header, IPv4 header with IP\
  48 | ... | protocol=61 and static payload. MAC addresses are matching MAC\
  49 | ... | addresses of the TG node interfaces.
  50 | ... | *[Ref] Applicable standard specifications:* RFC2544.
  51
  52 *** Variables ***
  53 | ${nic_name}= | Intel-X710
  54 | ${overhead}= | ${4}
  55 | ${subid}= | 10
  56 | ${tag_rewrite}= | pop-1
  57 # TG subnets used by T-Rex
  58 | ${tg_if1_net}= | 10.10.10.0
  59 | ${tg_if2_net}= | 20.20.20.0
  60 # Traffic profile:
  61 | ${traffic_profile}= | trex-sl-2n-dot1qip4asym-ip4src254
  62
  63 *** Keywords ***
  64 | Local Template
  65 | | [Documentation]
  66 | | ... | [Cfg] Each DUT runs IPv4 routing with VLAN and uses ${phy_cores}\
  67 | | ... | physical core(s) for worker threads.
  68 | | ... | [Ver] Measure NDR and PDR values using MLRsearch algorithm.\
  69 | | ...
  70 | | ... | *Arguments:*
  71 | | ... | - frame_size - Framesize in Bytes in integer or string (IMIX_v4_1).
  72 | | ... | Type: integer, string
  73 | | ... | - phy_cores - Number of physical cores. Type: integer
  74 | | ... | - rxq - Number of RX queues, default value: ${None}. Type: integer
  75 | | ...
  76 | | [Arguments] | ${frame_size} | ${phy_cores} | ${rxq}=${None}
  77 | | ...
  78 | | Set Test Variable | \${frame_size}
  79 | | ...
  80 | | Given Add worker threads and rxqueues to all DUTs | ${phy_cores} | ${rxq}
  81 | | And Add PCI devices to all DUTs
  82 | | Set Max Rate And Jumbo And Handle Multi Seg
  83 | | And Apply startup configuration on all VPP DUTs
  84 | | When Initialize IPv4 forwarding with VLAN dot1q sub-interfaces in circular topology
  85 | | ... | ${tg_if1_net} | ${tg_if2_net} | ${subid} | ${tag_rewrite}
  86 | | Then Find NDR and PDR intervals using optimized search
  87
  88 *** Test Cases ***
  89 | tc01-64B-1c-dot1q-ip4base-ndrpdr
  90 | | [Tags] | 64B | 1C
  91 | | frame_size=${64} | phy_cores=${1}
  92
  93 | tc02-64B-2c-dot1q-ip4base-ndrpdr
  94 | | [Tags] | 64B | 2C
  95 | | frame_size=${64} | phy_cores=${2}
  96
  97 | tc03-64B-4c-dot1q-ip4base-ndrpdr
  98 | | [Tags] | 64B | 4C
  99 | | frame_size=${64} | phy_cores=${4}
 100
 101 | tc04-1518B-1c-dot1q-ip4base-ndrpdr
 102 | | [Tags] | 1518B | 1C
 103 | | frame_size=${1518} | phy_cores=${1}
 104
 105 | tc05-1518B-2c-dot1q-ip4base-ndrpdr
 106 | | [Tags] | 1518B | 2C
 107 | | frame_size=${1518} | phy_cores=${2}
 108
 109 | tc06-1518B-4c-dot1q-ip4base-ndrpdr
 110 | | [Tags] | 1518B | 4C
 111 | | frame_size=${1518} | phy_cores=${4}
 112
 113 | tc07-9000B-1c-dot1q-ip4base-ndrpdr
 114 | | [Tags] | 9000B | 1C
 115 | | frame_size=${9000} | phy_cores=${1}
 116
 117 | tc08-9000B-2c-dot1q-ip4base-ndrpdr
 118 | | [Tags] | 9000B | 2C
 119 | | frame_size=${9000} | phy_cores=${2}
 120
 121 | tc09-9000B-4c-dot1q-ip4base-ndrpdr
 122 | | [Tags] | 9000B | 4C
 123 | | frame_size=${9000} | phy_cores=${4}
 124
 125 | tc10-IMIX-1c-dot1q-ip4base-ndrpdr
 126 | | [Tags] | IMIX | 1C
 127 | | frame_size=IMIX_v4_1 | phy_cores=${1}
 128
 129 | tc11-IMIX-2c-dot1q-ip4base-ndrpdr
 130 | | [Tags] | IMIX | 2C
 131 | | frame_size=IMIX_v4_1 | phy_cores=${2}
 132
 133 | tc12-IMIX-4c-dot1q-ip4base-ndrpdr
 134 | | [Tags] | IMIX | 4C
 135 | | frame_size=IMIX_v4_1 | phy_cores=${4}